implementation

uses
  Registry,
  StrUtils,
  Generics.Collections,
  Generics.Defaults;

{$R *.dfm}

//---------------------------------------------------
//  取得したバージョン関係の値を格納するレコード型
//---------------------------------------------------
Type
  TVersionInfo = record
    Version : string;
    SP      : string;
    Full    : Integer;
  end;
  PVersionInfo = ^ TVersionInfo;

//=============================================================================
//  インストールされている.NET Frameworkのバージョンをリスト
//  Version 1 は未対応(このコードでは検出できない)
//
//  usesにRegistry,StrUtils,Generics.Collections,Generics.Defaultsが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LRegistry    : TRegistry;
  LRegKey      : string;
  LBaseKeyList : TStringList;
  LRegItemSub  : string;
  LvStr        : string;
  LVersionList : TList<TVersionInfo>;
  LVerRec      : TVersionInfo;
  LVerStr      : string;
  LIsFull      : Boolean;
  LVerStrTemp  : string;
  LRecLoopCnt  : Integer;
  LRecNo       : Integer;
  i            : Integer;
begin
  LRegistry        := TRegistry.Create;
  LRegistry.Access := KEY_READ;

  LRegistry.RootKey := HKEY_LOCAL_MACHINE;
  LRegKey := 'SOFTWARE\Microsoft\NET Framework Setup\NDP';

  LVersionList := TList<TVersionInfo>.Create;
  LBaseKeyList := TStringList.Create;
  try
    //上で指定したキー項目の一覧を取得
    if LRegistry.OpenKey(LRegKey, False) then begin
      LRegistry.GetKeyNames(LBaseKeyList);
    end;
    LRegistry.CloseKey;

    for i := 0 to LBaseKeyList.Count - 1 do begin
      try
        if LRegistry.OpenKey(LRegKey + PathDelim + LBaseKeyList[i], False) then begin
          LvStr := LBaseKeyList[i];

          //バージョンによって格納形式が異なる
          if LeftStr(LvStr, 1) <> 'v' then Continue;

          if StrUtils.LeftStr(LvStr, 4) = 'v1.1' then begin
            LRegistry.CloseKey;
            LVerRec.Version := LvStr;

            LRegItemSub := LRegKey + PathDelim + LvStr;
            if LRegistry.OpenKey(LRegItemSub, False) then begin
              if LRegistry.ValueExists('SP') then begin
                LVerRec.SP := IntToStr(LRegistry.ReadInteger('SP'));
              end else begin
                LVerRec.SP := '-';
              end;
            end;
          end else
          if LvStr < 'v4' then begin
            LRegistry.CloseKey;
            LRegItemSub := LRegKey + PathDelim + LvStr;

            if LRegistry.OpenKey(LRegItemSub, False) then begin
              LVerRec.Version := LRegistry.ReadString('Version');

              if LRegistry.ValueExists('SP') then begin
                LVerRec.SP := IntToStr(LRegistry.ReadInteger('SP'));
              end else begin
                LVerRec.SP := '-';
              end;
            end;
            LVerRec.Full := 0;
          //(v4.0とv4 (v4の方が新しい)
          //レジストリの構成仕様が変わらなければv5以降も検出可能
          //処理コードは[v4.0][v4]とも同じ
          end else begin
            if LRegistry.KeyExists('Full') then begin
              LRegItemSub := LRegKey + PathDelim + LvStr + PathDelim + 'Full';
              LVerRec.Full := 1;
            end else
            if LRegistry.KeyExists('Client') then begin
              LRegItemSub := LRegKey + PathDelim + LvStr + PathDelim + 'Client';
              LVerRec.Full := 0;
            end;

            LRegistry.CloseKey;
            if LRegistry.OpenKey(LRegItemSub, False) then begin
              LVerRec.Version := LRegistry.ReadString('Version');

              if LRegistry.ValueExists('SP') then begin
                LVerRec.SP := IntToStr(LRegistry.ReadInteger('SP'));
              end else begin
                LVerRec.SP := '-';
              end;
            end;
          end;
        end;
      finally
        LRegistry.CloseKey;
      end;

      //リストにバージョンのレコードをセット
      if Trim(LVerRec.Version) <> '' then begin
        LVersionList.Add(LVerRec);
      end;
    end;

    //-------------------------------------------------------------------------
    //  リストのソート
    //  TComparer関係の使用にはusesにGenerics.Defaultsが必要
    //-------------------------------------------------------------------------
    LVersionList.Sort(TComparer<TVersionInfo>.Construct(
      function(const Left, Right: TVersionInfo): Integer
      begin
        //versionの値(文字列)でソート
        Result := SysUtils.CompareText(Left.Version, Right.Version);
      end)
    );
    //-------------------------------------------------------------------------


    //4.5以降は同じCLRの複数のバージョンは共存できないようなのでその検出
    //5以降にも対応(5以降も同じ仕様になるのかは不明だが)
    LRecLoopCnt := LVersionList.Count - 1;
    while True do begin
      if LRecLoopCnt = 0 then Break;

      LVerStr := LVersionList[LRecLoopCnt].version;
      LIsFull := LVersionList[LRecLoopCnt].Full = 1;
      if (LVerStr >= '4.5') and LIsFull then begin
        for LRecNo := LRecLoopCnt - 1 downto 0 do begin
          LVerStrTemp := LVersionList[LRecNo].Version;
          if (LVerStrTemp >= (LVerStr[1] + '.0'))
              and (LVerStrTemp < LVerStr) then begin

            LVerRec.Version := LVersionList[LRecNo].Version
                             + ' (UpgradeTo ' + LVerStr + ')';
            LVerRec.SP           := LVersionList[LRecNo].SP;
            LVerRec.Full         := LVersionList[LRecNo].Full;
            LVersionList[LRecNo] := LVerRec;

            Dec(LRecLoopCnt);
          end;
        end;
      end;
      Dec(LRecLoopCnt);
    end;

    //結果の表示
    Memo1.Lines.Clear;
    Memo1.Lines.BeginUpdate;
    for LVerRec in LVersionList do begin
      Memo1.Lines.Add('Version : ' + LVerRec.Version);
      Memo1.Lines.Add('SP : ' + LVerRec.SP);
    end;
    Memo1.Lines.EndUpdate;
  finally
    FreeAndNil(LRegistry);
    FreeAndNil(LBaseKeyList);
    FreeAndNil(LVersionList);
  end;
end;

    for LVerRec in LVersionList do begin
      LvStr := 'Version ' + LeftStr(LVerRec.Version, 3) + ' SP ' + LVerRec.SP;
      Memo1.Lines.Add(LvStr);
    end;