喫茶XRAYトップページ

[スレッド全体]
[12026] PAnsiCharをStrPCopy関数で使用返信　削除
2018/7/11 (水) 06:27:25 Mr.XRAY
Unicode 版の Delphi で PAnsiChar 型の文字列を StrPCopy 関数で使用する
場合は，次のように，uses に AnsiStrings を追加して明示的に AnsiStrings を
記述しみてください．

implementation

uses
  AnsiStrings;

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  LPAnsiChar  : PAnsiChar;
begin
  LPAnsiChar := AllocMem(200);
  try
    AnsiStrings.StrPCopy(LPAnsiChar, '日本語 ABC 文字列');
    Memo1.Lines.Add(string(LPAnsiChar));
  finally
    FreeMem(LPAnsiChar);
  end;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  LAnsiString : AnsiString;
  LPAnsiChar  : PAnsiChar;
begin
  LAnsiString := '日本語 ABC 文字列';
  LPAnsiChar  := AllocMem(Length(LAnsiString) + 1);
  try
    AnsiStrings.StrPCopy(LPAnsiChar, LAnsiString);
    Memo1.Lines.Add(string(LPAnsiChar));
  finally
    FreeMem(LPAnsiChar);
  end;
end;


[12032] Re:PAnsiCharをStrPCopy関数で使用返信　削除
2018/7/11 (水) 11:58:59 Mr.XRAY
> AnsiStrings を追加して明示的に AnsiStrings を

Move 関数を使ってしまう手もあります．
Move 関数を使用する場合は uses に AnsiStrings は不要です．

※ Length(Ansi文字変数) はバイト数を返します．

procedure TForm1.Button3Click(Sender: TObject);
var
  LAnsiString : AnsiString;
  LPAnsiChar  : PAnsiChar;
begin
  LAnsiString := '日本語 ABC 文字列';
  LPAnsiChar  := AllocMem(Length(LAnsiString) + 1);
  try
    Move(LAnsiString[1], LPAnsiChar^, Length(LAnsiString));
    Memo1.Lines.Add(string(LPAnsiChar));
  finally
    FreeMem(LPAnsiChar);
  end;
end;

[12036] Move関数の引数返信　削除
2018/7/12 (木) 06:22:50 Mr.XRAY
Move 関数には引数が 3 つあります．
第 2 の引数はコピー先です．
したがって，変数名を使用する必要があります．
以下の動作確認は Windows 7 U64(SP1) + Delphi XE5(UP2) Pro VCL-32 です．

[System.Move - RAD Studio API Documentation]
http://docwiki.embarcadero.com/Libraries/XE5/ja/System.Move


//=============================================================================
//  Move関数
//  第1引数 コピー元
//  第2引数 コピー先
//  第3引数 コピーするバイト数
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
 LAnsiString  : AnsiString;
 LAnsiCharArr : array [0..25] of AnsiChar;
begin
  LAnsiString := '日本語 ABC 文字列';

  FillChar(LAnsiCharArr, Length(LAnsiCharArr), #0);
  Move(LAnsiString[1], LAnsiCharArr, Length(LAnsiString));

  Memo1.Lines.Add(LAnsiCharArr);
end;


[12045] Re:Move関数の引数返信　削除
2018/7/13 (金) 11:23:57 Mr.XRAY
> したがって，変数名を使用する必要があります．

そうしないと

E2197 変数パラメータに定数オブジェクトを渡すことはできません

というエラーが発生します．以下のコードで実際の現象を確認できます．
簡単なコードです．実際にコーディングして確かめてみることをお勧めします．
記事をみて納得するだけでなく，実際に経験することには大きな意味があります．
「百閒は一見にしかず．百見は一触にしかず」です．


procedure HogeHoge(var Arg1: string);
begin
  ShowMessage(Arg1);
  Arg1 := '日本語';
end;

//=============================================================================
//  E2197 変数パラメータに定数オブジェクトを渡すことはできません
//  のエラーが発生するコード
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  HogeHoge('XYZ');
end;
//=============================================================================
//  E2197 変数パラメータに定数オブジェクトを渡すことはできません
//  のエラーが発生しないコード
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
 LText : string;
begin
  LText := 'XYZ';
  HogeHoge(LText);
  ShowMessage(LText);
end;

[12049] 関数の引数には変数を使用する返信　削除
2018/7/14 (土) 06:49:42 Mr.XRAY
> E2197 変数パラメータに定数オブジェクトを渡すことはできません

StrPCopy や Move 関数は「変数」が指す (アドレスの) メモリ上のデータを
コピーします．したがって，引数には「変数」を使用します．
一般に関数の引数には変数を使用します．
具体的な文字列を渡して，エラーが発生しなくても期待通りの動作とならない
ことがあります．

特に今回の場合，AnsiString あるいは PAnsiChar, AnsiChar であることを
明確にしなければならないのですから尚更です．
具体的な文字列を直接引数に使用できるのは特別な場合と思ってください．


# 最初のレスで終わると思ったのですが (^^;
# う～む，想定外 ?

# 提示したコードを実際に動作させてみることをお勧めします．
# 見て理解するのと，実際に体験するのとでは脳への記録のされ方が違います．
# どれもフォームに TButton と TMome だけを配置した簡単なプロジェクトです．

[▼次のスレッド]
INCM/CMT
Cyclamen v3.82