unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Label1: TLabel;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

function SetThreadExecutionState(esFlags: DWORD): DWORD; stdcall external 'kernel32.dll';

var
  Form1: TForm1;

implementation

{$R *.dfm}

const
  ES_SYSTEM_REQUIRED  = $00000001;
  ES_DISPLAY_REQUIRED = $00000002;
  ES_CONTINUOUS       = $80000000;


//=============================================================================
//  モニタの電源OFFの機能を抑止する
//  この設定は本プログラムが起動中のみ有効となる
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  SetThreadExecutionState(ES_DISPLAY_REQUIRED or ES_CONTINUOUS);
end;

//=============================================================================
//  モニタの電源OFFの機能を抑止しない
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  SetThreadExecutionState(ES_CONTINUOUS);
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Label1: TLabel;
    Timer1: TTimer;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

function SetThreadExecutionState(esFlags: DWORD): DWORD; stdcall external 'kernel32.dll';

var
  Form1: TForm1;

implementation

{$R *.dfm}

const
  ES_SYSTEM_REQUIRED  = $00000001;
  ES_DISPLAY_REQUIRED = $00000002;
  ES_CONTINUOUS       = $80000000;


//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Timer1.Enabled := False;
end;

//=============================================================================
//  タイマーのイベントを使用してモニタの電源OFFの機能を抑止する
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  Timer1.Interval := 30 * 1000;
  Timer1.Enabled := True;
end;

//=============================================================================
//  モニタの電源OFFの機能を抑止しない
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  Timer1.Enabled := False;
end;

//=============================================================================
//  Timer1のOnTimerイベント処理
//  一定の時間間隔でモニタの電源OFFの機能を抑止する
//  時間間隔はモニタOFFまでのタイムアウトの時間よりも短くする
//=============================================================================
procedure TForm1.Timer1Timer(Sender: TObject);
begin
  SetThreadExecutionState(ES_DISPLAY_REQUIRED);
end;

end.

procedure TForm1.Button1Click(Sender: TObject);
var
  LWaitTime : Integer;
  LText     : string;
begin
  SystemParametersInfo(SPI_GETSCREENSAVETIMEOUT,
                       0,
                       @LWaitTime,
                       0);

  LText := IntToStr(LWaitTime) + ' 秒';
  MessageBox(Handle, PChar(LText), '結果', MB_ICONINFORMATION);
end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Label1: TLabel;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

function SetThreadExecutionState(esFlags: DWORD): DWORD; stdcall external 'kernel32.dll';

var
  Form1: TForm1;

implementation

{$R *.dfm}

const
  ES_SYSTEM_REQUIRED  = $00000001;
  ES_DISPLAY_REQUIRED = $00000002;
  ES_CONTINUOUS       = $80000000;

//=============================================================================
//  システムのスリープ機能を抑止する
//  この設定は本プログラムが起動中のみ有効となる
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  SetThreadExecutionState(ES_SYSTEM_REQUIRED or ES_CONTINUOUS);
end;

//=============================================================================
//  システムのスリープ機能を抑止しない
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  SetThreadExecutionState(ES_CONTINUOUS);
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Label1: TLabel;
    Timer1: TTimer;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

function SetThreadExecutionState(esFlags: DWORD): DWORD; stdcall external 'kernel32.dll';

var
  Form1: TForm1;

implementation

{$R *.dfm}

const
  ES_SYSTEM_REQUIRED  = $00000001;
  ES_DISPLAY_REQUIRED = $00000002;
  ES_CONTINUOUS       = $80000000;


//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Timer1.Enabled := False;
end;

//=============================================================================
//  タイマーのイベントを使用してシステムのスリープ機能を抑止する
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  Timer1.Interval := 30 * 1000;
  Timer1.Enabled := True;
end;

//=============================================================================
//  システムのスリープ機能を抑止しない
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  Timer1.Enabled := False;
end;

//=============================================================================
//  Timer1のOnTimerイベント処理
//  一定の時間間隔でモニタの電源OFFの機能を抑止する
//  時間間隔はコンピュータのスリープまでのタイムアウトの時間よりも短くする
//=============================================================================
procedure TForm1.Timer1Timer(Sender: TObject);
begin
  SetThreadExecutionState(ES_SYSTEM_REQUIRED);
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Label1: TLabel;
    Label2: TLabel;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

function SetThreadExecutionState(esFlags: DWORD): DWORD; stdcall external 'kernel32.dll';

var
  Form1: TForm1;

implementation

{$R *.dfm}

const
  ES_SYSTEM_REQUIRED  = $00000001;
  ES_DISPLAY_REQUIRED = $00000002;
  ES_CONTINUOUS       = $80000000;


//=============================================================================
//  モニタの電源OFFの機能とシステムのスリープ機能を抑止する
//  この設定は本プログラムが起動中のみ有効となる
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  SetThreadExecutionState(ES_DISPLAY_REQUIRED or ES_SYSTEM_REQUIRED or ES_CONTINUOUS);
end;

//=============================================================================
//  モニタの電源OFFの機能とシステムのスリープ機能を抑止しない
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  SetThreadExecutionState(ES_CONTINUOUS);
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Label1: TLabel;
    Timer1: TTimer;
    Label2: TLabel;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

function SetThreadExecutionState(esFlags: DWORD): DWORD; stdcall external 'kernel32.dll';

var
  Form1: TForm1;

implementation

{$R *.dfm}

const
  ES_SYSTEM_REQUIRED  = $00000001;
  ES_DISPLAY_REQUIRED = $00000002;
  ES_CONTINUOUS       = $80000000;


//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Timer1.Enabled := False;
end;

//=============================================================================
//  モニタの電源OFFの機能とシステムのスリープ機能を抑止する
//  タイマーのイベントを使用
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  Timer1.Interval := 30 * 1000;
  Timer1.Enabled := True;
end;

//=============================================================================
//  モニタの電源OFFの機能とシステムのスリープ機能を抑止しない
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  Timer1.Enabled := False;
end;

//=============================================================================
//  Timer1のOnTimerイベント処理
//  一定の時間間隔でモニタの電源OFFの機能とシステムのスリープ機能を抑止
//  時間間隔はタイムアウトの時間よりも短くする
//=============================================================================
procedure TForm1.Timer1Timer(Sender: TObject);
begin
  SetThreadExecutionState(ES_DISPLAY_REQUIRED or ES_SYSTEM_REQUIRED);
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Timer1: TTimer;
    procedure FormCreate(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
  private
    { Private 宣言 }
    FIsMonitorPower : Boolean;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//  オブジェクト・インスペクタで Timer1 の Enabled を False にしておく
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  FIsMonitorPower := True;

  Timer1.Interval := 30 * 1000;
  Timer1.Enabled := True;
end;

//=============================================================================
//  Timer1のOnTimerイベント処理
//  一定の時間間隔でモニタの電源をON,OFF する
//=============================================================================
procedure TForm1.Timer1Timer(Sender: TObject);
begin
  if FIsMonitorPower then begin
    // モニタの電源をOFF
    PostMessage(HWND_BROADCAST, WM_SYSCOMMAND, SC_MONITORPOWER, 2);
    FIsMonitorPower := False;
  end else begin
    // モニタの電源をON
    PostMessage(HWND_BROADCAST, WM_SYSCOMMAND, SC_MONITORPOWER, -1);
    FIsMonitorPower := True;
  end;
end;

end.

    // マウスカーソルの移動をエミュレート
    mouse_event(MOUSEEVENTF_MOVE, 1, 1, 0, 0);

    // キー操作のエミュレート
    keybd_event(VK_ESCAPE, MapVirtualKey(VK_ESCAPE, 0), 0, 0);
    keybd_event(VK_ESCAPE, MapVirtualKey(VK_ESCAPE, 0), KEYEVENTF_KEYUP, 0);

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,
  Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.ExtCtrls;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    Button1: TButton;
    Timer1: TTimer;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Memo1.Lines.Clear;
end;

//=============================================================================
//  モニタの電源が ON であるか OFF であるかを調べてタイマーを起動
//
//  TPowerBroadcastSetting レコード型の Data メンバの値で判定
//  TPowerBroadcastSetting レコード型は POWERBROADCAST_SETTING 構造体に相当
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LPwrSetting : TPowerBroadcastSetting;
  LPwrState   : Byte;
begin
  LPwrState := LPwrSetting.Data[0];

  if LPwrState = 0 then begin
    Memo1.Lines.Add('OFF :  ' + FormatDateTime('hh:nn:ss', Now));
  end else begin
    Memo1.Lines.Add('ON  :  ' + FormatDateTime('hh:nn:ss', Now));
  end;

  if Sender = nil then begin
    Timer1.Enabled := False;
  end else begin
    Timer1.Interval := 70 * 1000;
    Timer1.Enabled := True;
  end;
end;

//=============================================================================
//  Timer1 の OnTimer イベント
//  一定の時間経過後,モニタの電源が ON であるか OFF であるかを調べる
//=============================================================================
procedure TForm1.Timer1Timer(Sender: TObject);
begin
  Button1Click(nil);
end;

end.

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,
  Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.ExtCtrls;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    Button1: TButton;
    procedure FormDestroy(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
    FhPowerNotify : THandle;
  protected
    procedure WMPowerbroadcast(var Message: TMessage);
      message WM_POWERBROADCAST;
  public
    { Public 宣言 }
  end;

  function RegisterPowerSettingNotification(hRecipient : THandle;
                                            PowerSettingGuid: PGuid;
                                            Flags: byte): THandle;
                                            stdcall;external 'user32.dll';

  function UnregisterPowerSettingNotification(AHandle: THandle): BOOL;
                                              stdcall; external 'user32.dll';

var
  Form1: TForm1;

implementation

{$R *.dfm}

const
  // MSDN に掲載の値は一部間違いあり
  GUID_ACDC_POWER_SOURCE             : TGUID = '{5d3e9a59-e9D5-4b00-a6bd-ff34ff516548}';
  GUID_BATTERY_PERCENTAGE_REMAININGE : TGUID = '{a7ad8041-b45a-4cae-87a3-eecbb468a9e1}';
  GUID_CONSOLE_DISPLAY_STATE         : TGUID = '{6fe69556-704a-47a0-8f24-c28d936fda47}';
  GUID_GLOBAL_USER_PRESENCE          : TGUID = '{786E8A1D-B427-4344-9207-09E70BDCBEA9}';
  GUID_IDLE_BACKGROUND_TASK          : TGUID = '{515c31d8-f734-163d-a0fd-11a08c91e8f1}';
  GUID_MONITOR_POWER_ON              : TGUID = '{02731015-4510-4526-99e6-e5a17ebd1aea}';
  GUID_POWER_SAVING_STATUS           : TGUID = '{E00958C0-C213-4ACE-AC77-FECCED2EEEA5}';
  GUID_POWERSCHEME_PERSONALITY       : TGUID = '{245d8541-3943-4422-b025-13A784F679B7}';
  GUID_SESSION_DISPLAY_STATUS        : TGUID = '{2B84C20E-AD23-4ddf-93DB-05FFBD7EFCA5}';
  GUID_SESSION_USER_PRESENCE         : TGUID = '{3C0F4548-C03F-4c4d-B9F2-237EDE686376}';
  GUID_SYSTEM_AWAYMODE               : TGUID = '{98a7f580-01f7-48aa-9c0f-44352c29e5C0}';


//=============================================================================
//  フォーム破棄時の処理
//=============================================================================
procedure TForm1.FormDestroy(Sender: TObject);
begin
  if FhPowerNotify <> 0 then begin
    UnregisterPowerSettingNotification(FhPowerNotify);
  end;
end;

//=============================================================================
//  モニタの電源の ON, OFF の監視を開始
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  Memo1.Lines.Clear;
  // モニタの電源状態変更メッセージの受信設定
  // このフォームで受信する場合  
  FhPowerNotify := RegisterPowerSettingNotification(Handle,
                                                    @GUID_CONSOLE_DISPLAY_STATE,
                                                    DEVICE_NOTIFY_WINDOW_HANDLE);
end;

//=============================================================================
//  WM_POWERBROADCAST メッセージの処理
//
//  TPowerBroadcastSetting レコード型の Data メンバの値で判定
//  TPowerBroadcastSetting レコード型は POWERBROADCAST_SETTING 構造体に相当
//=============================================================================
procedure TForm1.WMPowerbroadcast(var Message: TMessage);
var
  LpPwrSetting : PPowerBroadcastSetting;
begin
  LpPwrSetting := PPowerBroadcastSetting(Message.LParam);

  if LpPwrSetting^.PowerSetting = GUID_CONSOLE_DISPLAY_STATE then begin
    if LpPwrSetting^.Data[0] = 0 then begin
      Memo1.Lines.Add('OFF :  ' + FormatDateTime('hh:nn:ss', Now));
    end else begin
      Memo1.Lines.Add('ON  :  ' + FormatDateTime('hh:nn:ss', Now));
    end;
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

function SetSuspendState(bHibernate: Boolean;
                         bForce: Boolean;
                         bWakeupEventsDisabled: Boolean): Boolean;
                         stdcall external 'PowrProf.dll';

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  コンピュータをスリープ状態にする
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  SetSuspendState(False, False, False);
end;

//=============================================================================
//  コンピュータを休止状態のスリープにする
//  休止状態が無効の場合は上のスリープと同じ
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  SetSuspendState(True, False, False);
end;

end.

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, 
  Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    procedure FormCreate(Sender: TObject);
  protected
    procedure WMPowerbroadcast(var Message: TMessage);
      message WM_POWERBROADCAST;
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Memo1.Lines.Clear;
end;

//=============================================================================
//  WM_POWERBROADCAST メッセージ処理
//=============================================================================
procedure TForm1.WMPowerbroadcast(var Message: TMessage);
var
  LTypeText: string;
begin
  case Message.WParam of
    PBT_APMPOWERSTATUSCHANGE  : LTypeText := 'PBT_APMPOWERSTATUSCHANGE';
    PBT_APMRESUMEAUTOMATIC    : LTypeText := 'PBT_APMRESUMEAUTOMATIC';
    PBT_APMRESUMESUSPEND      : LTypeText := 'PBT_APMRESUMESUSPEND';
    PBT_APMSUSPEND            : LTypeText := 'PBT_APMSUSPEND';
    PBT_POWERSETTINGCHANGE    : LTypeText := 'PBT_POWERSETTINGCHANGE';
  end;
  Message.Result := Ord(True);

  Memo1.Lines.Add(LTypeText);
end;

end.

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, 
  Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
    FPowerNotify : HPOWERNOTIFY;
  end;


  function SetSuspendState(bHibernate: Boolean;
                           bForce: Boolean;
                           bWakeupEventsDisabled: Boolean): Boolean;
                           stdcall; external 'PowrProf.dll';

  function PowerRegisterSuspendResumeNotification(Flags : DWORD;
                           Recipient : PHandle;
                           RegistrationHandle : PHPOWERNOTIFY): DWORD; 
                           stdcall; external 'Powrprof.dll';

  function PowerUnregisterSuspendResumeNotification(
                           RegistrationHandle : HPOWERNOTIFY): DWORD; 
                           stdcall; external 'Powrprof.dll';

  function DeviceNotifyCallbackRoutine(Context: PVOID; AType: ULONG;
    Setting: PVOID): ULONG; stdcall;

var
  Form1: TForm1;

const
  DEVICE_NOTIFY_CALLBACK = 2;


implementation

{$R *.dfm}

type
  //--------------------------------------------------------
  //  DEVICE_NOTIFY_SUBSCRIBE_PARAMETERS レコード型の定義
  //--------------------------------------------------------
  DEVICE_NOTIFY_SUBSCRIBE_PARAMETERS = record
    ACallback : Pointer;
    AContext  : PVOID;
  end;
  PDEVICE_NOTIFY_SUBSCRIBE_PARAMETERS = ^DEVICE_NOTIFY_SUBSCRIBE_PARAMETERS;

//=============================================================================
//  フォーム生成時の処理
//
//  本サンプルは Windows 8 以降用
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  LParameters : DEVICE_NOTIFY_SUBSCRIBE_PARAMETERS;
begin
  // 関数の第 1 引数のパラメータを設定
  // コールバックに渡す値はないので nil としている
  LParameters.ACallback := @DeviceNotifyCallbackRoutine;
  LParameters.AContext := nil;

  // システムのスタンバイ・休止関係の状態変更メッセージの受信設定
  // コールバック関数で受信する場合
  PowerRegisterSuspendResumeNotification(DEVICE_NOTIFY_CALLBACK,
                                         @LParameters,
                                         @FPowerNotify);
end;

//=============================================================================
//  フォーム破棄時の処理
//=============================================================================
procedure TForm1.FormDestroy(Sender: TObject);
begin
  // システムのスタンバイ・休止関係の状態変更メッセージの受信設定を解除
  PowerUnregisterSuspendResumeNotification(FPowerNotify);
end;

//=============================================================================
//  コンピュータをスリープ状態にする
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  Memo1.Lines.Clear;
  SetSuspendState(False, False, False);
end;

//----------------------------------------------------------------------------
//  PowerRegisterSuspendResumeNotification 関数のコールバック関数
//----------------------------------------------------------------------------
function DeviceNotifyCallbackRoutine(Context: PVOID; AType: ULONG;
  Setting: PVOID): ULONG; stdcall;
var
  LTypeText: string;
begin
  case AType of
    PBT_APMPOWERSTATUSCHANGE  : LTypeText := 'PBT_APMPOWERSTATUSCHANGE';
    PBT_APMRESUMEAUTOMATIC    : LTypeText := 'PBT_APMRESUMEAUTOMATIC';
    PBT_APMRESUMESUSPEND      : LTypeText := 'PBT_APMRESUMESUSPEND';
    PBT_APMSUSPEND            : LTypeText := 'PBT_APMSUSPEND';
    PBT_POWERSETTINGCHANGE    : LTypeText := 'PBT_POWERSETTINGCHANGE';
  end;

  Form1.Memo1.Lines.Add(LTypeText);

  Result := 0;
end;

end.

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, 
  Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
    FPowerNotify : HPOWERNOTIFY;
  end;

  function SetSuspendState(bHibernate: Boolean;
                           bForce: Boolean;
                           bWakeupEventsDisabled: Boolean): Boolean;
                           stdcall; external 'PowrProf.dll';

  function RegisterSuspendResumeNotification(hRecipient : PHandle;
                           Flags : DWORD): HPOWERNOTIFY;
                           stdcall; external 'User32.dll';

  function UnregisterSuspendResumeNotification(
                           RegistrationHandle : HPOWERNOTIFY): BOOL;

                           stdcall; external 'User32.dll';
  function DeviceNotifyCallbackRoutine(Context: PVOID; AType: ULONG;
    Setting: PVOID): ULONG; stdcall;

var
  Form1: TForm1;

const
  DEVICE_NOTIFY_CALLBACK = 2;

implementation

{$R *.dfm}

type
  //--------------------------------------------------------
  //  DEVICE_NOTIFY_SUBSCRIBE_PARAMETERS レコード型の定義
  //--------------------------------------------------------
  DEVICE_NOTIFY_SUBSCRIBE_PARAMETERS = record
    ACallback : Pointer;
    AContext  : PVOID;
  end;
  PDEVICE_NOTIFY_SUBSCRIBE_PARAMETERS = ^DEVICE_NOTIFY_SUBSCRIBE_PARAMETERS;

//=============================================================================
//  フォーム生成時の処理
//
//  本サンプルは Windows 8 以降用
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  LParameters : DEVICE_NOTIFY_SUBSCRIBE_PARAMETERS;
begin
  // 関数の第 1 引数のパラメータを設定
  // コールバックに渡す値はないので nil としている 
  LParameters.ACallback := @DeviceNotifyCallbackRoutine;
  LParameters.AContext  := nil;

  // システムのスタンバイ・休止関係の状態変更メッセージの受信設定
  // コールバック関数で受信する場合
  FPowerNotify := RegisterSuspendResumeNotification(@LParameters,
                                                    DEVICE_NOTIFY_CALLBACK);
end;

//=============================================================================
//  フォーム破棄時の処理
//=============================================================================
procedure TForm1.FormDestroy(Sender: TObject);
begin
  // システムのスタンバイ・休止関係の状態変更メッセージの受信設定を解除
  UnregisterSuspendResumeNotification(FPowerNotify);
end;

//=============================================================================
//  コンピュータをスリープ状態にする
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  Memo1.Lines.Clear;
  SetSuspendState(False, False, False);
end;

//----------------------------------------------------------------------------
//  RegisterSuspendResumeNotification 関数のコールバック関数
//----------------------------------------------------------------------------
function DeviceNotifyCallbackRoutine(Context: PVOID; AType: ULONG;
  Setting: PVOID): ULONG; stdcall;
var
  LTypeText: string;
begin
  case AType of
    PBT_APMPOWERSTATUSCHANGE  : LTypeText := 'PBT_APMPOWERSTATUSCHANGE';
    PBT_APMRESUMEAUTOMATIC    : LTypeText := 'PBT_APMRESUMEAUTOMATIC';
    PBT_APMRESUMESUSPEND      : LTypeText := 'PBT_APMRESUMESUSPEND';
    PBT_APMSUSPEND            : LTypeText := 'PBT_APMSUSPEND';
    PBT_POWERSETTINGCHANGE    : LTypeText := 'PBT_POWERSETTINGCHANGE';
  end;

  Form1.Memo1.Lines.Add(LTypeText);

  Result := 0;
end;

end.

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, 
  Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  protected
    procedure WMPowerbroadcast(var Message: TMessage);
      message WM_POWERBROADCAST;
  private
    { Private 宣言 }
    FPowerNotify : HPOWERNOTIFY;
  public
    { Public 宣言 }
  end;

  function SetSuspendState(bHibernate: Boolean;
                           bForce: Boolean;
                           bWakeupEventsDisabled: Boolean): Boolean;
                           stdcall; external 'PowrProf.dll';

  function RegisterSuspendResumeNotification(hRecipient : PHandle;
                           Flags : DWORD): HPOWERNOTIFY;
                           stdcall; external 'User32.dll';

  function UnregisterSuspendResumeNotification(
                           RegistrationHandle : HPOWERNOTIFY): BOOL;
                           stdcall; external 'User32.dll';

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//
//  本サンプルは Windows 8 以降用
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  // システムのスタンバイ・休止関係の状態変更メッセージの受信設定
  // このフォームで受信する場合
  FPowerNotify := RegisterSuspendResumeNotification(PHandle(Self.Handle),
                                                    DEVICE_NOTIFY_WINDOW_HANDLE);
end;

//=============================================================================
//  フォーム破棄時の処理
//=============================================================================
procedure TForm1.FormDestroy(Sender: TObject);
begin
  // システムのスタンバイ・休止関係の状態変更メッセージの受信設定を解除
  UnregisterSuspendResumeNotification(FPowerNotify);
end;

//=============================================================================
//  コンピュータをスリープ状態にする
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  Memo1.Lines.Clear;
  SetSuspendState(False, False, False);
end;

//=============================================================================
//  WM_POWERBROADCAST メッセージ処理
//=============================================================================
procedure TForm1.WMPowerbroadcast(var Message: TMessage);
var
  LTypeText: string;
begin
  case Message.WParam of
    PBT_APMPOWERSTATUSCHANGE  : LTypeText := 'PBT_APMPOWERSTATUSCHANGE';
    PBT_APMRESUMEAUTOMATIC    : LTypeText := 'PBT_APMRESUMEAUTOMATIC';
    PBT_APMRESUMESUSPEND      : LTypeText := 'PBT_APMRESUMESUSPEND';
    PBT_APMSUSPEND            : LTypeText := 'PBT_APMSUSPEND';
    PBT_POWERSETTINGCHANGE    : LTypeText := 'PBT_POWERSETTINGCHANGE';
  end;

  Memo1.Lines.Add(LTypeText);
end;

end.

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,
  Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  JwaPowrProf,
  JwaWinNT,
  Diagnostics,
  DateUtils;

{$R *.dfm}

//=============================================================================
//  最後にスリープになった日時と最後にスリープから復帰した日時を表示
//
//  uses に JwaPowrProf, JwaWinNT, Diagnostics,DateUtils が必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LSleepTime : Int64;
  LWakeTime  : Int64;
  LNowTime   : Int64;
  LDateTime  : TDateTime;
  LFormatStr : string;
begin
  Memo1.Lines.Clear;

  // 第 1 引数に取得する情報のタイプを指定して CallNtPowerInformation 関数を実行
  CallNtPowerInformation(LastSleepTime, nil, 0, @LSleepTime, SizeOf(LSleepTime));
  CallNtPowerInformation(LastWakeTime, nil, 0, @LWakeTime, SizeOf(LWakeTime));

  // 取得した値はシステムが起動してからの 100 ns 単位なので秒単位の値にする
  LSleepTime := LSleepTime div 10000000;
  LWakeTime  := LWakeTime div 10000000;
  LNowTime   := TStopWatch.GetTimeStamp div 10000000;

  LFormatStr := 'yyyy/mm/dd hh:nn:ss';

  // 最後にスリープ状態にした日時に換算
  LDateTime := IncSecond(Now, LSleepTime - LNowTime);
  Memo1.Lines.Add('LastSleepTime : ' + FormatDateTime(LFormatStr, LDateTime));

  // 最後にスリープから復帰した日時に換算
  LDateTime := IncSecond(Now, LWakeTime - LNowTime);
  Memo1.Lines.Add('LastWakeTime  : ' + FormatDateTime(LFormatStr, LDateTime));
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    Button5: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure Button5Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  plPrivilegeUnit;

{$R *.dfm}

//=============================================================================
//  コンピュータのロック
//  ログイン画面になる
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  LockWorkStation;
end;

//=============================================================================
//  ログオフする
//  EWX_FORCE は強制実行のフラグ
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  ExitWindowsEx(EWX_LOGOFF or EWX_FORCE, 0);
end;

//=============================================================================
//  再起動する
//  EWX_FORCE は強制実行のフラグ
//  実行には SE_SHUTDOWN_NAME の特権が必要
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
begin
  plPrivilegeUnit.SetPrivilege(SE_SHUTDOWN_NAME, True);
  try
    ExitWindowsEx(EWX_REBOOT or EWX_FORCE, 0);
  finally
    plPrivilegeUnit.SetPrivilege(SE_SHUTDOWN_NAME, False);
  end;
end;

//=============================================================================
//  シャットダウン
//  実行には SE_SHUTDOWN_NAME の特権が必要
//=============================================================================
procedure TForm1.Button4Click(Sender: TObject);
begin
  plPrivilegeUnit.SetPrivilege(SE_SHUTDOWN_NAME, True);
  try
    ExitWindowsEx(EWX_SHUTDOWN, 0);
  finally
    plPrivilegeUnit.SetPrivilege(SE_SHUTDOWN_NAME, False);
  end;
end;

//=============================================================================
//  強制シャットダウン
//  実行には SE_SHUTDOWN_NAME の特権が必要
//=============================================================================
procedure TForm1.Button5Click(Sender: TObject);
begin
  plPrivilegeUnit.SetPrivilege(SE_SHUTDOWN_NAME, True);
  try
    ExitWindowsEx(EWX_SHUTDOWN or EWX_FORCE, 0);
  finally
    plPrivilegeUnit.SetPrivilege(SE_SHUTDOWN_NAME, False);
  end;
end;

end.

implementation

uses
  plPrivilegeUnit;

{$R *.dfm}

//=============================================================================
//  シャットダウンのダイアログを表示して指定時間(秒)後 にシャットダウン
//  uses に plPrivilegeUnit が必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  plPrivilegeUnit.SetPrivilege(SE_SHUTDOWN_NAME, True);
  InitiateSystemShutdown(nil, nil, 30, True, False);
end;

//=============================================================================
//  シャットダウンの中止
//
//  AbortSystemShutdown は InitiateSystemShutdown,InitiateSystemShutdownEx 
//  で開始したシャットダウンを中止する関数
//  他の方法で開始したシャットダウンはキャンセルできない
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  AbortSystemShutdown(nil);
end;

  function RestartDialog(AhWnd: HWND;
                         pszPromt: PChar;
                         dwReturn: DWORD): Integer; stdcall; external 'shell32';

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  再起動を確認するダイアログを表示
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LRet : Integer;
begin
  LRet := RestartDialog(Handle, '', EWX_REBOOT);
  if LRet = IDNO then begin
    // 後で再起動する場合
  end;
end;

//=============================================================================
//  シャットダウンを確認するダイアログを表示
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LRet : Integer;
begin
  LRet := RestartDialog(Handle, '', EWX_SHUTDOWN);
  if LRet = IDNO then begin
    // キャンセルした場合
  end;
end;

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,
  Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);
  protected
    procedure WMQueryEndSession(var Message: TWMQueryEndSession);
      message WM_QUERYENDSESSION;
  private
    { Private 宣言 }
    FFlagEndSession : Boolean;
    FEndSession     : Cardinal;
  public
    { Public 宣言 }
  end;

  function ShutdownBlockReasonCreate(AhWnd: HWND; pwszReason: LPCWSTR): BOOL;
    stdcall; external 'user32';
  function ShutdownBlockReasonDestroy(AhWnd: HWND): BOOL; stdcall; external 'user32';

var
  Form1: TForm1;

implementation

uses
  MMSystem;

{$R *.dfm}

//=============================================================================
//  WM_QUERYENDSESSION メッセージの処理
//
//  ここには数秒以上の処理コードを書かないこと(マイクロソフトの記事による)
//  Delphi には OnCloseQuery という便利なイベントがある
//=============================================================================
procedure TForm1.WMQueryEndSession(var Message: TWMQueryEndSession);
begin
  // ログオフやシャットダウンの種類
  // 変数の型はCardinal(32 ビット値) とする
  // Cardinal 型の変数でないと ENDSESSION_XXX との比較が正しくできない
  FEndSession := Message.Unused;

  if (FEndSession = 0) then begin
    Message.Result := LRESULT(False);
  end;

  // このメッセージ受信のフラグ
  FFlagEndSession := True;

  // この inherited で OnCloseQuery イベントが実行される
  inherited;
end;

//=============================================================================
//  フォームの OnCloseQuery イベントの処理
//  シャットダウンとログオフの検出
//=============================================================================
procedure TForm1.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
var
  LTimeStart : Cardinal;
  LOldValue  : Integer;
  LNewValue  : Integer;
begin
  if FFlagEndSession then begin
    FFlagEndSession := false;
    // 0 の時はシャットダウンか再起動
    // シャットダウンと再起動の区別はできない
    if FEndSession = 0 then begin
      //
    end else
    // 強制シャットダウン
    if FEndSession = ENDSESSION_CRITICAL then begin
      //
    end else
    // ログオフ
    if FEndSession = ENDSESSION_LOGOFF then begin
      //
    end;

    //
    // ここか上のどこかに Windows が終了する時の処理を書く

    LTimeStart := timeGetTime;
    //指定時間経過したら終了
    LOldValue := 0;
    while True do begin
      LNewValue := (timeGetTime - LTimeStart) div 1000;
      if LOldValue < LNewValue then begin
        LOldValue := LNewValue;
        Memo1.Lines.Add(IntToStr(LNewValue));
      end;
      if LNewValue >= 90 then Break;

      Application.ProcessMessages;
      Sleep(1);
    end;
    //
    //
  end;

  if CanClose then begin
    //
    // フォームを閉じる時の処理コード
    //
  end;
end;

end.

    ShutdownBlockReasonCreate(Handle, 'Delphi 処理中');

    LTimeStart := timeGetTime;
    //指定時間経過したら終了
    LOldValue := 0;
    while True do begin
      LNewValue := (timeGetTime - LTimeStart) div 1000;
      if LOldValue < LNewValue then begin
        LOldValue := LNewValue;
        Memo1.Lines.Add(IntToStr(LNewValue));
      end;
      if LNewValue >= 90 then Break;

      Application.ProcessMessages;
      Sleep(1);
    end;

    ShutdownBlockReasonDestroy(Handle);

    LTimeStart := timeGetTime;
    //指定時間経過したら終了
    LOldValue := 0;
    while True do begin
      LNewValue := (timeGetTime - LTimeStart) div 1000;
      if LOldValue < LNewValue then begin
        LOldValue := LNewValue;
        Memo1.Lines.Add(IntToStr(LNewValue));

        LText := '処理中 : ' + IntToStr(LNewValue) + ' / 90 秒経過';
        ShutdownBlockReasonCreate(Handle, PChar(LText));
      end;
      if LNewValue >= 90 then Break;

      Application.ProcessMessages;
      Sleep(1);
    end;

    ShutdownBlockReasonDestroy(Handle);

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,
  Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    Button1: TButton;
    Button2: TButton;
    procedure FormCreate(Sender: TObject);
    procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
    FCancelFlag : Boolean;
    FCloseEvent : Boolean;
  public
    { Public 宣言 }
  end;

  function ShutdownBlockReasonCreate(AhWnd: HWND; pwszReason: LPCWSTR): BOOL;
    stdcall; external 'user32';
  function ShutdownBlockReasonDestroy(AhWnd: HWND): BOOL; stdcall; external 'user32';

var
  Form1: TForm1;

implementation

uses
  MMSystem;

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  // 初期状態ではフォームを閉じる設定
  FCancelFlag := True;
  // フォームを閉じる時の処理の有無(初期状態ではなし)
  // 時間のかかる処理を実行する前にこのフラグを True にしておく
  FCloseEvent := False;
end;

//=============================================================================
//  フォームの OnCloseQuery イベントの処理
//  システムのシャットダウン時にはメインフォームが閉じる
//  フォームが閉じる時はこのイベントが実行される
//=============================================================================
procedure TForm1.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
begin
  // このイベント通過フラグ
  FCloseEvent := True;
  // 時間のかかる処理が実行中の時は FCloseFlag は Falseになっている
  CanClose := FCancelFlag;

  if CanClose then begin
    // フォームを閉じる時のその他の処理
  end;
end;

//=============================================================================
//  [処理開始] ボタン
//  時間のかかる処理の例としてのコード
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LTimeStart : Cardinal;
  LOldValue  : Integer;
  LNewValue  : Integer;
begin
  Memo1.Lines.Clear;

  // フォームを閉じないようにフラグを False にする
  FCancelFlag := False;

  // シャットダウン画面に表示するテキスト
  ShutdownBlockReasonCreate(Handle, '処理中です。お待ちください');

  LTimeStart := timeGetTime;
  //指定時間経過したら終了
  LOldValue := 0;
  while True do begin
    LNewValue := (timeGetTime - LTimeStart) div 1000;
    if LOldValue < LNewValue then begin
      LOldValue := LNewValue;
      Memo1.Lines.Add(IntToStr(LNewValue));
    end;

    if LNewValue >= 90 then Break;
    // [処理中止] ボタンをクリックした時の処理
    if FCancelFlag then Break;

    Application.ProcessMessages;
    Sleep(1);
  end;

  // シャットダウン画面に表示するテキストをデフォルトに戻す
  ShutdownBlockReasonDestroy(Handle);

  // フォームを閉じても OK のフラグをセット
  FCancelFlag := True;
  // 上のコードを実行中に OnCloseQuery イベントが発生した場合
  // FCancelFlag を True にして再度 Close すればフォームが閉じる
  // 処理終了後またはキャンセル時にフォームを閉じる必要がなければこのコードは不要
  if FCloseEvent then Close;
end;

//=============================================================================
//  [処理中止] ボタン
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  // 処理のキャンセルフラグをセット
  FCancelFlag := True;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button5: TButton;
    Button3: TButton;
    Button4: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure Button5Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  ShellAPI;

{$R *.dfm}

//=============================================================================
//  モニタ(ディスプレイ)の電源を切るまでの時間を設定
//
//  uses にShellAPI が必要 
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LCmdExe : string;
  LOption : string;
begin
  LCmdExe := 'powercfg.exe';
  LOption := '/CHANGE monitor-timeout-ac 5';
  ShellExecute(Handle, '', PChar(LCmdExe), PChar(LOption), nil, SW_HIDE);
end;

//=============================================================================
//  システムがスリープ(スタンバイ)状態になるまでの時間を設定
//
//  uses にShellAPI が必要 
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LCmdExe : string;
  LOption : string;
begin
  LCmdExe := 'powercfg.exe';
  LOption := '/CHANGE standby-timeout-ac 20';
  ShellExecute(Handle, '', PChar(LCmdExe), PChar(LOption), nil, SW_HIDE);
end;

//=============================================================================
//  モニタ(ディスプレイ)の電源を切らない設定
//  タイムアウト時間を 0 にすれば無効となる
//  電源オプションの設定ダイアログでは表示が [なし] になる
//
//  uses にShellAPI が必要 
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
var
  LCmdExe : string;
  LOption : string;
begin
  LCmdExe := 'powercfg.exe';
  LOption := '/CHANGE monitor-timeout-ac 0';
  ShellExecute(Handle, '', PChar(LCmdExe), PChar(LOption), nil, SW_HIDE);
end;

//=============================================================================
//  モニタの電源を切るまでの時間とシステムがスリープ状態になるまでの時間を設定
//
//  uses にShellAPI が必要 
//=============================================================================
procedure TForm1.Button4Click(Sender: TObject);
var
  LCmdExe : string;
  LOption : string;
begin
  LCmdExe := 'powercfg.exe';
  LOption := '/CHANGE monitor-timeout-ac 20';
  ShellExecute(Handle, '', PChar(LCmdExe), PChar(LOption), nil, SW_HIDE);

  LOption := '/CHANGE standby-timeout-ac 60';
  ShellExecute(Handle, '', PChar(LCmdExe), PChar(LOption), nil, SW_HIDE);
end;

//=============================================================================
//  電源オプションの設定ダイアログを表示
//  設定した内容の確認用
//
//  uses にShellAPI が必要 
//=============================================================================
procedure TForm1.Button5Click(Sender: TObject);
var
  LCmdExe : string;
  LOption : string;
begin
  LCmdExe := 'control.exe';
  LOption := '/name Microsoft.PowerOptions /page pagePlanSettings';
  ShellExecute(Handle, '', PChar(LCmdExe), PChar(LOption), nil, SW_SHOW);
end;


end.

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,
  Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
    procedure GetTimeOutValue(var AMonitorTime: DWORD; var ASystemTime: DWORD);
    procedure SetTimeOutValue(AMonitorTime: DWORD; ASystemTime: DWORD);
  public
    { Public 宣言 }
  end;

  function PowerGetActiveScheme(UserRootPowerKey : HKEY;
                                var ActivePolicyGuid : PGUID): DWORD;
                                stdcall; external 'PowrProf.dll';

  function PowerReadACValueIndex(RootPowerKey : HKEY;
                                 const SchemeGuid : PGUID;
                                 const SubGroupOfPowerSettingsGuid : PGUID;
                                 const PowerSettingGuid : PGUID;
                                 AcValueIndex : LPDWORD): DWORD;
                                 stdcall; external 'powrprof.dll';

  function PowerWriteACValueIndex(RootPowerKey : HKEY;
                                  const SchemeGuid : PGUID;
                                  const SubGroupOfPowerSettingsGuid : PGUID;
                                  const PowerSettingGuid : PGUID;
                                  AcValueIndex : DWORD): DWORD;
                                  stdcall; external 'powrprof.dll'

var
  Form1: TForm1;

implementation

{$R *.dfm}

const
  // 操作対象の GUID 値に定数名を設定
  // 設定する名前は任意(MSDNの記事には定数名の記述がある)
  GUID_SUB_DISPLAY       : TGUID = '{7516b95f-f776-4464-8c53-06167f40cc99}';
  GUID_SUB_DISPLAY_POWER : TGUID = '{3c0bc021-c8a8-4e07-a973-6b14cbcb2b7e}';
  GUID_SUB_SLEEP         : TGUID = '{238c9fa8-0aad-41ed-83f4-97be242c8f20}';
  GUID_SUB_SLEEP_TIMEOUT : TGUID = '{29f6c1db-86da-48c5-9fdb-f2b67b1f44da}';

//=============================================================================
//  現在の電源関係の設定値を取得
//  ここではモニタの電源 OFF とシステムのスリープ開始までのタイムアウトの時間
//  時間の単位は秒
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LTime1 : DWORD;
  LTime2 : DWORD;
begin
  GetTimeOutValue(LTime1, LTime2);

  Memo1.Lines.Clear;
  Memo1.Lines.Add(IntToStr(LTime1) + ' sec ($' + IntToHex(LTime1, 8) + ')');
  Memo1.Lines.Add(IntToStr(LTime2) + ' sec ($' + IntToHex(LTime2, 8) + ')');
end;

//=============================================================================
//  電源関係の値を設定
//  ここではモニタの電源 OFF とシステムのスリープ開始までのタイムアウトの時間
//  時間の単位は秒
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  SetTimeOutValue(10 * 60, 120 * 60);

  // 確認のため設定値を取得して表示
  Button1Click(nil);
end;

//-----------------------------------------------------------------------------
//  モニタの電源 OFF とシステムのスリープ開始までの時間を取得
//
//  PowerGetActiveScheme 関数の引数 (AC は AC 電源用)
//  第 1 引数 : 常に 0
//  第 2 引数 : 取得対象の電源設定の GUID 値
//  第 3 引数 : 電源設定 GUID のサブグループの GUID 値
//  第 4 引数 : サブグループ階層下の取得対象の GUID 値
//  第 5 引数 : 取得するインデックスの値を格納する変数
//              4 バイトの符号なし整数変数のポインタ
//-----------------------------------------------------------------------------
procedure TForm1.GetTimeOutValue(var AMonitorTime: DWORD; var ASystemTime: DWORD);
var
  LpActiveGuid : PGUID;
  LTimeOut     : DWORD;
begin
  AMonitorTime := 0;
  ASystemTime  := 0;

  LpActiveGuid := nil;
  try
    // 現在アクティブな電源設定の GUID 値を取得
    // 別の電源プランの設定値を取得する場合はこの GUID の値を変える
    if PowerGetActiveScheme(0, LpActiveGuid) <> 0 then Exit;

    // ディスプレイの電源を切るまでの時間を取得(単位は秒)
    if PowerReadACValueIndex(0,
                             LpActiveGuid,
                             @GUID_SUB_DISPLAY,
                             @GUID_SUB_DISPLAY_POWER,
                             @LTimeOut) = ERROR_SUCCESS then begin
      AMonitorTime := LTimeOut;
    end else begin
      AMonitorTime := 0;
    end;

    // システムをスリープ状態にするまでの時間を取得(単位は秒)
    if PowerReadACValueIndex(0,
                             LpActiveGuid,
                             @GUID_SUB_SLEEP,
                             @GUID_SUB_SLEEP_TIMEOUT,
                             @LTimeOut) = ERROR_SUCCESS then begin
      ASystemTime := LTimeOut;
    end else begin
      ASystemTime := 0;
    end;
  finally
    LocalFree(HLOCAL(LpActiveGuid));
  end;
end;

//-----------------------------------------------------------------------------
//  モニタの電源 OFF とシステムのスリープ開始までの時間を設定
//
//  PowerWriteACValueIndex 関数の引数 (AC は AC 電源用)
//  第 1 引数 : 常に 0
//  第 2 引数 : 設定対象の電源設定の GUID 値
//  第 3 引数 : 電源設定 GUID のサブグループの GUID 値
//  第 4 引数 : サブグループ階層下の設定対象の GUID 値
//  第 5 引数 : 設定するインデックスの値
//              4 バイトの符号なし整数変数
//-----------------------------------------------------------------------------
procedure TForm1.SetTimeOutValue(AMonitorTime, ASystemTime: DWORD);
var
  LpActiveGuid : PGUID;
begin
  LpActiveGuid := nil;
  try
    // 現在アクティブな電源設定の GUID 値を取得
    // 別の電源プランの設定値を変更する場合はこの GUID の値を変える
    if PowerGetActiveScheme(0, LpActiveGuid) <> 0 then Exit;

    // ディスプレイの電源を切るまでの時間を設定(単位は秒)
    PowerWriteACValueIndex(0,
                           LpActiveGuid,
                           @GUID_SUB_DISPLAY,
                           @GUID_SUB_DISPLAY_POWER,
                           AMonitorTime);

    // システムをスリープ状態にするまでの時間を設定(単位は秒)
    PowerWriteACValueIndex(0,
                           LpActiveGuid,
                           @GUID_SUB_SLEEP,
                           @GUID_SUB_SLEEP_TIMEOUT,
                           ASystemTime);
  finally
    LocalFree(HLOCAL(LpActiveGuid));
  end;
end;

end.

procedure TForm1.Button1Click(Sender: TObject);
var
  LPwrStatus   : TSystemPowerStatus;
  LAcLinStatus : Byte;
begin
  GetSystemPowerStatus(LPwrStatus);
  LAcLinStatus := LPwrStatus.ACLineStatus;

  if LAcLinStatus = 0 then begin
    // AC 電源オフライン(バッテリー動作)
  end else
  if LAcLinStatus = 1 then begin
    // AC 電源オンライン
  end else begin
    // AC 電源の状態は不明
  end;
end;

Microsoft Windows [Version 6.1.7601]
Copyright (c) 2009 Microsoft Corporation.  All rights reserved.

d:\>powercfg.exe /Q 381b4222-f694-41f0-9685-ff5bb260df2e
電源設定の GUID: 381b4222-f694-41f0-9685-ff5bb260df2e  (バランス)
  サブグループの GUID: fea3413e-7e05-4911-9a71-700331f1c294  (どのサブグループに
も属さない設定)
    電源設定の GUID: 0e796bdb-100d-47d6-a2d5-f7d2daa51f51  (復帰時のパスワードを
必要とする)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: いいえ
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: はい
    現在の AC 電源設定のインデックス: 0x00000001
    現在の DC 電源設定のインデックス: 0x00000001

  サブグループの GUID: 0012ee47-9041-4b5d-9b77-535fba8b1442  (ハード ディスク)
    電源設定の GUID: 6738e2c4-e8a5-4a42-b16a-e040e769756e  (次の時間が経過後ハー
ド ディスクの電源を切る)
      利用可能な設定の最小値: 0x00000000
      利用可能な設定の最大値: 0xffffffff
      利用可能な設定の増分: 0x00000001
      利用可能な設定の単位: 秒
    現在の AC 電源設定のインデックス: 0x000004b0
    現在の DC 電源設定のインデックス: 0x00000258

  サブグループの GUID: 02f815b5-a5cf-4c84-bf20-649d1f75d3d8  (Internet Explorer)

    電源設定の GUID: 4c793e7d-a264-42e1-87d3-7a0d2f523ccd  (JavaScript タイマー
の間隔)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: 最大限の省電力
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: 最大パフォーマンス
    現在の AC 電源設定のインデックス: 0x00000001
    現在の DC 電源設定のインデックス: 0x00000000

  サブグループの GUID: 0d7dbae2-4294-402a-ba8e-26777e8488cd  (デスクトップの背景
の設定)
    電源設定の GUID: 309dce9b-bef4-4119-9921-a851fb12f0f4  (スライド ショー)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: 有効
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: 一時停止
    現在の AC 電源設定のインデックス: 0x00000000
    現在の DC 電源設定のインデックス: 0x00000001

  サブグループの GUID: 19cbb8fa-5279-450e-9fac-8a3d5fedd0c1  (ワイヤレス アダプ
ターの設定)
    電源設定の GUID: 12bbebe6-58d6-4636-95bb-3217ef867c1a  (省電力モード)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: 最大パフォーマンス
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: 省電力 (低)
      利用可能な設定のインデックス: 002
      利用可能な設定のフレンドリ名: 省電力 (中)
      利用可能な設定のインデックス: 003
      利用可能な設定のフレンドリ名: 省電力 (高)
    現在の AC 電源設定のインデックス: 0x00000000
    現在の DC 電源設定のインデックス: 0x00000002

  サブグループの GUID: 238c9fa8-0aad-41ed-83f4-97be242c8f20  (スリープ)
    電源設定の GUID: 29f6c1db-86da-48c5-9fdb-f2b67b1f44da  (次の時間が経過後スリ
ープする)
      利用可能な設定の最小値: 0x00000000
      利用可能な設定の最大値: 0xffffffff
      利用可能な設定の増分: 0x00000001
      利用可能な設定の単位: 秒
    現在の AC 電源設定のインデックス: 0x00000e10
    現在の DC 電源設定のインデックス: 0x00000384

    電源設定の GUID: 94ac6d29-73ce-41a6-809f-6363ba21b47e  (ハイブリッド スリー
プを許可する)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: オフ
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: オン
    現在の AC 電源設定のインデックス: 0x00000001
    現在の DC 電源設定のインデックス: 0x00000001

    電源設定の GUID: 9d7815a6-7ee4-497e-8888-515a05f02364  (次の時間が経過後休止
状態にする)
      利用可能な設定の最小値: 0x00000000
      利用可能な設定の最大値: 0xffffffff
      利用可能な設定の増分: 0x00000001
      利用可能な設定の単位: 秒
    現在の AC 電源設定のインデックス: 0x00000000
    現在の DC 電源設定のインデックス: 0x00000000

    電源設定の GUID: bd3b718a-0680-4d9d-8ab2-e1d2b4ac806d  (スリープ解除タイマー
の許可)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: 無効
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: 有効
    現在の AC 電源設定のインデックス: 0x00000001
    現在の DC 電源設定のインデックス: 0x00000001

  サブグループの GUID: 2a737441-1930-4402-8d77-b2bebba308a3  (USB 設定)
    電源設定の GUID: 48e6b7a6-50f5-4782-a5d4-53bb8f07e226  (USB のセレクティブ
サスペンドの設定)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: 無効
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: 有効
    現在の AC 電源設定のインデックス: 0x00000001
    現在の DC 電源設定のインデックス: 0x00000001

  サブグループの GUID: 4f971e89-eebd-4455-a8de-9e59040e7347  (電源ボタンとカバー
)
    電源設定の GUID: 5ca83367-6e45-459f-a27b-476b1d01c936  (カバーを閉じたときの
操作)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: 何もしない
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: スリープ
      利用可能な設定のインデックス: 002
      利用可能な設定のフレンドリ名: 休止状態
      利用可能な設定のインデックス: 003
      利用可能な設定のフレンドリ名: シャットダウン
    現在の AC 電源設定のインデックス: 0x00000001
    現在の DC 電源設定のインデックス: 0x00000001

    電源設定の GUID: 7648efa3-dd9c-4e3e-b566-50f929386280  (電源ボタンの操作)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: 何もしない
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: スリープ
      利用可能な設定のインデックス: 002
      利用可能な設定のフレンドリ名: 休止状態
      利用可能な設定のインデックス: 003
      利用可能な設定のフレンドリ名: シャットダウン
    現在の AC 電源設定のインデックス: 0x00000003
    現在の DC 電源設定のインデックス: 0x00000003

    電源設定の GUID: 96996bc0-ad50-47ec-923b-6f41874dd9eb  (スリープ ボタンの操
作)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: 何もしない
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: スリープ
      利用可能な設定のインデックス: 002
      利用可能な設定のフレンドリ名: 休止状態
      利用可能な設定のインデックス: 003
      利用可能な設定のフレンドリ名: シャットダウン
    現在の AC 電源設定のインデックス: 0x00000001
    現在の DC 電源設定のインデックス: 0x00000001

    電源設定の GUID: a7066653-8d6c-40a8-910e-a1f54b84c7e5  ([スタート] メニュー
の電源ボタンの操作)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: スリープ
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: 休止状態
      利用可能な設定のインデックス: 002
      利用可能な設定のフレンドリ名: シャットダウン
    現在の AC 電源設定のインデックス: 0x00000000
    現在の DC 電源設定のインデックス: 0x00000000

  サブグループの GUID: 501a4d13-42af-4429-9fd1-a8218c268e20  (PCI Express)
    電源設定の GUID: ee12f906-d277-404b-b6da-e5fa1a576df5  (リンク状態の電源管理
)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: オフ
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: 適切な省電力
      利用可能な設定のインデックス: 002
      利用可能な設定のフレンドリ名: 最大限の省電力
    現在の AC 電源設定のインデックス: 0x00000001
    現在の DC 電源設定のインデックス: 0x00000002

  サブグループの GUID: 528259f7-7bae-4f30-8321-8afa6e155c4c  (GPU 設定)
  サブグループの GUID: 54533251-82be-4824-96c1-47b60b740d00  (プロセッサの電源管
理)
    電源設定の GUID: 893dee8e-2bef-41e0-89c6-b55d0929964c  (最小のプロセッサの状
態)
      利用可能な設定の最小値: 0x00000000
      利用可能な設定の最大値: 0x00000064
      利用可能な設定の増分: 0x00000001
      利用可能な設定の単位: %
    現在の AC 電源設定のインデックス: 0x00000005
    現在の DC 電源設定のインデックス: 0x00000005

    電源設定の GUID: 94d3a615-a899-4ac5-ae2b-e4d8f634367f  (システムの冷却ポリシ
ー)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: パッシブ
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: アクティブ
    現在の AC 電源設定のインデックス: 0x00000001
    現在の DC 電源設定のインデックス: 0x00000000

    電源設定の GUID: bc5038f7-23e0-4960-96da-33abaf5935ec  (最大のプロセッサの状
態)
      利用可能な設定の最小値: 0x00000000
      利用可能な設定の最大値: 0x00000064
      利用可能な設定の増分: 0x00000001
      利用可能な設定の単位: %
    現在の AC 電源設定のインデックス: 0x00000064
    現在の DC 電源設定のインデックス: 0x00000064

  サブグループの GUID: 7516b95f-f776-4464-8c53-06167f40cc99  (ディスプレイ)
    電源設定の GUID: 17aaa29b-8b43-4b94-aafe-35f64daaf1ee  (次の時間の経過後、デ
ィスプレイを暗くする)
      利用可能な設定の最小値: 0x00000000
      利用可能な設定の最大値: 0xffffffff
      利用可能な設定の増分: 0x00000001
      利用可能な設定の単位: 秒
    現在の AC 電源設定のインデックス: 0x0000012c
    現在の DC 電源設定のインデックス: 0x00000078

    電源設定の GUID: 3c0bc021-c8a8-4e07-a973-6b14cbcb2b7e  (次の時間が経過後ディ
スプレイの電源を切る)
      利用可能な設定の最小値: 0x00000000
      利用可能な設定の最大値: 0xffffffff
      利用可能な設定の増分: 0x00000001
      利用可能な設定の単位: 秒
    現在の AC 電源設定のインデックス: 0x000004b0
    現在の DC 電源設定のインデックス: 0x0000012c

    電源設定の GUID: aded5e82-b909-4619-9949-f5d71dac0bcb  (ディスプレイの明るさ
)
      利用可能な設定の最小値: 0x00000000
      利用可能な設定の最大値: 0x00000064
      利用可能な設定の増分: 0x00000001
      利用可能な設定の単位: %
    現在の AC 電源設定のインデックス: 0x00000064
    現在の DC 電源設定のインデックス: 0x00000028

    電源設定の GUID: f1fbfde2-a960-4165-9f88-50667911ce96  (ディスプレイ暗転時の
明るさ)
      利用可能な設定の最小値: 0x00000000
      利用可能な設定の最大値: 0x00000064
      利用可能な設定の増分: 0x00000001
      利用可能な設定の単位: %
    現在の AC 電源設定のインデックス: 0x0000001e
    現在の DC 電源設定のインデックス: 0x0000001e

  サブグループの GUID: 9596fb26-9850-41fd-ac3e-f7c3c00afd4b  (マルチメディアの設
定)
    電源設定の GUID: 03680956-93bc-4294-bba6-4e0f09bb717f  (メディアを共有するタ
イミング)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: コンピューターのスリープを許可する
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: アイドリングがスリープ状態になるのを回避する

      利用可能な設定のインデックス: 002
      利用可能な設定のフレンドリ名: コンピューターが退席中モードになるのを許可す
る
    現在の AC 電源設定のインデックス: 0x00000001
    現在の DC 電源設定のインデックス: 0x00000000

    電源設定の GUID: 34c7b99f-9a6d-4b3c-8dc7-b6693b78cef4  (ビデオの再生時)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: ビデオ品質の最適化
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: バランス
      利用可能な設定のインデックス: 002
      利用可能な設定のフレンドリ名: 省電力の最適化
    現在の AC 電源設定のインデックス: 0x00000000
    現在の DC 電源設定のインデックス: 0x00000001

  サブグループの GUID: e73a048d-bf27-4f12-9731-8b2076e8891f  (バッテリ)
    電源設定の GUID: 637ea02f-bbcb-4015-8e2c-a1c7b9c0b546  (バッテリ切れの操作)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: 何もしない
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: スリープ
      利用可能な設定のインデックス: 002
      利用可能な設定のフレンドリ名: 休止状態
      利用可能な設定のインデックス: 003
      利用可能な設定のフレンドリ名: シャットダウン
    現在の AC 電源設定のインデックス: 0x00000000
    現在の DC 電源設定のインデックス: 0x00000002

    電源設定の GUID: 8183ba9a-e910-48da-8769-14ae6dc1170a  (バッテリ低下のレベル
)
      利用可能な設定の最小値: 0x00000000
      利用可能な設定の最大値: 0x00000064
      利用可能な設定の増分: 0x00000001
      利用可能な設定の単位: %
    現在の AC 電源設定のインデックス: 0x0000000a
    現在の DC 電源設定のインデックス: 0x0000000a

    電源設定の GUID: 9a66d8d7-4ff7-4ef9-b5a2-5a326ca2a469  (バッテリ切れのレベル
)
      利用可能な設定の最小値: 0x00000000
      利用可能な設定の最大値: 0x00000064
      利用可能な設定の増分: 0x00000001
      利用可能な設定の単位: %
    現在の AC 電源設定のインデックス: 0x00000005
    現在の DC 電源設定のインデックス: 0x00000005

    電源設定の GUID: bcded951-187b-4d05-bccc-f7e51960c258  (バッテリ低下の通知)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: オフ
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: オン
    現在の AC 電源設定のインデックス: 0x00000001
    現在の DC 電源設定のインデックス: 0x00000001

    電源設定の GUID: d8742dcb-3e6a-4b3c-b3fe-374623cdcf06  (バッテリ低下の操作)
      利用可能な設定のインデックス: 000
      利用可能な設定のフレンドリ名: 何もしない
      利用可能な設定のインデックス: 001
      利用可能な設定のフレンドリ名: スリープ
      利用可能な設定のインデックス: 002
      利用可能な設定のフレンドリ名: 休止状態
      利用可能な設定のインデックス: 003
      利用可能な設定のフレンドリ名: シャットダウン
    現在の AC 電源設定のインデックス: 0x00000000
    現在の DC 電源設定のインデックス: 0x00000000

    電源設定の GUID: f3c5027d-cd16-4930-aa6b-90db844a8f00  (省電源移行バッテリ
レベル)
      利用可能な設定の最小値: 0x00000000
      利用可能な設定の最大値: 0x00000064
      利用可能な設定の増分: 0x00000001
      利用可能な設定の単位: %
    現在の AC 電源設定のインデックス: 0x00000007
    現在の DC 電源設定のインデックス: 0x00000007


d:\>

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,
  Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.ExtCtrls;

const
  WM_RESUME_NOTIFY = WM_APP + 10;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    Button2: TButton;
    Button3: TButton;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  protected
    procedure WMResumeNotiry(var Message: TMessage); message WM_RESUME_NOTIFY;
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

  procedure SetSystemWakeUpTimer(AHandle: THandle; ADateTime: TDateTime);
  procedure CancelSystemWakeUpTimer;
  function TDateTimeToUTCFileTime(ADateTime: TDateTime): Int64;

  function SetThreadExecutionState(esFlags: DWORD): DWORD; stdcall external 'kernel32.dll';

  function SetSuspendState(bHibernate: Boolean;
                         bForce: Boolean;
                         bWakeupEventsDisabled: Boolean): Boolean;
                         stdcall external 'PowrProf.dll';

var
  Form1: TForm1;

implementation

uses
  DateUtils;

{$R *.dfm}

const
  ES_SYSTEM_REQUIRED  = $00000001;
  ES_DISPLAY_REQUIRED = $00000002;
  ES_CONTINUOUS       = $80000000;

var
  FhWaitTimer  : THandle;
  FTimerThread : TThread;
  FFlagCancel  : Boolean;

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  // 待機可能タイマー関係変数の初期化
  // 実際にはグローバル変数なので以下の値が初期値となっている
  FhWaitTimer  := 0;
  FTimerThread := nil;
  FFlagCancel  := False;
end;

//=============================================================================
//  フォーム破棄時の処理
//=============================================================================
procedure TForm1.FormDestroy(Sender: TObject);
begin
  // 待機タイマーを無効にする
  CancelSystemWakeUpTimer;
end;

//=============================================================================
//  待機タイマーのセット
//  スリープ状態からの自動復帰の日時を設定
//
//  テストで日時を指定する場合,以下のようなコードでも指定可能
//  LDateTime := StrToDateTime('2019/01/08 07:00:00');
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LDateTime : TDateTime;
begin
  Memo1.Lines.Clear;

  // スリープからの自動復帰(レジューム)予定日時
  // 今の日時から指定時間後(単位は分)とする例
  LDateTime := IncMinute(Now, 3);

  // スリープからの自動復帰(レジューム)の時刻を表示
  Memo1.Lines.Add(FormatDateTime('yyyy/mm/dd hh:nn:ss', LDateTime));

  // 待機タイマーを起動
  SetSystemWakeUpTimer(Self.Handle, LDateTime);
end;

//=============================================================================
//  待機タイマーの処理を無効にする
//  タイマーをセットしたが中止したい場合
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  CancelSystemWakeUpTimer;
end;

//=============================================================================
//  スリープ開始
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
begin
  SetSuspendState(False, False, False);
end;

//-----------------------------------------------------------------------------
//  待機タイマーのスレッドが終了するとこのメッセージが送信されてくる
//  (システムがスリープ状態であるかとは関係なく)
//
//  スリープから復帰してからこのメッセージが処理されるまでは少しタイムラグがある
//  本サンプルでスリープ状態にした場合は 10 ～ 15 秒程度
//  [シャットダウン],他のプログラムからスリープ状態にした場合は 0 ～ 2 秒
//-----------------------------------------------------------------------------
procedure TForm1.WMResumeNotiry(var Message: TMessage);
begin
  if Message.LParam = 1 then begin

    // ここにスリープから自動復帰した時の処理を書く
    // 本サンプルでは以下の 2 行だけ

    // モニタの電源をON (モニタの電源を ON にする必要がなければ不要)
    PostMessage(HWND_BROADCAST, WM_SYSCOMMAND, SC_MONITORPOWER, -1);

    Memo1.Lines.Add(FormatDateTime('yyyy/mm/dd hh:nn:ss', Now));
  end else begin
    Memo1.Lines.Add('Cancel');
  end;
end;

//-----------------------------------------------------------------------------
//  待機タイマーの生成とスリープからの自動復帰の日時のセット
// 
//  AHandle   : 指定した日時にメッセージを送信するウィンドウのハンドル
//  ADateTime : 自動復帰の日時.この日時になるとメッセージを送信する
//
//  以下のグローバル変数を使用
//  FhWaitTimer  : 待機タイマーのハンドル
//  FTimerThread : タイマー用のスレッドオブジェクト
//  FFlagCancel  : 待機タイマーを無効(リセット)する時のフラグ
//-----------------------------------------------------------------------------
procedure SetSystemWakeUpTimer(AHandle: THandle; ADateTime: TDateTime);
var
  LTimeValue : Int64;
begin
  // 現在の待機タイマー用のスレッドを終了させる
  if Assigned(FTimerThread) then begin
    FTimerThread.Terminate;
    FreeAndNil(FTimerThread);
  end;

  // 待機タイマー用のスレッドを生成
  FTimerThread := TThread.CreateAnonymousThread(
    procedure()
    begin
      // TDateTime の時刻を UTC 換算のシステムファイル時刻に変換
      LTimeValue := TDateTimeToUTCFileTime(ADateTime);

      // 待機タイマーのオブジェクトを作成
      FhWaitTimer:= CreateWaitableTimer(nil, False ,nil);

      // 待機可能タイマーの日時を設定
      SetWaitableTimer(FhWaitTimer, LTimeValue, 0, nil, nil, True);

      // 待機タイマーがシグナル状態になるのを待つ
      WaitForSingleObject(FhWaitTimer, INFINITE);

      //上の処理が終了したら...
      // スリープからの復帰(レジューム)完了またはキャンセル
      TThread.Synchronize(TThread.CurrentThread,
        procedure
        begin
          // 待機タイマーのハンドルを閉じる
          CloseHandle(FhWaitTimer);
          FhWaitTimer := 0;
          // スリープの抑止
          // これがないと再スリープしてしまう
          SetThreadExecutionState(ES_SYSTEM_REQUIRED or ES_CONTINUOUS);
          // 指定したウィンドウに終了のメッセージを送信
          // 処理をキャンセルした場合も送信
          PostMessage(AHandle, WM_RESUME_NOTIFY, 0, Ord(not FFlagCancel));
        end
      );
    end
  );
  FTimerThread.FreeOnTerminate := False;
  FTimerThread.Start;
end;

//-----------------------------------------------------------------------------
//  待機タイマーの処理を中止
//  スリープからの自動復帰(レジューム)のキャンセル用メソッド
//
//  SetWaitableTimer 関数でコールバック関数を指定しても処理できるが
//  本サンプルでは以下のコードで処理
//
//  以下のグローバル変数を使用
//  FhWaitTimer  : 待機タイマーのハンドル
//  FTimerThread : タイマー用のスレッドオブジェクト
//  FFlagCancel  : 待機タイマーを無効(リセット)する時のフラグ
//-----------------------------------------------------------------------------
procedure CancelSystemWakeUpTimer;
var
  LTimeValue : Int64;
begin
  if FhWaitTimer <> 0 then begin
    // キャンセル用のフラグを True にする
    FFlagCancel := True;
    // 待機タイマーの日時を今現在にする
    // 待機タイマーの処理は直ちに終了してシグナル状態になる(リセットと同じ効果)
    LTimeValue := TDateTimeToUTCFileTime(Now);
    SetWaitableTimer(FhWaitTimer, LTimeValue, 0, nil, nil, True);
  end;

  // 現在の待機タイマー用のスレッドを終了させる
  if Assigned(FTimerThread) then begin
    FTimerThread.Terminate;
    FreeAndNil(FTimerThread);
  end;

  FFlagCancel := False;
end;

//-----------------------------------------------------------------------------
//  TDateTime 型の時刻を UTC 換算のシステムファイル時刻に変換する関数
//  取得する値は 1970/1/1 9:0:0 から(日本の場合)の経過時間(単位は 100 ns)
//
//  uses に DateUtils が必要
//-----------------------------------------------------------------------------
function TDateTimeToUTCFileTime(ADateTime: TDateTime): Int64;
var
  LSystemTime    : TSystemTime;
  LLocalFileTime : TFileTime;
  LUTCFileTime   : TFileTime;
begin
  // TDateTime の時刻をシステム時刻に変換
  DateTimeToSystemTime(ADateTime, LSystemTime);

  // システム時刻をローカルなファイル時刻に変換
  SystemTimeToFileTime(LSystemTime, LLocalFileTime);

  // ローカルのファイル時刻を世界協定時刻 (UTC) ファイル時刻へ変換
  LocalFileTimeToFileTime(LLocalFileTime, LUTCFileTime);

  Result := Int64(LUTCFileTime);
end;

end.