program EXERes;

{$R *.dres}

uses
  Winapi.Windows;

var
  LuType : Cardinal;

begin
  LuType := MB_ICONWARNING or MB_TOPMOST;
  MessageBox(0, 'このファイルは実行できません。', '実行不可', LuType);
end.

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,
  Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.ExtCtrls, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    Image1: TImage;
    Button2: TButton;
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
    FEXEResPath : string;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//
//  外部の EXE に埋め込んだリソースを読み出して表示
//  埋め込んだリソースは文字列とビットマップ画像
//
//  リソースの文字列は Unicode と仮定
//  メモ帳の場合、文字コードを UTF-16LE (little endian) にして保存したテキスト
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  LhModule    : THandle;
  LTextStream : TResourceStream;
  LBitmap     : TBitmap;
begin
  // 外部 EXE のフルパス 
  FEXEResPath := ExtractFilePath(Application.ExeName) + 'EXERes.exe';
//
  // EXE のモジュールハンドルを取得
  LhModule := LoadLibraryEx(PChar(FEXEResPath),
                       0,
                       LOAD_LIBRARY_AS_DATAFILE or LOAD_WITH_ALTERED_SEARCH_PATH);
  if LhModule = 0 then Exit;

  LTextStream := TResourceStream.Create(LhModule, 'Text_1', RT_RCDATA);
  LBitmap     := TBitmap.Create;
  try
     // 文字列 (テキスト) を取得
     Memo1.Lines.LoadFromStream(LTextStream, TEncoding.Unicode);

     // ビットマップ画像を取得して TImage に描画
     LBitmap.LoadFromResourceName(LhModule, 'Bitmap_1');
     Image1.Picture.Assign(LBitmap);
  finally
    FreeAndNil(LTextStream);
    FreeAndNil(LBitmap);
    FreeLibrary(LhModule);
  end;
end;

//=============================================================================
//  フォームを閉じる時の処理
//  外部 EXE に埋め込んだリソースを書き換える
//=============================================================================
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
var
  LBitmap    : TBitmap;
  LhModule   : THandle;
  LBmpStream : TMemoryStream;
  LResStream : TMemoryStream;
  LText      : string;
begin
  // EXE のモジュールハンドルを取得
  LhModule := BeginUpdateResource(PChar(FEXEResPath), False);
  if LhModule = 0 then Exit;


  LBmpStream := TMemoryStream.Create;
  LResStream := TMemoryStream.Create;
  LBitmap    := TBitmap.Create;
  try
    // 文字列のリソースを書き換える
    LText := Memo1.Lines.Text;
    UpdateResource(LhModule, RT_RCDATA, 'Text_1', 0, 
                   Pointer(LText), Length(LText) * SizeOf(Char));

    // TImage に描画しているビットマップをメモリストリームに格納
    Image1.Picture.Bitmap.SaveToStream(LBmpStream);

    // ビットマップファイルヘッダ部分を削除したメモリストリームを作成
    // リソースのビットマップには、ビットマップファイルヘッダはない
    LResStream.Size := LBmpStream.Size - SizeOf(TBitmapFileHeader);
    LBmpStream.Position := SizeOf(TBitmapFileHeader);
    LResStream.CopyFrom(LBmpStream, LBmpStream.Size - SizeOf(TBitmapFileHeader));

    // ビットマップ画像リソースを書き換える
    UpdateResource(LhModule, RT_BITMAP, 'Bitmap_1', 0,
                   LResStream.Memory, LResStream.Size);
  finally
    // リソースを更新
    EndUpdateResource(LhModule, False);

    FreeAndNil(LBmpStream);
    FreeAndNil(LResStream);
    FreeAndNil(LBitmap);
  end;
end;

//=============================================================================
//  別のビットマップ画像 TImage にを表示
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LBitmap : TBitmap;
begin
  LBitmap := TBitmap.Create;
  try
    if Sender = nil then begin
      LBitmap.LoadFromFile('Smail_01.bmp');
    end else begin
      LBitmap.LoadFromFile('Smail_02.bmp');
    end;
    Image1.Picture.Assign(LBitmap);
  finally
    FreeAndNil(LBitmap);
  end;
end;

//=============================================================================
//  別のビットマップ画像 TImage にを表示
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  Button1Click(nil);
end;

end.