喫茶XRAY [Mr.XRAY掲示板]

[11458] DLLの関数に文字列を渡す

返信　削除

2017/10/15 (日) 21:08:53 Mr.XRAY

DLL の関数を作成して，その関数で，DLL 側で文字列を受け取る時は，
基本的には PChar 型にしておいた方が無難です．
以下は簡単な例です．
動作確認は Windows 7 U64(SP1) + Delphi XE(UP1) Pro です．

[参考]
[889] [08_DLL 内の関数で外部に文字列を渡す]
http://mrxray.on.coocan.jp/Delphi/plSamples/889_VCLStyleResource.htm#08

//----------------- DLLの全コード-----------------------------------------
// ファイル名は DllTest_PChar.dpr

library DllTest_PChar;

uses
  Windows,
  SysUtils,
  Dialogs;

function SetText2Dll(Buff: PChar):Bool; stdcall;
var
  LText : string;
begin
  LText := string(Buff);
  ShowMessage(LText);
  Result := True;
end;

exports
  SetText2Dll;

end.

//----------------- テスト側のコード ------------------------------------------

implementation

{$R *.dfm}

function SetText2Dll(Buff: PChar):Bool; stdcall; external 'DllTest_PChar.dll';

procedure TForm1.Button1Click(Sender: TObject);
begin
  Edit1.Text := BoolToStr(SetText2Dll('日本語'));
end;

[11459] Re:DLLの関数に文字列を渡す

返信　削除

2017/10/15 (日) 21:13:49 Mr.XRAY

> DLL の関数を作成して，その関数で，DLL 側で文字列を受け取る時は，
> 基本的には PChar 型にしておいた方が無難です．
> 以下は簡単な例です．

[DLLとの文字列の受け渡しがうまくいきません ]
https://forums.embarcadero.com/thread.jspa?threadID=258840&tstart=0

というのがありますが，これでは他の方が動作を検証できません．
言い尽くされたことですが，動作確認用のプロジェクトを作成して
そのコードを提示すれば誰かが確認できます．
そうでなければ抽象的なアドバイスしかできません．
具体的なアドバイスはできません．

と書くと，何万行のプログラムなのでそういうことはできません．
という方もいますが.(笑)

[11472] Re2:DLLの関数に文字列を渡す

返信　削除

2017/10/16 (月) 17:39:56 Mr.XRAY

[DLLとの文字列の受け渡しがうまくいきません ]
https://forums.embarcadero.com/thread.jspa?threadID=258840&tstart=0#903352

上で提示したコードの場合，StrCopy を使用する必要がないのであれば，
以下のように PChar 型の変数に代入できます．
StrAlloc でメモリを確保した場合は StrDispose でメモリを解放します．

procedure TForm1.Button1Click(Sender: TObject);
var
  LPChar : PChar;
begin
  LPChar := PChar('ABCDE');
  Edit1.Text := BoolToStr(SetText2Dll(LPChar));
end;

[11473] Re3:DLLの関数に文字列を渡す

返信　削除

2017/10/16 (月) 17:57:46 Mr.XRAY

> 上で提示したコードの場合，StrCopy を使用する必要がないのであれば，

どうしても StrCopy を使用する必要がある場合は，
例えば以下のように書けます．
質問された方のコードは省略があるので参考です．
この上もこのコードも動作確認は Windows 7 U64(SP1) + Delphi XE(UP1) Pro です．

procedure TForm1.Button2Click(Sender: TObject);
var
  LText  : string;
  LPChar : PChar;
begin
  //+1はnull終端文字の分
  //これがないと無効ポインタの操作となる
  LText := 'ABCDE';
  LPChar := StrAlloc(Length(LText) + 1);
  try
    StrCopy(LPChar, PChar(LText));
    Edit1.Text := BoolToStr(SetText2Dll(LPChar));
  finally
    StrDispose(LPChar);
  end;
end;

[▼次のスレッド]

INCM/CMT
Cyclamen v3.82