喫茶XRAY [Mr.XRAY掲示板]

[8071] 四捨五入

返信　削除

2014/10/8 (水) 16:50:38 Mr.XRAY

四捨五入と丸めに関するサンプルです．
例えば以下のコードを実行します．
コードの下の図を見てください．
動作確認は，Windows 7 U64(SP1) + Delphi XE5 Pro で，32 ビットのEXEです．

//-----------------------------------------------------------------------------
//  (1)と(2)の計算式は，数学的には等しく，179.935となる
//  SimpleRoundToの使用にはusesにMathが必要
//
//  Math.GetRoundModeで取得したモードはrmNearest
//  Extendedの扱いは
//  Math.SetPrecisionMode(pmDouble);
//  でDouble型として扱うようにできる
//-----------------------------------------------------------------------------
procedure TForm1.Button1Click(Sender: TObject);
var
  a,b,c,d,e,f:Extended;
  strText : String;
begin
  a:=389.7;
  b:=94.4;
  c:=30;
  d:=0.35;
  e:=(a+b+c)*d;    //(1)
  f:=a*d+b*d+c*d;  //(2)

  StrText :=  FloatToStr(e)+#13+
              FloatToStr(f)+#13+ sLineBreak +
              FloatToStr(SimpleRoundTo(e,-2))+#13+
              FloatToStr(SimpleRoundTo(f,-2));
  MessageBox(Handle, PChar(strText), '結果', MB_OK);
end;

//-----------------------------------------------------------------------------
//  変数の型をDoubleとした場合
//-----------------------------------------------------------------------------
procedure TForm1.Button2Click(Sender: TObject);
var
  a,b,c,d,e,f:Double;
  strText : String;
begin
  a:=389.7;
  b:=94.4;
  c:=30;
  d:=0.35;
  e:=(a+b+c)*d;    //(1)
  f:=a*d+b*d+c*d;  //(2)

  StrText :=  FloatToStr(e)+#13+
              FloatToStr(f)+#13+ sLineBreak +
              FloatToStr(SimpleRoundTo(e,-2))+#13+
              FloatToStr(SimpleRoundTo(f,-2));
  MessageBox(Handle, PChar(strText), '結果', MB_OK);
end;

数学的に正確な値は，どちらも 179.94 です．
  e:=(a+b+c)*d;    //(1)
  f:=a*d+b*d+c*d;  //(2)

しかし，結果の図のように Extended 型では e と f が違っています．
Double 型では同じ値になっていますが，数学的に正しい値ではありません．

[8072] Re:四捨五入

返信　削除

2014/10/8 (水) 16:51:20 Mr.XRAY

今度は，64 ビットのEXE を作成して実行してみます．
やはり，e と f の表示が違います．

[8073] Re2:四捨五入

返信　削除

2014/10/8 (水) 16:52:07 Mr.XRAY

>今度は，64 ビットのEXE を作成して実行してみます．
>やはり，e と f の表示が違います．

当サイトに次のような記事があります．
これとも関係してきます．

[890_計算誤差 ( 数値計算の誤差 ) と多倍長演算]
http://mrxray.on.coocan.jp/Delphi/plSamples/890_CalcError.htm

サンプルの

  e:=(a+b+c)*d;    //(1)
  f:=a*d+b*d+c*d;  //(2)

e と f の値は，数学的には同じでも，コンピュータ内部では異なる場合があります．
FloatToStr 関数は，数値を文字列にする際，15 桁で丸めます．
一方，SimpleRoundTo 関数は，元の値を使用して四捨五入します．

このことを利用すると，数値を一度 FloatToStr 関数で文字列にして，
再度実数にすれば，16 桁以上の精度があれば，計算結果の違いを回避すること
ができることになります．
今回のような単純な計算であれば利用可能でしょう．
そのテスト用コードです．

//-----------------------------------------------------------------------------
//  (1)と(2)の計算式は，数学的には等しく，179.935となる
//-----------------------------------------------------------------------------
procedure TForm1.Button1Click(Sender: TObject);
var
  a,b,c,d,e,f:Extended;
  strText : String;
begin
  a:=389.7;
  b:=94.4;
  c:=30;
  d:=0.35;
  e:=(a+b+c)*d;    //(1)
  f:=a*d+b*d+c*d;  //(2)

  //StrToFloatは15桁で丸めを行うので15桁に丸めた文字列を取得する
  //その文字列を再度実数にする
  e := StrToFloat(FloatToStr(e));
  f := StrToFloat(FloatToStr(f));

  StrText :=  FloatToStr(e)+#13+
              FloatToStr(f)+#13+ sLineBreak +
              FloatToStr(SimpleRoundTo(e,-2))+#13+
              FloatToStr(SimpleRoundTo(f,-2));
  MessageBox(Handle, PChar(strText), '結果', MB_OK);
end;

下図が実行結果です．
指定小数点以上の精度が必要ないか，計算の結果の精度が分かっている場合，
次のように，計算の結果をその小数点の桁数に四捨五入してしまう方法も
考えられます．

  e := SimpleRoundTo(e, -10);
  f := SimpleRoundTo(f, -10);

この他，FloatToStrF 関数, FloatToText 関数や FloatToTextFmt 関数で，
精度を指定する方法もあります．

   FloatToStrF(f, ffFixed, 10, 2))

は，10 桁の精度で，固定小数点形式の小数点 2 桁までの値の文字列を取得します．

[System.SysUtils.FloatToStrF - RAD Studio API Documentation]
http://docwiki.embarcadero.com/Libraries/XE6/ja/System.SysUtils.FloatToStrF

[8074] Re3:四捨五入

返信　削除

2014/10/8 (水) 17:06:18 Mr.XRAY

> 下図が実行結果です．

重要なことは，サンプルコードの値を四捨五入した結果が違っていても，
これは文字列に変換した時の現象，問題です．
計算結果としての e, f の値を，次の計算に使用することには何ら問題はない
ことになります．

[8078] 計算結果をバイト値で確認

返信　削除

2014/10/9 (木) 12:59:10 Mr.XRAY

>一方，SimpleRoundTo 関数は，元の値を使用して四捨五入します．
>そのために違いが生じることになります．

SimpleRoundTo 関数で使用する元の値を確認してみます．
元の値とは計算式による値のことです．
Delphi XE2 で実装された浮動小数点用レコードで計算結果の値をバイト値
で確認してみました．
図のように，e の値が 1 だけ小さい値になっています．
つまり，FloatToStr(SimpleRoundTo) の結果は，計算結果を正確に反映していると言えます．

[Delphi のデータ型 - RAD Studio]
http://docwiki.embarcadero.com/RADStudio/XE6/ja/Delphi_%E3%81%AE%E3%83%87%E3%83%BC%E3%82%BF%E5%9E%8B#.E6.B5.AE.E5.8B.95.E5.B0.8F.E6.95.B0.E7.82.B9.E3.83.87.E3.83.BC.E3.82.BF.E5.9E.8B

で，Extended 型のレコード型は TExtended80Rec なので，これを使用しています．
動作確認は，Windows 7 U6(SP1) + Delphi XE5 Pro (VCL-32) です．

//-----------------------------------------------------------------------------
//  (1)と(2)の計算式は，数学的には等しく，179.935となる
//  SimpleRoundToの使用にはusesにMathが必要
//  Delphi XE2 で実装された浮動小数点用レコードで計算結果の値を確認
//-----------------------------------------------------------------------------
procedure TForm1.Button1Click(Sender: TObject);
var
  a,b,c,d,e,f:Extended;
   FF: TExtended80Rec;
   I: Integer;
   StrText : string;
begin
  a:=389.7;
  b:=94.4;
  c:=30;
  d:=0.35;
  e:=(a+b+c)*d;    //(1)
  f:=a*d+b*d+c*d;  //(2)

  FF := TExtended80Rec(e);
  StrText := '';
  for I := 9 downto 0 do begin
    StrText := StrText + IntToHex(FF.Bytes[I], 2) + ' ';
  end;

  FF := TExtended80Rec(f);
  StrText := StrText + sLineBreak + '';
  for I := 9 downto 0 do begin
    StrText := StrText + IntToHex(FF.Bytes[I], 2) + ' ';
  end;

  StrText := StrText + sLineBreak + sLineBreak +
             FloatToStr(e)+#13+
             FloatToStr(f)+#13+ sLineBreak +
             FloatToStr(SimpleRoundTo(e,-2))+#13+
             FloatToStr(SimpleRoundTo(f,-2));

  MessageBox(Handle, PChar(StrText), '結果', MB_OK);
end;

[8079] Re:計算結果をバイト値で確認

返信　削除

2014/10/9 (木) 14:27:31 Mr.XRAY

> つまり，FloatToStr(SimpleRoundTo の結果は，計算結果を正確に反映していると言えます．

   FloatToStr(e)
   FloatToStr(f)

は 179.935 になります．
既に述べたように，FloatToStr が有効桁数 15 で丸めをするためと
考えられます．
つまり，今回のサンプルでは，計算結果の違いが 16 桁目以上にあることになります．
実際に [8078] でそのことを確認しました．

[System.SysUtils.FloatToStr - RAD Studio API Documentation]
http://docwiki.embarcadero.com/Libraries/XE6/ja/System.SysUtils.FloatToStr

一方，SimpleRoundTo は，引数の値としても元の値を用いようとします．
その結果ということになります．
当然ですが，以下のように，SimpleRoundTo の丸めの位置を小数点 3 桁目にすると
下図のような結果となります．

  FloatToStr(SimpleRoundTo(e,-3)+#13+
  FloatToStr(SimpleRoundTo(f,-3));

[8080] Re2:計算結果をバイト値で確認

返信　削除

2014/10/9 (木) 14:37:20 Mr.XRAY

>したがって，以下のように，SimpleRoundTo の丸めの位置を小数点 3 桁目にすると
>下図のような結果となります．

以下のようなコードでも確認できます．
小数点以下，何桁目で丸めをするかということと，
何桁目までを表示するかということとは違うことにも注意します．

procedure TForm1.Button1Click(Sender: TObject);
var
  a,b,c,d,e,f:Extended;
  StrText : string;
begin
  e:= 179.9349;
  f:= 179.9350;

  StrText := FloatToStr(e) + sLineBreak +
             FloatToStr(f) + sLineBreak + sLineBreak +
             FloatToStr(SimpleRoundTo(e,-2)) + sLineBreak +
             FloatToStr(SimpleRoundTo(f,-2)) + sLineBreak + sLineBreak +
             FloatToStr(SimpleRoundTo(e,-3)) + sLineBreak +
             FloatToStr(SimpleRoundTo(f,-3));

  MessageBox(Handle, PChar(StrText), '結果', MB_OK);
end;

179.9349 を小数点 2 桁目で丸めると，179.93 となるのは，
小数点 3 桁目の値が 4 (5 よりも小さい) だからです．
最初に示したサンプルコードでの e の計算結果は，実際には以下のようになっています．
  179.93499999999....
少なくても仮数部 (有効桁数) の 15 桁目までは 9 ということになります．

[8081] というわけで...

返信　削除

2014/10/9 (木) 14:53:27 Mr.XRAY

最初に示したサンプルの結果は，結局，

[890_計算誤差 ( 数値計算の誤差 ) と多倍長演算]
http://mrxray.on.coocan.jp/Delphi/plSamples/890_CalcError.htm

の記事の内容が原因ということが分かりました．
たまにある質問なのですが，現在のコンピュータが有限桁数の演算しか
できないというこを理解していないと，数学的に正しい結果でないことが，
疑問となることがあります．

実際問題として，最後の桁の数値が 1 ぐらい違っていても，
数値計算では誤差範囲内と言えます．

ネタ元はメールでの問い合わせですが，例によって，いろいろやってみました．
質問された方が納得するかどうかは不明です (^^;

[8083] Re:というわけで...

返信　削除

2014/10/9 (木) 22:33:50 Mr.XRAY

Delphi Forum に，内容をまとめて投稿しておきました．
[数値計算の誤差と四捨五入]
http://ht-deko.minim.ne.jp/delphiforum/?vasthtmlaction=viewtopic&t=1203.0#postid-2404

このような数値計算の誤差による違いを表現できる例というのは，
中々見つかるものではありません．
個人的には貴重なサンプルではないかと思っています．

[▼次のスレッド]

INCM/CMT
Cyclamen v3.82