unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Buttons, ExtCtrls, AppEvnts;

type
 TForm1 = class(TForm)
    SpeedButton1: TSpeedButton;
    SpeedButton2: TSpeedButton;
    Edit1: TEdit;
    ApplicationEvents1: TApplicationEvents;
    procedure FormDestroy(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure ApplicationEvents1Activate(Sender: TObject);
 private
   { Private 宣言 }
 public
   { Public 宣言 }
 end;

var
 Form1: TForm1;

implementation

{$R *.DFM}

//-----------------------------------------------------------------------------
//  低レベルキーフックのキー情報構造体と定数
//-----------------------------------------------------------------------------
const
  LLKHF_EXTENDED = KF_EXTENDED shr 8;
  LLKHF_INJECTED = $00000010;
  LLKHF_ALTDOWN  = KF_ALTDOWN shr 8;
  LLKHF_UP       = KF_UP shr 8;
  LLMHF_INJECTED = $00000001;

type
  LPKBDLLHOOKSTRUCT = ^KBDLLHOOKSTRUCT;
  tagKBDLLHOOKSTRUCT = record
    vkCode      : DWORD;
    scanCode    : DWORD;
    flags       : DWORD;
    time        : DWORD;
    dwExtraInfo : ULONG_PTR;
  end;
  KBDLLHOOKSTRUCT  = tagKBDLLHOOKSTRUCT;
  TKbDllHookStruct = KBDLLHOOKSTRUCT;
  PKbDllHookStruct = LPKBDLLHOOKSTRUCT;

var
  KeyHookHandle : HHOOK=0;

//-----------------------------------------------------------------------------
//  [NumLock] の状態をチェックして設定
//-----------------------------------------------------------------------------
procedure ChangeNumLockOn;
var
  LKeyFlg : Boolean;
  LKeyExt : Cardinal;
  LMsg    : TMsg;
begin
  LKeyFlg := (GetKeyState(VK_NUMLOCK) and 1) = 1;

  if LKeyFlg = False then begin
    LKeyExt := KEYEVENTF_EXTENDEDKEY;
    keybd_event(VK_NUMLOCK, MapVirtualKey(VK_NUMLOCK, 0), LKeyExt, 0);

    LKeyExt := KEYEVENTF_KEYUP or KEYEVENTF_EXTENDEDKEY;
    keybd_event(VK_NUMLOCK, MapVirtualKey(VK_NUMLOCK, 0), LKeyExt, 0);

    // キーバッファのクリア
    while PeekMessage(LMsg, 0, WM_KEYFIRST, WM_KEYLAST, PM_REMOVE) do;
  end;
end;

//-----------------------------------------------------------------------------
//  フックのコールバ ック関数
//  現在の Foreground なウィンドウのスレッド ID とこのアプリのスレッドID が
//  等しい場合のみ処理を行う
//-----------------------------------------------------------------------------
function LowLevelKeyProc(Code:integer; wPar:wParam; lPar:LParam): LRESULT; stdcall;
var
  LKeyFlg       : Boolean;
  Lkbdll        : PKBDLLHOOKSTRUCT;
  LThreadForeID : Cardinal;
  LThreadSelfID : Cardinal;
begin
  Result := 0;

  // Code < 0の時は余計なことをせずに
  // 直ち に CallNextHookEx の Result を返して終了する
  if Code < 0 then begin
    Result := CallNextHookEx(KeyHookHandle, Code, wPar, lPar);
    exit;
  end;

  Lkbdll := PKBDLLHOOKSTRUCT(lPar);

  if Code = HC_ACTION then begin

    LThreadSelfID := GetCurrentThreadId;
    LThreadForeID := GetWindowThreadProcessId(GetForegroundWindow);

    if LThreadSelfID = LThreadForeID then begin
      if (Lkbdll.vkCode in [VK_NUMLOCK]) then begin
        LKeyFlg := (GetKeyState(VK_NUMLOCK) and 1) = 1;
        if LKeyFlg= False then begin
          ChangeNumLockOn;
          Result := 1;
        end;
      end;
    end;
  end;

  if Result = 0 then begin
    Result := CallNextHookEx(KeyHookHandle, Code, wPar, lPar);
  end;
end;

//=============================================================================
//  キーフック開始
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Button1Click(nil);
end;

//=============================================================================
//  終了時にはフックを解除
//=============================================================================
procedure TForm1.FormDestroy(Sender: TObject);
begin
  Button2Click(nil);
end;

//=============================================================================
//  キーフック開始
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  if KeyHookHandle = 0 then begin
    KeyHookHandle := SetWindowsHookEx(WH_KEYBOARD_LL,
                                      @LowLevelKeyProc,
                                      hInstance,
                                      0);
    ChangeNumLockOn;
  end;
end;

//=============================================================================
//  キーフックを解除して通常の動作に戻す
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  if KeyHookHandle <> 0 then begin
    UnhookWindowsHookEx(KeyHookHandle);
    KeyHookHandle := 0;
  end;
end;

//=============================================================================
//  このフォームがアクティブになった ら[NumLock] の状態をチェックして設定
//=============================================================================
procedure TForm1.ApplicationEvents1Activate(Sender: TObject);
begin
  ChangeNumLockOn;
end;

end.