//=============================================================================
//  Shift_JIS のテキストをファイルから読み込んで TMemo に表示
//  コードページの変換には LConvEncoding ユニットの CP932ToUTF8 関数も使用可能
//
//  uses に LazUTF8 が必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LStrList : TStringList;
begin
  LStrList := TStringList.Create;
  try
    LStrList.LoadFromFile('TEST.txt');
    Memo1.Lines.Text:= WinCPToUTF8(LStrList.Text);
  finally
    FreeAndNil(LStrList);
  end;
end;

//=============================================================================
//  TMemo のテキストを Shift_JIS のテキストとしてファイルに保存
//  コードページの変換には LazUTF8 ユニットの UTF8ToWinCP 関数も使用可能
//  TMemo.SaveToFile で保存すると UTF-8 (BOM 無し) のテキストになる
//
//  uses に LConvEncoding が必要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LStrList : TStringList;
begin
  LStrList := TStringList.Create;
  try
    LStrList.Text := UTF8ToCP932(Memo1.Lines.text);
    LStrList.SaveToFile('TEST_SAVE.txt');
  finally
    FreeAndNil(LStrList);
  end;
end;

//-----------------------------------------------------------------------------
//  ウィンドウのタイトル名を取得する関数
//  戻り値が string 型の例
//  この場合の string 型の変数のコードページは AnsiString 型と同じになる
//
//  GetWindowText 関数の末尾に A も W もないので Ansi 用の関数
//-----------------------------------------------------------------------------
function GetWindowTitelStr(hWindow: HWND): string;
var
  LBuffer : array[0..MAX_PATH-1] of Char;
  LLen    : Integer;
begin
  FillChar(LBuffer, SizeOf(LBuffer), #0);
  LLen := GetWindowText(hWindow, LBuffer, Length(LBuffer));
  if LLen > 0 then begin
    Result := LBuffer
  end else begin
    Result := '';
  end;
end;

//=============================================================================
//  Windows API で string ( AnsiString ASCII ) 文字列を取得
//  コードページの処理なし
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LTitle : string;
begin
  LTitle:= GetWindowTitelStr(Handle);

  Edit1.Text:= LTitle;
  ShowMessage(LTitle);
end;

//=============================================================================
//  Windows API で string ( AnsiString 日本語 ) 文字列を取得
//  コードページの処理なし
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LTitle : string;
begin
  Caption:= '日本語タイトル ABC';

  LTitle:= GetWindowTitelStr(Handle);

  Edit1.Text:= LTitle;
  ShowMessage(LTitle);
end;

//=============================================================================
//  Windows API で string ( AnsiString 日本語 ) 文字列を取得
//  WinCPToUTF8 (AnsiString をUTF-8 に変換) を使用しててコードページを変換

//  uses に LazUTF8 が必要
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
var
  LTitle : string;
begin
  Caption:= '日本語タイトル ABC';

  LTitle:= WinCPToUTF8(GetWindowTitelStr(Handle));

  Edit1.Text:= LTitle;
  ShowMessage(LTitle);
end;

//-----------------------------------------------------------------------------
//  ウィンドウのタイトル名を取得する関数
//  戻り値が UnicodeString 型の例
//  この場合の UnicodeString 型の変数の文字のコードページは UTF-16 となる
//
//  ユニコードでは末尾に W がある GetWindowTextW 関数を使用する
//-----------------------------------------------------------------------------
function GetWindowTitelStr(hWindow: HWND): UnicodeString;
var
  LBuffer : array[0..MAX_PATH-1] of UnicodeChar;
  LLen    : Integer;
begin
  FillChar(LBuffer, SizeOf(LBuffer), #0);
  LLen := GetWindowTextW(hWindow, LBuffer, Length(LBuffer));
  if LLen > 0 then begin
    Result := LBuffer
  end else begin
    Result := '';
  end;
end;

//=============================================================================
//  Windows API で UnicodeString ( UTF-16 ASCII 文字のみ) 文字列を取得
//  コードページの処理なし
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LTitle : string;
begin
  LTitle:= GetWindowTitelStr(Handle);

  Edit1.Text:= LTitle;
  ShowMessage(LTitle);
end;

//=============================================================================
//  Windows API で UnicodeString ( UTF-16 の日本語) 文字列を取得
//  コードページの処理なし
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LTitle : string;
begin
  Caption:= '日本語タイトル ABC';

  LTitle:= GetWindowTitelStr(Handle);

  Edit1.Text:= LTitle;
  ShowMessage(LTitle);
end;

//=============================================================================
//  Windows API で UnicodeString ( UTF-16 の日本語) 文字列を取得
//  UTF16ToUTF8 (Unicode を UTF-8 に変換) を使用してコードページを変換
//
//  uses に LazUTF8 が必要
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
var
  LTitle : string;
begin
  Caption:= '日本語タイトル ABC';

  LTitle:= UTF16ToUTF8(GetWindowTitelStr(Handle));

  Edit1.Text:= LTitle;
  ShowMessage(LTitle);
end;

//=============================================================================
//  Windows API の関数の引数に文字列を渡す
//  UTF-8 の文字列を渡しているので文字化けする 
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LText : string;
begin
  LText:= '日本語 ABC';

  MessageBox(Handle, PChar(LText), 'TEST', MB_ICONINFORMATION);
end;

//=============================================================================
//  Windows API の関数の引数に文字列を渡す
//  文字列を UTF8ToWinCP で変換して引数に渡しているので文字化けしない 
//
//  uses に LazUTF8 が必要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LSrcText : string;
  LDstText : string;
begin
  LSrcText:= '日本語 ABC';

  LDstText:= UTF8ToWinCP(LSrcText);
  MessageBox(Handle, PChar(LDstText), 'TEST', MB_ICONINFORMATION);
end;

//=============================================================================
//  Windows API の関数の引数に文字列を渡す
//  Unicode 用 Windows API の関数の場合は UTF8ToUTF16 でコードページを変換する
//
//  uses に LazUTF8 が必要
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
var
  LSrcText : string;
  LDstText : WideString;
begin
  LSrcText:= '日本語 ABC';

  LDstText:= UTF8ToUTF16(LSrcText);
  MessageBoxW(Handle, PWideChar(LDstText), 'TEST', MB_ICONINFORMATION);
end;

//=============================================================================
//  Windows API の関数の引数に文字列を渡す
//  静的文字配列の場合
//  PChar の変数も同じように変換可能
//
//  uses に LazUTF8 が必要
//=============================================================================
procedure TForm1.Button4Click(Sender: TObject);
var
  LSrcText : array [0..MAX_PATH] of Char;
  LDstText : array [0..MAX_PATH] of WideChar;
begin
  LSrcText := '日本語テキスト';

  LDstText:= UTF8ToUTF16(LSrcText);
  MessageBoxW(Handle, PWideChar(LDstText), 'TEST', MB_ICONINFORMATION);
end;

//=============================================================================
//  Windows API の関数の引数に文字列を渡す
//  FindWindow 関数の例
//  引数に UTF-8 の文字列を渡しているので検索に失敗する
//
//  uses に LazUTF8 が必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LhWnd : HWND;
  LText : AnsiString;
begin
  Caption:= '日本語タイトル';

  LhWnd:= FindWindow(nil, PAnsiChar(Caption));

  if LhWnd = 0 then begin
    LText:= UTF8ToWinCP('見つかりませんでした');
    MessageBox(Handle, PAnsiChar(LText), 'Result', MB_ICONWARNING
    );
  end else begin
    LText:= UTF8ToWinCP('見つかりました');
    MessageBox(Handle, PAnsiChar(LText), 'Result', MB_ICONINFORMATION);
  end;
end;

//=============================================================================
//  Windows API の関数の引数に文字列を渡す
//  FindWindow 関数の例
//  文字列を UTF8ToWinCP で変換して引数に渡しているので検索に成功する
//
//  uses に LazUTF8 が必要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LhWnd : HWND;
  LText : AnsiString;
begin
  Caption:= '日本語タイトル';

  LText:= UTF8ToWinCP(Caption);
  LhWnd:= FindWindow(nil, PAnsiChar(LText));

  if LhWnd = 0 then begin
    LText:= UTF8ToWinCP('見つかりませんでした');
    MessageBox(Handle, PAnsiChar(LText), 'Result', MB_ICONWARNING);
  end else begin
    LText:= UTF8ToWinCP('見つかりました');
    MessageBox(Handle, PAnsiChar(LText), 'Result', MB_ICONINFORMATION);
  end;
end;