procedure TCustomShellListView.DblClick;
begin
  if FAutoNavigate and (Selected <> nil) then
    with Folders[Selected.Index] do
      if IsFolder then
        SetPathFromID(AbsoluteID)
      else
        ExecuteDefault;                                      //追加
//        ShellExecute(Handle, nil, PChar(PathName), nil,    //削除
//          PChar(ExtractFilePath(PathName)), 0);            //削除
  inherited DblClick;
end;

procedure TCustomShellListView.DblClick;
var
  LFolder : TShellFolder;
begin
  if FAutoNavigate and (Selected <> nil) then begin
    LFolder := Folders[Selected.Index];
    if LFolder.IsFolder then begin
      SetPathFromID(LFolder.AbsoluteID);
    end else begin
      LFolder.ExecuteDefault;
    end;
  end;

  //inherited DblClickはOnDblClickイベントを実行するだけ
  inherited DblClick;
end;

//=============================================================================
//  デスクトップを表示している状態で、TShellListViewの項目が未選択の場合
//  以下のコードを実行すると、終了時に例外が発生
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LPath : String;
begin
  if ShellTreeView1.Selected <> nil then begin
    LPath := ShellTreeView1.Path;
    Memo1.Lines.Add(LPath);
  end;
end;

//=============================================================================
//  TShellListViewのOnAddFolderイベント処理
//  このイベントは、現在のフォルダ内のファイル数だけ実行される
//  指定した拡張子のファイル名だけをリストする例
//
//  イベントの引数CanAddの値をFalseにすると非表示となる。デフォルトはTrue
//  MatchTextの使用にはusesにStrUtilsが必要
//=============================================================================
procedure TForm1.ShellListView1AddFolder(Sender: TObject; AFolder: TShellFolder;
  var CanAdd: Boolean);
var
  Ext : String;
begin
  //フォルダは表示
  if AFolder.IsFolder then exit;

  //拡張子が.jpgと.bmpのファイルのみ表示
  Ext    := ExtractFileExt(AFolder.PathName);
  CanAdd := MatchText(Ext, ['.jpg', '.bmp']);
end;

//=============================================================================
//  現在選択中のフォルダとファイル名を取得する例
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LItem   : TListItem;
  LFolder : TShellFolder;
begin
  Memo1.Clear;

  LItem := ShellListView1.Selected;
  while LItem <> nil do begin
    LFolder := ShellListView1.Folders[LItem.Index];
    Memo1.Lines.Add(LFolder.PathName);
    LItem := ShellListView1.GetNextItem(LItem, sdAll, [isSelected]);
  end;
end;

//-----------------------------------------------------------------------------
//  項目識別子(完全項目識別子)からフルパスを取得する関数
//  この関数を使用するにはusesにShlObjが必要
//-----------------------------------------------------------------------------
function GetFullPathFromABSPItemID(pidlFull: PItemIDList): String;
var
  pShFolder : IShellFolder;
  pidl      : PItemIDList;
  StrRet    : TStrRet;
begin
  Result := '';

  //該当ファイルのフォルダオブジェクト(pShFolder)と、相対項目識別子をpidlに取得
  SHBindToParent(pidlFull, IShellFolder, Pointer(pShFolder), pidl);
  FillChar(StrRet, SizeOf(StrRet), 0);
  if pShFolder.GetDisplayNameOf(pidl, SHGDN_FORPARSING, StrRet) = S_OK then begin
    Result := StrRet.pOleStr;
  end;
end;

//=============================================================================
//  現在選択中のフォルダとファイル名を実パス名で取得する例
//  仮想フォルダ等はGUID文字列となる
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LItem     : TListItem;
  LFolder   : TShellFolder;
  LFullPath : String;
begin
  Memo1.Clear;

  LItem := ShellListView1.Selected;
  while LItem <> nil do begin
    LFolder   := ShellListView1.Folders[LItem.Index];
    LFullPath := GetFullPathFromABSPItemID(LFolder.AbsoluteID);
    Memo1.Lines.Add(LFullPath);
    LItem := ShellListView1.GetNextItem(LItem, sdAll, [isSelected]);
  end;
end;

//=============================================================================
//  ルートフォルダを[Dドライブ]にする例
//  TShellTreeViewを使用していない場合は、そのフォルダ内のファイルをリスト
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  ShellListView1.Root := 'D:\';
end;

//=============================================================================
//  ルートフォルダを仮想フォルダの[ライブラリ]にする例
//  TShellTreeViewを使用していない場合は、そのフォルダ内のファイルをリスト
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  ShellListView1.Root := '::{031E4825-7B94-4DC3-B131-E946B44C8DD5}';
end;

//=============================================================================
//  ルートフォルダを仮想フォルダの[ライブラリ]にする例
//  TShellTreeViewを使用していない場合は、そのフォルダ内のファイルをリスト
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
begin
  ShellListView1.Root := 'shell:UsersLibrariesFolder';
end;

//=============================================================================
//  Delphiに付属のTShellListViewで表示形式を[タイル]にするコード
//  [詳細]と[タイル]のトグル
//  場合によってはTShellListView.Refreshが必要かも知れない
//=============================================================================
{$WRITEABLECONST ON}
procedure TForm1.Button2Click(Sender: TObject);
const
  ID_Value : Integer = 0;
var
  LiView : Cardinal;
begin
  if ID_Value = 0 then begin
    LiView := LV_VIEW_TILE;
    ID_Value := 1;
  end else begin
    LiView := LV_VIEW_DETAILS;
    ID_Value := 0;
  end;
  SendMessage(ShellListView1.Handle, LVM_SETVIEW, WPARAM(LiView), 0);
end;
{$WRITEABLECONST OFF}