unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,
  Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls,
  uWVBrowser, uWVWinControl, uWVWindowParent, uWVTypes, uWVConstants, uWVTypeLibrary,
  uWVLibFunctions, uWVLoader, uWVInterfaces, uWVCoreWebView2Args, uWVBrowserBase,

  Vcl.ExtCtrls;

type
  TForm1 = class(TForm)
    WVWindowParent1: TWVWindowParent;
    WVBrowser1: TWVBrowser;
    Timer1: TTimer;
    Edit1: TEdit;
    procedure FormShow(Sender: TObject);
    procedure WVBrowser1AfterCreated(Sender: TObject);
    procedure WVBrowser1InitializationError(Sender: TObject;
      aErrorCode: HRESULT; const aErrorMessage: wvstring);
    procedure Timer1Timer(Sender: TObject);
    procedure Edit1KeyDown(Sender: TObject; var Key: Word; Shift: TShiftState);
  private
    { Private 宣言 }
  protected
    procedure WMMove(var Message: TWMMove); message WM_MOVE;
    procedure WMMoving(var Message: TWMMoving); message WM_MOVING;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム表示開始前の処理
//  環境の準備ができていない場合に備えて，タイマーを使用してブラウザを作成
//
//  本サンプルでは WVWindowParent1.browser の値を WVBrowser1 にしている
//  本サンプル開発時の TWVBrowser.TargetCompatibleBrowserVersion は 97.0.1072.55
//
//  本サンプルのコンパイルには，uses に各種のユニットが必要
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  if GlobalWebView2Loader.InitializationError then begin
    showmessage(GlobalWebView2Loader.ErrorMessage);
  end else begin
    if GlobalWebView2Loader.Initialized then  begin
      WVBrowser1.CreateBrowser(WVWindowParent1.Handle)
    end else begin
      Timer1.Enabled := True;
    end;
  end;
end;

//=============================================================================
//  Edit1 の OnKeyDown イベント処理
//  [Enter] キー押下で Exit1.Text の URL を表示
//=============================================================================
procedure TForm1.Edit1KeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  if Key = VK_RETURN then begin
    WVBrowser1.Navigate(Trim(Edit1.Text));
    Key := 0;
  end;
end;

//=============================================================================
//  WVBrowser1 の OnAfterCreated イベント
//  ブラウザが生成されたらウェブページを表示
//=============================================================================
procedure TForm1.WVBrowser1AfterCreated(Sender: TObject);
begin
  WVWindowParent1.UpdateSize;
  Caption := 'シンプルブラウザ';
  Edit1.Enabled := True;

  Edit1.Text := 'http://mrxray.on.coocan.jp/';
  WVBrowser1.Navigate(Edit1.Text);
end;

//=============================================================================
//  WVBrowser1 の OnInitializationError イベント
//  初期化に失敗した場合
//=============================================================================
procedure TForm1.WVBrowser1InitializationError(Sender: TObject;
  aErrorCode: HRESULT; const aErrorMessage: wvstring);
begin
  showmessage(aErrorMessage);
end;

//=============================================================================
//  Timer1 の OnTimer イベント
//  本サンプルでは Timer1.Enabled を False にしている
//  本サンプルでは Timer1.Interval を 300 にしている
//=============================================================================
procedure TForm1.Timer1Timer(Sender: TObject);
begin
  Timer1.Enabled := False;

  if GlobalWebView2Loader.Initialized then begin
    WVBrowser1.CreateBrowser(WVWindowParent1.Handle);
  end else begin
    Timer1.Enabled := True;
  end;
end;

//-----------------------------------------------------------------------------
//  WM_MOVE メッセージ処理
//  WM_MOVE, WM_MOVING の処理がないとウェブページの描画がかすれることがある
//-----------------------------------------------------------------------------
procedure TForm1.WMMove(var Message: TWMMove);
begin
  inherited;

  if (WVBrowser1 <> nil) then begin
    WVBrowser1.NotifyParentWindowPositionChanged;
  end;
end;

//-----------------------------------------------------------------------------
//  WM_MOVING メッセージ処理
 //  WM_MOVE, WM_MOVING の処理がないとウェブページの描画がかすれることがある
//-----------------------------------------------------------------------------
procedure TForm1.WMMoving(var Message: TWMMoving);
begin
  inherited;

  if (WVBrowser1 <> nil) then begin
    WVBrowser1.NotifyParentWindowPositionChanged;
  end;
end;

//-----------------------------------------------------------------------------
//  initialization 部
//  GlobalWebView2Loaderをロードしてグローバル環境を非同期的に初期化
//
//  UserDataFolder はキャッシュやクッキー等の保存場所
//  指定しないとコンポーネントのデフォルトの名前になる
//-----------------------------------------------------------------------------
initialization
  GlobalWebView2Loader := TWVLoader.Create(nil);
  GlobalWebView2Loader.UserDataFolder := ExtractFileDir(Application.ExeName)
                                       + '\CustomCache';
  GlobalWebView2Loader.StartWebView2;
end.