unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,
  Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    Button1: TButton;
    procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);
    procedure Button1Click(Sender: TObject);
  protected
    procedure WMApp100(var Message: TMessage); message WM_APP+100;
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  Winapi.ShellAPI;

{$R *.DFM}

//=============================================================================
//  フォームを閉じる時の処理
//  起動したアプリが起動中だったら閉じる
//=============================================================================
procedure TForm1.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
var
  LhWindow : HWND;
begin
  LhWindow := FindWindow('TReceivForm', nil);
  if LhWindow <> 0 then begin
    PostMessage(LhWindow, WM_ClOSE, 0, 0);
  end;
end;

//=============================================================================
//  PostMessage の後に SendMessage を実行
//  PostMessage でメッセージキューにポストされたメッセージは
//  この Button2Click イベント終了後に処理される
//  その結果，起動したアプリの表示位置が変わる
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LExePath : string;
begin
  Memo1.Lines.Clear;

  PostMessage(Handle, WM_APP+100, 0, 0);
  SendMessage(Handle, WM_APP+100, 1, 0);

  // 他のアプリを起動
  LExePath := ExpandFileName('..\AppExe\Receiver.exe');
  ShellExecute(0, '', PChar(LExePath), nil, nil, SW_SHOW);
  Sleep(500);

  Memo1.Lines.Add('END Button1Click');
end;

//-----------------------------------------------------------------------------
//  メッセージの受信処理の例
//-----------------------------------------------------------------------------
procedure TForm1.WMApp100(var Message: TMessage);
var
  LhWindow : HWND;
begin
  if Message.WParam = 0 then begin
    Memo1.Lines.Add('PostMessage');
  end else
  if Message.WParam = 1 then begin
    Memo1.Lines.Add('SendMessage');
  end;

  LhWindow := FindWindow('TReceivForm', nil);

  if LhWindow <> 0 then begin
    SetWindowPos(LhWindow,
                 0,
                 Self.Left - 120,
                 Self.Top,
                 0,
                 0,
                 SWP_NOSIZE or SWP_NOZORDER);
  end;
  SetForegroundWindow(Handle);
end;

end.

//=============================================================================
//  PostMessage の後に SendMessage を実行
//  Application.ProcessMessages はメッセージキューの処理を待つ
//  PostMessage でメッセージキューにポストされたメッセージが処理される
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LExePath : string;
begin
  Memo1.Lines.Clear;

  PostMessage(Handle, WM_APP+100, 0, 0);
  // 前のサンプルに追加したのはこの 1 行だけ
  Application.ProcessMessages;
  SendMessage(Handle, WM_APP+100, 1, 0);

  // 他のアプリを起動
  LExePath := ExpandFileName('..\AppExe\Receiver.exe');
  ShellExecute(0, '', PChar(LExePath), nil, nil, SW_SHOW);
  Sleep(500);

  Memo1.Lines.Add('END Button1Click');
end;

//=============================================================================
//  フェーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  RichEdit1.Lines.Text := '日本語テスト文字列';

  RichEdit1.HideSelection := False;
end;

//=============================================================================
//  指定コントロールに WM_KEYDOWN, WM_KEYUP メッセージでキー操作を行う
//  WM_KEYDOWN, WM_KEYUP は PostMessage を使用しないと正常に機能しない
//
//  PostMessage による操作の結果が SendMessage で取得できることが確認できる
//  つまり，SendMessage 実行前にメッセージキューのメッセージは処理されている
//=============================================================================
procedure TForm1.SpeedButton1Click(Sender: TObject);
const
  EM_EXGETSEL = $0434;
type
  TCharRange = record
    cpMin : Longint;
    cpMax : LongInt;
  end;
var
  LCharRange : TCharRange;
  LLength    : Integer;
  LSelText   : string;
begin
  // キャレットの位置を 3 文字目の後ろ (4 文字目の前) にする
  RichEdit1.SelStart := 3;

  // 現在のキャレット位置から文字を選択
  // キー操作は [Shift] + [→]
  PostKeyExHWND(RichEdit1.Handle, VK_RIGHT, [ssShift], False);
  PostKeyExHWND(RichEdit1.Handle, VK_RIGHT, [ssShift], False);
  PostKeyExHWND(RichEdit1.Handle, VK_RIGHT, [ssShift], False);

  // 選択した文字を取得
  SendMessage(RichEdit1.Handle, EM_EXGETSEL, 0, LPARAM(@LCharRange));

  // 取得した文字列を表示
  LLength := LCharRange.cpMax - LCharRange.cpMin;
  LSelText := Copy(RichEdit1.Text, LCharRange.cpMin + 1, LLength);
  RichEdit1.Lines.Add(LSelText);
end;

{***********************************************************}
{3. With keybd_event API}

procedure PostKeyExHWND(hWindow: HWnd; key: Word; const shift: TShiftState;
  specialkey: Boolean);
{************************************************************
 * Procedure PostKeyEx
 *
 * Parameters:
 *  hWindow: target window to be send the keystroke
 *  key    : virtual keycode of the key to send. For printable
 *           keys this is simply the ANSI code (Ord(character)).
 *  shift  : state of the modifier keys. This is a set, so you
 *           can set several of these keys (shift, control, alt,
 *           mouse buttons) in tandem. The TShiftState type is
 *           declared in the Classes Unit.
 *  specialkey: normally this should be False. Set it to True to
 *           specify a key on the numeric keypad, for example.
 *           If this parameter is true, bit 24 of the lparam for
 *           the posted WM_KEY* messages will be set.
 * Description:
 *  This procedure sets up Windows key state array to correctly
 *  reflect the requested pattern of modifier keys and then posts
 *  a WM_KEYDOWN/WM_KEYUP message pair to the target window. Then
 *  Application.ProcessMessages is called to process the messages
 *  before the keyboard state is restored.
 * Error Conditions:
 *  May fail due to lack of memory for the two key state buffers.
 *  Will raise an exception in this case.
 * NOTE:
 *  Setting the keyboard state will not work across applications
 *  running in different memory spaces on Win32 unless AttachThreadInput
 *  is used to connect to the target thread first.
 *Created: 02/21/96 16:39:00 by P. Below
 ************************************************************}
type
  TBuffers = array [0..1] of TKeyboardState;
var
  pKeyBuffers: ^TBuffers;
  lParam: LongInt;
begin
  (* check if the target window exists *)
  if IsWindow(hWindow) then
  begin
    (* set local variables to default values *)
    pKeyBuffers := nil;
    lParam := MakeLong(0, MapVirtualKey(key, 0));

    (* modify lparam if special key requested *)
    if specialkey then
      lParam := lParam or $1000000;

    (* allocate space for the key state buffers *)
    New(pKeyBuffers);
    try
      (* Fill buffer 1 with current state so we can later restore it.
         Null out buffer 0 to get a "no key pressed" state. *)
      GetKeyboardState(pKeyBuffers^[1]);
      FillChar(pKeyBuffers^[0], SizeOf(TKeyboardState), 0);

      (* set the requested modifier keys to "down" state in the buffer*)
      if ssShift in shift then
        pKeyBuffers^[0][VK_SHIFT] := $80;
      if ssAlt in shift then
      begin
        (* Alt needs special treatment since a bit in lparam needs also be set *)
        pKeyBuffers^[0][VK_MENU] := $80;
        lParam := lParam or $20000000;
      end;
      if ssCtrl in shift then
        pKeyBuffers^[0][VK_CONTROL] := $80;
      if ssLeft in shift then
        pKeyBuffers^[0][VK_LBUTTON] := $80;
      if ssRight in shift then
        pKeyBuffers^[0][VK_RBUTTON] := $80;
      if ssMiddle in shift then
        pKeyBuffers^[0][VK_MBUTTON] := $80;

      (* make out new key state array the active key state map *)
      SetKeyboardState(pKeyBuffers^[0]);
      (* post the key messages *)
      if ssAlt in Shift then
      begin
        PostMessage(hWindow, WM_SYSKEYDOWN, key, lParam);
        PostMessage(hWindow, WM_SYSKEYUP, key, lParam or $C0000000);
      end
      else
      begin
        PostMessage(hWindow, WM_KEYDOWN, key, lParam);
        PostMessage(hWindow, WM_KEYUP, key, lParam or $C0000000);
      end;
      (* process the messages *)
      Application.ProcessMessages;

      (* restore the old key state map *)
      SetKeyboardState(pKeyBuffers^[1]);
    finally
      (* free the memory for the key state buffers *)
      if pKeyBuffers <> nil then
        Dispose(pKeyBuffers);
    end; { If }
  end;
end; { PostKeyEx }

procedure TForm1.FormCreate(Sender: TObject);
begin
  // メッセージをメッセージキューにポスト
  PostMessage(Handle, WM_CLOSE, 0, 0);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  SendMessage(Handle, WM_CLOSE, 0, 0);
end;