program Project1;
{$APPTYPE CONSOLE}

uses
  SysUtils;

begin
  try
    { TODO -oUser -cConsole メイン : ここにコードを記述してください }
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

program ConsoleApp_Test;
{$APPTYPE CONSOLE}

uses
  SysUtils;

begin
  Writeln('Hello World !! ');
  Readln;
end.

program ConsoleApp_Test;
{$APPTYPE CONSOLE}

uses
  SysUtils;

var
  S : String;
begin
  Writeln('Hello World !! ');
  while True do begin
    Readln(S);
    //コンソール上で文字'A'を入力したら終了
    if S = 'A' then exit;
  end;
end.

program Console_function;
{$APPTYPE CONSOLE}

uses
  SysUtils;

// 関数の定義。この場合、関数の名前はTestA
procedure TestA;

  // TestAの中でTestBという関数を定義。これを関数内関数と言う
  // 関数内関数は、関数内関数を定義した関数の中でしか使用できない
  procedure TestB;
  begin
    Writeln('TestA - TestB');
  end;

begin
  Writeln('TestA');
  // 下のコメント(//)をはずすとこの上の関数内の関数TestBを実行することになる
  // TestB;
end;

// 関数の定義。この場合、関数の名前はTestB
procedure TestB;
begin
  Writeln('TestB');
end;

//  実行部
begin
  TestB;
  Readln;
end.

program Console_const;
{$APPTYPE CONSOLE}

uses
  SysUtils;

// コード全体で使用する変数や定数も、使用する前に定義されいなければならない
const
  TEISUU = 500;

procedure Test;
const
  TEISUU = 200;
begin
  Writeln(TEISUU);
end;

// 実行部
// Testという関数を実行して、次にTEISUUの値を表示する
begin
  Test;
  Writeln(TEISUU);
  Readln;
end.

program Project1;
{$APPTYPE CONSOLE}

uses
  SysUtils,
  Windows,
  Messages,
  DWMAPI;

//-----------------------------------------------------------------------------
//  SetCurrentConsoleFontEx関数とこの関数で使用する構造体の定義
//  SetCurrentConsoleFontExはDelphi XE7 までは実装されていない
//  SetCurrentConsoleFontExはWindows Vista以降で使用可能
//-----------------------------------------------------------------------------
type
  PConsoleFontInfoEx = ^TConsoleFontInfoEx;
  _CONSOLE_FONT_INFOEX = record
    cbSize     : ULONG;
    nFont      : DWORD;
    dwFontSize : TCoord;
    FontFamily : UINT;
    FontWeigth : UINT;
    FontName   : array [0..LF_FACESIZE-1] of WideChar;
  end;
  TConsoleFontInfoEx = _CONSOLE_FONT_INFOEX;

  function SetCurrentConsoleFontEx(
            hConsoleOutput : THandle;
            bMaximumWindow : BOOL;
            lpConsoleCurrentFontEx : PConsoleFontInfoEx):
            BOOL; stdcall; external 'kernel32.dll';

//-----------------------------------------------------------------------------
//  Windows Vista以降では、フォームのフレームの仕様が拡張されている
//  これを考慮したウィンドウのTRect構造体の値を取得
//  usesにDWMAPIが必要
//-----------------------------------------------------------------------------
function GetWindowRectForVista(hWindow: HWND): TRect;
var
  LRect : TRect;
begin
  //拡張したウィンドウのフレームのTRect構造体の値を取得
  DwmGetWindowAttribute(hWindow,
                        DWMWA_EXTENDED_FRAME_BOUNDS,
                        @LRect,
                        SizeOf(TRect));
  Result := LRect;
end;
//-----------------------------------------------------------------------------

var
  LConsoleWnd : HWND;
  LhStdout    : THandle;
  LFontInfo   : TConsoleFontInfoEx;
  LBuffSize   : TCoord;
  LWndSize    : TSmallRect;
  LColor      : Word;
  LWndRect    : TRect;
begin
  //ウインドウハンドルを取得
  //LConsoleWnd := Application.Handle;でも同じ
  //Application.Handleを使用する場合はusesにFormsが必要
  LConsoleWnd := FindWindow('ConsoleWindowClass', nil);
  //標準出力デバイスのハンドルを取得
  LhStdout := GetStdHandle(STD_OUTPUT_HANDLE);

  //フォントサイズの設定
  LFontInfo.cbSize       := SizeOf(TConsoleFontInfoEx);
  LFontInfo.dwFontSize.X := 0;
  LFontInfo.dwFontSize.Y := 12;
  LFontInfo.FontFamily   := FF_DONTCARE;
  LFontInfo.FontWeigth   := FW_NORMAL;
  LFontInfo.FontName     := 'ＭＳ ゴシック';
  SetCurrentConsoleFontEx(LhStdout, False, @LFontInfo);


  //ウィンドウのサイズ(文字数)
  LWndSize.Left   := 0;
  LWndSize.Top    := 0;
  LWndSize.Right  := 50;
  LWndSize.Bottom := 15;
  SetConsoleWindowInfo(LhStdout, True, LWndSize);


  //画面のバッファのサイズ(文字数)
  LBuffSize.X := LWndSize.Right - LWndSize.Left;
  LBuffSize.Y := LWndSize.Bottom - LWndSize.Top + 50;
  SetConsoleScreenBufferSize(LhStdout, LBuffSize);


  //文字の色を、緑と赤で黄色にする
  LColor := FOREGROUND_GREEN or FOREGROUND_RED or FOREGROUND_INTENSITY;
  SetConsoleTextAttribute(LhStdout, LColor);


  //コンソールウィンドウのサイズ(ピクセル)を取得して位置を設定
  LWndRect := GetWindowRectForVista(LConsoleWnd);
  MoveWindow(LConsoleWnd,
             100,
             0,
             LWndRect.Right  - LWndRect.Left,
             LWndRect.Bottom - LWndRect.Top,
             True);


  //タイトルを設定
  SetConsoleTitle('コンソールのテスト');


  Writeln('ウィンドウの表示位置を変更');
  Writeln('文字の色とサイズも変更');

  LColor := FOREGROUND_GREEN or FOREGROUND_INTENSITY;
  SetConsoleTextAttribute(LhStdout, LColor);
  Writeln('');
  Writeln('文字の色を緑に変更');

  //何かキーを押したら終了
  Readln;
end.

program Project1;
{$APPTYPE CONSOLE}

uses
  ShellAPI,
  Windows;

var
  LCommandLine : string;
  LStartupInfo : TStartupInfo;
  LProcessInfo : TProcessInformation;

begin
  SetConsoleTitle('コマンドの実行テスト');

  writeln('dir コマンドを実行します');
  writeln('何かキーを押してください');
  Readln;

  //CreateProcessの引数の構造体のメンバを設定
  //入出力を標準入出力に設定する
  ZeroMemory(@LStartupInfo, SizeOf(TStartupInfo));
  ZeroMemory(@LProcessInfo, SizeOf(TProcessInformation));
  LStartupInfo.cb          := SizeOf(TStartupInfo);
  LStartupInfo.hStdInput   := GetStdHandle(STD_INPUT_HANDLE);
  LStartupInfo.hStdOutput  := GetStdHandle(STD_OUTPUT_HANDLE);
  LStartupInfo.hStdError   := GetStdHandle(STD_ERROR_HANDLE);
  LStartupInfo.dwFlags     := STARTF_USESTDHANDLES;

  //コマンド実行
  try
    LCommandLine := 'cmd.exe /c dir';
    UniqueString(LCommandLine);
    if not CreateProcess(nil,
                         PChar(LCommandLine),
                         nil,
                         nil,
                         True,
                         0,
                         nil,
                         nil,
                         LStartupInfo,
                         LProcessInfo) then begin
      //CreateProcess失敗
    end;
  finally
    CloseHandle(LProcessInfo.hProcess);
    CloseHandle(LProcessInfo.hThread);
  end;

  Readln;
end.

program Project1;
{$APPTYPE CONSOLE}

uses
  Windows;

//-----------------------------------------------------------------------------
//  コマンドライン用のプログラムの例
//  必要があれば標準出力等のハンドルを取得して操作するく
//-----------------------------------------------------------------------------
begin
  writeln('');
  writeln('');
  writeln('コマンドアプリのテストです');
  writeln(100);
  writeln(200);
  writeln(300);

  //デバッグ時はコンソール画面を表示したままにする
  //処理が終了したらすぐコマンドプロンプトに戻るためReadln等は書かない
  if DebugHook <> 0 then begin
    Readln;
  end;
end.

program Project1;
{$APPTYPE CONSOLE}

{$R *.dres}

uses
  Windows,
  SysUtils;

begin
  SetConsoleTitle('アイコンのテスト');
  Writeln('コンソールアプリのアイコンの設定');
  Readln;
end.

program Project1;
{$APPTYPE CONSOLE}

uses
  Winapi.Windows,
  Winapi.Messages,
  Vcl.Dialogs,
  Vcl.Forms;
               var
  FhConsole : HWND;

//-----------------------------------------------------------------------------
//  SetConsoleCtrlHandler のコールバック関数
//  以下のイベントが使用可能
//  処理の変更 (閉じる処理の阻止等) はできない
//
//  CTRL_C_EVENT        : [Ctrl] + [C] の信号を受信
//  CTRL_BREAK_EVENT    : [Ctrl] + [Break] の信号を受信
//  CTRL_CLOSE_EVENT    : コンソールウィンドウを閉じる時の信号
//  CTRL_LOGOFF_EVENT   : ユーザーがログオフする時の信号
//  CTRL_SHUTDOWN_EVENT : システムのシャットダウン時の信号
//-----------------------------------------------------------------------------
function ConsoleEventProc(CtrlType: DWORD): Bool; stdcall;
var
  LText : string;
begin
  Result := True;
  LText := '';

  case CtrlType of
  CTRL_C_EVENT:
    begin
      LText := '[Ctrl] + [C] のキー操作がありました。';
    end;
  CTRL_CLOSE_EVENT:
    begin
      LText := 'ウィンドウが閉じようとしています';
    end;
  else
  end;

  if LText <> '' then begin
    MessageBox(0, PChar(LText), '情報', MB_ICONINFORMATION);
  end;
end;
//-----------------------------------------------------------------------------

begin
  Writeln('コンソールアプリのイベント');

  // コンソールウィンドウのハンドルを取得
  FhConsole := FindWindow(nil, PChar(Application.ExeName));
  // ウィンドウのキャプション (タイトル) を変更
  SetConsoleTitle('CTRL_XXX_EVENT イベントのテスト');

  // イベントハンドラの設定
  SetConsoleCtrlHandler(@ConsoleEventProc, True);
  SetConsoleMode(FhConsole, ENABLE_PROCESSED_INPUT);

  Readln;
  // ダイアログを見られるようにするためのタイムラグ
  Sleep(3000);
end.

begin
  Writeln('コンソールアプリのイベント');
  Writeln('5 秒後に自動終了します');

  // コンソールウィンドウのハンドルを取得
  FhConsole := FindWindow(nil, PChar(Application.ExeName));
  // ウィンドウのキャプション (タイトル) を変更
  SetConsoleTitle('CTRL_XXX_EVENT イベントのテスト');

  // イベントハンドラの設定
  SetConsoleCtrlHandler(@ConsoleEventProc, True);
  SetConsoleMode(FhConsole, ENABLE_PROCESSED_INPUT);

  Sleep(5000);
  // ExitProcess ではなく [Ctrl] + [C] で終了してみる
  GenerateConsoleCtrlEvent(CTRL_C_EVENT, 0);

  // Readln;
  // ダイアログを見られるようにするためのタイムラグ
  Sleep(3000);
end.