unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, GDIPAPI, GDIPOBJ, GDIPUTIL, StdCtrls, ExtCtrls, ExtDlgs;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Label1: TLabel;
    Label2: TLabel;
    OpenDialog1: TOpenDialog;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure FormPaint(Sender: TObject);
  private
    { Private 宣言 }
    FImageFilePath : string;
    FLoadFilePath  : string;
    FSaveFilePath  : string;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

const
  OpenFileFilter =
    '画像ファイル|*.png;*.jpg;*.gif;*.bmp;*.tif;*.emf;*.wmf;*.ico' +
    '|*.png|*.png' +
    '|*.jpg|*.jpg' +
    '|*.gif|*.gif' +
    '|*.bmp|*.bmp' +
    '|*.tif|*.tif' +
    '|*.emf|*.emf' +
    '|*.wmf|*.wmf' +
    '|*.ico|*.ico';

//=============================================================================
//  フォーム生成時の処理
//  画像ファイルの読み出しフォルダと，保存先のフォルダをデリミタ付きで設定
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Caption := 'GDI+  各種画像形式に変換して保存';

  FLoadFilePath := ExtractFilePath(ParamStr(0)) + 'OriginalImages';
  FLoadFilePath := IncludeTrailingPathDelimiter(FLoadFilePath);

  FSaveFilePath := ExtractFilePath(ParamStr(0)) + 'ChangedImages';
  FSaveFilePath := IncludeTrailingPathDelimiter(FSaveFilePath);
end;

//=============================================================================
//  画像ファイルを読み出して，各種形式で保存
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LGPBitmap     : TGPBitmap;
  LSaveFilePath : string;
  LFileName     : string;
  LImgGUID      : TGUID;
begin
  if OpenDialog1.InitialDir = '' then begin
    OpenDialog1.InitialDir := ExtractFileDir(FLoadFilePath);
  end;

  OpenDialog1.Filter := OpenFileFilter;
  if OpenDialog1.Execute then begin
    FImageFilePath := OpenDialog1.FileName;
    LGPBitmap      := TGPBitmap.Create(FImageFilePath);

    LFileName     := ExtractFileName(FImageFilePath);
    LSaveFilePath  := FSaveFilePath + LFileName;
    Label1.Caption := LFileName;
    Label2.Caption := '左から  .bmp,  .jpg,  .gif,   .png,  .tif ';

    //指定MIMEタイプのGUIDを求め，読み出したファイル名の拡張子を変更して保存
    //ビットマップ画像として保存
    if GetEncoderClsid('image/bmp', LImgGUID) >= 0 then begin
      LGPBitmap.Save(ChangeFileExt(LSaveFilePath, '.bmp'), LImgGUID);
    end;

    //JPEG画像として保存
    if GetEncoderClsid('image/jpeg', LImgGUID) >= 0 then begin
      LGPBitmap.Save(ChangeFileExt(LSaveFilePath, '.jpg'), LImgGUID);
    end;

    //GIF画像として保存
    if GetEncoderClsid('image/gif', LImgGUID) >= 0 then begin
      LGPBitmap.Save(ChangeFileExt(LSaveFilePath, '.gif'), LImgGUID);
    end;

    //PNG画像として保存
    if GetEncoderClsid('image/png', LImgGUID) >= 0 then begin
      LGPBitmap.Save(ChangeFileExt(LSaveFilePath, '.png'), LImgGUID);
    end;

    //TIFF画像として保存
    if GetEncoderClsid('image/tiff', LImgGUID) >= 0 then begin
      LGPBitmap.Save(ChangeFileExt(LSaveFilePath, '.tif'), LImgGUID);
    end;

    LGPBitmap.Free;
    Invalidate;
  end;
end;

//=============================================================================
//  フォームのOnPaintイベント
//  読み出した画像と，保存した画像を読み出して描画
//=============================================================================
//  GetImageEncodersSize
procedure TForm1.FormPaint(Sender: TObject);
var
  LLoadFilePath : string;
  LFileName     : string;
  LGPGraphic    : TGPGraphics;
  LGPImage      : TGPImage;
  LWidth        : Integer;
  LHeight       : Integer;
  LLeft         : Integer;
  LTop          : Integer;
begin
  if FImageFilePath = '' then exit;

  LFileName      := ExtractFileName(FImageFilePath);
  LLoadFilePath  := FSaveFilePath + LFileName;

  LWidth  := 110;
  LHeight := 110;
  LLeft   := 10;
  LTop    := 40;

  //変換元の画像ファイルからTGPImageを生成
  LGPImage   := TGPImage.Create(FImageFilePath);
  //描画先はこのCanvasとする
  LGPGraphic := TGPGraphics.Create(Canvas.Handle);

  //元の画像を描画
  LGPGraphic.DrawImage(LGPImage, MakeRect(LLeft, LTop, LWidth, LHeight));

  LGPImage.Free;
  LGPGraphic.Free;


  //表示位置を設定して...
  LLeft := 10;
  LTop  := 160;
  //画像の形式を変換して保存したファイルを読み出して表示
  //ビットマップ画像に変換した画像
  LGPImage   := TGPImage.Create(ChangeFileExt(LLoadFilePath, '.bmp'));
  LGPGraphic := TGPGraphics.Create(Canvas.Handle);
  LGPGraphic.DrawImage(LGPImage, MakeRect(LLeft, LTop, LWidth, LHeight));

  LGPImage.Free;
  LGPGraphic.Free;


  LLeft := LLeft + LWidth + 10;
  //JPEG画像に変換した画像
  LGPImage   := TGPImage.Create(ChangeFileExt(LLoadFilePath, '.jpg'));
  LGPGraphic := TGPGraphics.Create(Canvas.Handle);
  LGPGraphic.DrawImage(LGPImage, MakeRect(LLeft, LTop, LWidth, LHeight));

  LGPImage.Free;
  LGPGraphic.Free;


  LLeft := LLeft + LWidth + 10;
  //GIF画像に変換した画像
  LGPImage   := TGPImage.Create(ChangeFileExt(LLoadFilePath, '.gif'));
  LGPGraphic := TGPGraphics.Create(Canvas.Handle);
  LGPGraphic.DrawImage(LGPImage, MakeRect(LLeft, LTop, LWidth, LHeight));

  LGPImage.Free;
  LGPGraphic.Free;


  LLeft := LLeft + LWidth + 10;
  //PNG画像に変換した画像
  LGPImage   := TGPImage.Create(ChangeFileExt(LLoadFilePath, '.png'));
  LGPGraphic := TGPGraphics.Create(Canvas.Handle);
  LGPGraphic.DrawImage(LGPImage, MakeRect(LLeft, LTop, LWidth, LHeight));

  LGPImage.Free;
  LGPGraphic.Free;


  LLeft := LLeft + LWidth + 10;
  //TIFF画像に変換した画像
  LGPImage   := TGPImage.Create(ChangeFileExt(LLoadFilePath, '.tif'));
  LGPGraphic := TGPGraphics.Create(Canvas.Handle);
  LGPGraphic.DrawImage(LGPImage, MakeRect(LLeft, LTop, LWidth, LHeight));

  LGPImage.Free;
  LGPGraphic.Free;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, GDIPAPI, GDIPOBJ, GDIPUTIL;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Image1: TImage;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  Math;

{$R *.dfm}

//=============================================================================
//  マルチページTIFF画像の作成
//  ビットマップ,GIF,PNG画像をTIFFに変換して1つのファイルに格納
//  変換形式は何も設定していないのでデフォルトのまま
//
//  このコードは新規作成(上書き)保存としている　　
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LSaveFilePath      : string;
  LEncoderParams     : TEncoderParameters;
  LEncoderParamValue : TEncoderValue;
  LclsidTIFF         : TGUID;
  LGPImage          : TGPImage;
  LGPImageTIFF      : TGPImage;
begin
  Button1.Enabled := False;
  Button2.Enabled := False;
  Sleep(100);
  Button2.Refresh;

  //保存ファイル名
  LSaveFilePath := ExtractFilePath(Application.ExeName) + 'MultiTest.tif';

  //ここではTIFFへのエンコードだけ指定
  LEncoderParams.Count := 1;
  LEncoderParams.Parameter[0].Guid           := EncoderSaveFlag;
  LEncoderParams.Parameter[0].Type_          := EncoderParameterValueTypeLong;
  LEncoderParams.Parameter[0].NumberOfValues := 1;
  LEncoderParams.Parameter[0].Value          := @LEncoderParamValue;
  //TIFFのGUIDを取得
  GetEncoderClsid('image/tiff', LclsidTIFF);

  //最初の画像をTGPImageに読み込みマルチ画像であることを指定して保存
  LGPImage := TGPImage.Create('503.bmp');
  LEncoderParamValue := EncoderValueMultiFrame;
  LGPImage.Save(LSaveFilePath, LclsidTIFF, @LEncoderParams);

  //2番目以降は別のTGPImageを生成して読み込み，それをSaveAddで追加保存する
  LGPImageTIFF := TGPImage.Create('ABC.bmp');
  try
    LEncoderParamValue := EncoderValueFrameDimensionPage;
    LGPImage.SaveAdd(LGPImageTIFF, @LEncoderParams);
  finally
    LGPImageTIFF.Free;
  end;

  LGPImageTIFF := TGPImage.Create('054709.gif');
  try
    LEncoderParamValue := EncoderValueFrameDimensionPage;
    LGPImage.SaveAdd(LGPImageTIFF, @LEncoderParams);
  finally
    LGPImageTIFF.Free;
  end;

  LGPImageTIFF := TGPImage.Create('agt_business.png');
  try
    LEncoderParamValue := EncoderValueFrameDimensionPage;
    LGPImage.SaveAdd(LGPImageTIFF, @LEncoderParams);
  finally
    LGPImageTIFF.Free;
  end;

  LGPImage.Free;

  Button1.Enabled := True;
  Button2.Enabled := True;
end;

//=============================================================================
//  マルチページTIFFの表示
//  指定時間間隔で各ページを表示
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LGPGraphic      : TGPGraphics;
  LGPImage        : TGPImage;
  LPageGuid       : TGUID;
  LPageCount      : Cardinal;
  LPageDimensions : TGPSizeF;
  i               : Integer;
begin
  Button1.Enabled := False;
  Sleep(100);
  Button1.Refresh;
  Button2.Enabled := False;

  LGPGraphic := TGPGraphics.Create(Image1.Canvas.Handle);

  //TGPImageを生成して画像を読み込み，ページ数を取得
  LGPImage   := TGPImage.Create('MultiTest.tif');
  LPageGuid  := FrameDimensionPage;
  LPageCount := LGPImage.GetFrameCount(LPageGuid);

  //順番に表示
  for i := 0 to LPageCount - 1 do begin
    LGPImage.SelectActiveFrame(LPageGuid, i);
    LGPImage.GetPhysicalDimension(LPageDimensions);
    //各ページの画像のサイズが必要なら，以下のコードで取得
    //Image1.Width  := Trunc(LPageDimensions.Width);
    //Image1.Height := Trunc(LPageDimensions.Height);

    //TImageのCanvasを現在の色で塗り潰す(画像のクリア)
    Image1.Canvas.FillRect(Image1.Canvas.ClipRect);
    //表示
    LGPGraphic.DrawImage(LGPImage, MakeRect(0, 0, Image1.Width, Image1.Height));
    //描画の更新
    Image1.Repaint;
    Sleep(1000);
  end;

  LGPGraphic.Free;
  LGPImage.Free;

  Button1.Enabled := True;
  Button2.Enabled := True;
end;

end.