uses
  ShellAPI;

{$R *.dfm}

//=============================================================================
//  拡張子に関連付けされたプログラムを起動して動画を再生
//  ShellExecute関数の使用にはusesにShellAPIが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LMediaFile : string;
begin
  LMediaFile := 'C:\Users\Public\Videos\Sample Videos\Wildlife.wmv';
  ShellExecute(Handle, '', PChar(LMediaFile), nil, nil, SW_HIDE);
end;

//=============================================================================
//  Windows Media Player で動画を再生
//  再生するファイルのパスに空白文字があるので " 括っていることに注意
//  ShellExecute関数の使用にはusesにShellAPIが必要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LExePath   : string;
  LMediaFile : string;
begin
  LExePath   := 'C:\Program Files (x86)\Windows Media Player\wmplayer.exe';
  LMediaFile := '"C:\Users\Public\Videos\Sample Videos\Wildlife.wmv"';
  ShellExecute(Handle, '', PChar(LExePath), PChar(LMediaFile), nil, SW_SHOW);
end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, MPlayer, ExtCtrls;

type
  TForm1 = class(TForm)
    MediaPlayer1: TMediaPlayer;
    Button1: TButton;
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure Button1Click(Sender: TObject);
  private
  protected
    procedure CMShowingchanged(var Message: TMessage);
      message CM_SHOWINGCHANGED;
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム表示直後の処理
//  フォームが表示されていないとフォームの位置とサイズが取得できないので
//  CM_SHOWINGCHANGEDで処理
//=============================================================================
procedure TForm1.CMShowingchanged(var Message: TMessage);
begin
  inherited;
  if not Visible then exit;

  MediaPlayer1.DeviceType := dtAutoSelect;
  MediaPlayer1.AutoRewind := True;
  MediaPlayer1.FileName   := 'C:\Users\Public\Videos\Sample Videos\Wildlife.wmv';
  MediaPlayer1.Open;

  Button1Click(nil);
end;

//=============================================================================
//  フォームを閉じる時の処理
//=============================================================================
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  MediaPlayer1.Stop;
  MediaPlayer1.Close;
end;

//=============================================================================
//  表示位置とサイズを変更
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LRect   : TRect;
  LWidth  : Integer;
  LHeight : Integer;
  LLeft   : Integer;
  LTop    : Integer;
  LhWnd   : HWND;
begin
  //デフォルトの出力デバイスにおける表示サイズを取得
  LRect   := MediaPlayer1.DisplayRect;

  LWidth  := (LRect.Right  - LRect.Left) div 3;
  LHeight := (LRect.Bottom - LRect.Top)  div 3;

  //ウィンドウのフレームのサイズとキャプションバーの高さを加算
  LWidth  := LWidth  + GetSystemMetrics(SM_CXFRAME) * 2;
  LHeight := LHeight + GetSystemMetrics(SM_CYFRAME) + GetSystemMetrics(SM_CYCAPTION);

  LLeft := Self.Left + Self.Width - LWidth;
  LTop  := Self.Top - LHeight;

  LhWnd := FindWindow('MCIQTZ_Window', nil);
  if LhWnd <> 0 then begin
    SetWindowPos(LhWnd, 0, LLeft, LTop, LWidth, LHeight, SWP_NOZORDER);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, MPlayer, ExtCtrls;

type
  TForm1 = class(TForm)
    MediaPlayer1: TMediaPlayer;
    Panel1: TPanel;
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  LRect   : TRect;
  LWidth  : Integer;
  LHeight : Integer;
begin

  MediaPlayer1.DeviceType := dtAutoSelect;
  MediaPlayer1.FileName   := 'C:\Users\Public\Videos\Sample Videos\Wildlife.wmv';
  MediaPlayer1.Open;

  //デフォルトの出力デバイスにおける表示サイズを取得
  LRect   := MediaPlayer1.DisplayRect;
  LWidth  := LRect.Right - LRect.Left;
  LHeight := LRect.Bottom - LRect.Top;

  MediaPlayer1.Display := Panel1;
  MediaPlayer1.DisplayRect := Rect(0, 0, LWidth div 3, LHeight div 3);
end;

//=============================================================================
//  フォームを閉じる時の処理
//=============================================================================
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  if MediaPlayer1.DeviceID = 0 then exit;

  MediaPlayer1.Stop;
  MediaPlayer1.Close;
end;

end.

//=============================================================================
//  フォーム生成時の処理
//  FVideoWidth, FVideoHeightはInteger型のグローバル変数
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  LVideoRect : TRect;
begin
  MediaPlayer1.DeviceType := dtAutoSelect;
  MediaPlayer1.FileName   := 'C:\Users\Public\Videos\Sample Videos\Wildlife.wmv';
  MediaPlayer1.Open;

  MediaPlayer1.Display := Panel1;

  //オリジナルのサイズを取得しておく
  LVideoRect   := MediaPlayer1.DisplayRect;
  FVideoWidth  := LVideoRect.Right  - LVideoRect.Left;
  FVideoHeight := LVideoRect.Bottom - LVideoRect.Top;

  Panel1Resize(nil);
end;

//=============================================================================
//  フォームを閉じる時の処理
//=============================================================================
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  if MediaPlayer1.DeviceID = 0 then exit;

  MediaPlayer1.Stop;
  MediaPlayer1.Close;
end;

//=============================================================================
//  Panel1のOnResizeイベント処理
//=============================================================================
procedure TForm1.Panel1Resize(Sender: TObject);
var
  LVideoRatio : Double;
  LDispRatio  : Double;
  LDispLeft   : Integer;
  LDispTop    : Integer;
  LDispWidth  : Integer;
  LDispHeight : Integer;
begin
  if MediaPlayer1.DeviceID = 0 then exit;
  if FVideoWidth = 0 then exit;

  LVideoRatio := FVideoHeight / FVideoWidth;
  LDispRatio  := Panel1.Height / Panel1.Width;

  if LDispRatio > LVideoRatio then begin
    LDispLeft   := 0;
    LDispWidth  := Panel1.Width;
    LDispHeight := Round(LDispWidth * LVideoRatio);
    LDispTop    := Abs((Panel1.Height - LDispHeight) div 2);
  end else begin
    LDispTop    := 0;
    LDispHeight := Panel1.Height;
    LDispWidth  := Round(LDispHeight / LVideoRatio);
    LDispLeft   := (Panel1.Width - LDispWidth) div 2;
  end;

  //DisplayRect要素の値はTRect本来の定義とは違うようだ
  MediaPlayer1.DisplayRect := Rect(LDispLeft, LDispTop, LDispWidth, LDispHeight);
end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, OleCtrls, WMPLib_TLB;

type
  TForm1 = class(TForm)
    WindowsMediaPlayer1: TWindowsMediaPlayer;
    procedure FormCreate(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  WindowsMediaPlayer1.Align := alClient;

  WindowsMediaPlayer1.URL := 'C:\Users\Public\Videos\Sample Videos\Wildlife.wmv';
end;

end.

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
 WindowsMediaPlayer1.Align := alClient;

  WindowsMediaPlayer1.URL := 'bongo1.wmv';
  WindowsMediaPlayer1.stretchToFit := True;
end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, OleCtrls, WMPLib_TLB;

type
  TForm1 = class(TForm)
    WindowsMediaPlayer1: TWindowsMediaPlayer;
    procedure FormCreate(Sender: TObject);
    procedure FormResize(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  ShlObj,
  ActiveX;

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  LWMPCore    : IWMPCore;
  LWMPPlayer4 : IWMPPlayer4;
begin
  //DefaultInterfaceのインスタンスを取得
  LWMPCore := WindowsMediaPlayer1.DefaultInterface;

  //IWMPPlayer4インターフェイスのインスタンスを取得
  if LWMPCore.QueryInterface(IID_IWMPPlayer4, LWMPPlayer4) = S_OK then begin
    LWMPPlayer4.stretchToFit := False;
  end;

  //動画ファイルの指定
  WindowsMediaPlayer1.URL := 'bongo1.wmv';
end;

//=============================================================================
//  フォームをリサイズした時の処理
//=============================================================================
procedure TForm1.FormResize(Sender: TObject);
var
  LWMPCore   : IWMPCore;
  LOleObject : IOleInPlaceObject;
  LCtrlRect  : TRect;
begin
  //DefaultInterfaceのインスタンスを取得
  LWMPCore := WindowsMediaPlayer1.DefaultInterface;

  //IOleInPlaceObjectインターフェイスのインスタンスを取得して
  //そのSetObjectRectsメソッドでInPlaceObjectの描画位置とサイズを設定
  if LWMPCore.QueryInterface(IOleInPlaceObject, LOleObject) = S_OK then begin
    SetRect(LCtrlRect, 0, 0, Self.ClientWidth, Self.ClientHeight);
    LOleObject.SetObjectRects(LCtrlRect, LCtrlRect);
  end;
end;

end.

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  LWMPPlayer4 : IWMPPlayer4;
begin
  //テストなので
  WindowsMediaPlayer1.Align := alNone;

  //LWMPPlayer4のインスタンスを取得
  //Delphi XEではIWMPPlayer4がDefaultInterface
  LWMPPlayer4 := WindowsMediaPlayer1.DefaultInterface;
  LWMPPlayer4.stretchToFit := True;

  //動画ファイルの指定
  WindowsMediaPlayer1.URL := 'bongo1.wmv';
end;

//=============================================================================
//  フォームをリサイズした時の処理
//=============================================================================
procedure TForm1.FormResize(Sender: TObject);
var
  LWMPPlayer4 : IWMPPlayer4;
  LOleObject  : IOleInPlaceObject;
  LCtrlRect   : TRect;
begin
  //DefaultInterfaceのインスタンスを取得
  LWMPPlayer4 := WindowsMediaPlayer1.DefaultInterface;

  //IOleInPlaceObjectインターフェイスのインスタンスを取得して
  //そのSetObjectRectsメソッドでInPlaceObjectの描画位置とサイズを設定
  if LWMPPlayer4.QueryInterface(IOleInPlaceObject, LOleObject) = S_OK then begin
    SetRect(LCtrlRect, 0, 0, Self.ClientWidth, Self.ClientHeight);
    LOleObject.SetObjectRects(LCtrlRect, LCtrlRect);
  end;
end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, MMSystem;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
    FMCIOpenParams : TMCI_Open_Parms;
    FMCIPlayParams : TMCI_Play_Parms;
    FDeviceID      : Word;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//  mci関係の関数，定数名の使用にはusesにMMSystemが必要
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  LMediaFile : string;
begin
  LMediaFile := 'ibutama.wmv';

  FMCIOpenParams.lpstrElementName := PChar(LMediaFile);
  mciSendCommand(0, MCI_OPEN, MCI_OPEN_ELEMENT, Integer(@FMCIOpenParams));
  FDeviceID := FMCIOpenParams.wDeviceID;

  Button1.Caption := 'Play';
  Button2.Caption := 'Stop';
end;

//=============================================================================
//  フォームを閉じる時の処理
//=============================================================================
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  mciSendCommand(FDeviceID, MCI_STOP, 0, 0);
  mciSendCommand(FDeviceID, MCI_CLOSE, 0, 0);
end;

//=============================================================================
//  Start
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  mciSendCommand(FDeviceID, MCI_PLAY, 0, Integer(@FMCIPlayParams));
end;

//=============================================================================
//  Stop
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  mciSendCommand(FDeviceID, MCI_STOP, 0, 0);
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, DSPack;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    FilterGraph1: TFilterGraph;
    Panel1: TPanel;
    DSVideoWindowEx21: TDSVideoWindowEx2;
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  LMediaFile : string;
begin
  LMediaFile := 'C:\Users\Public\Videos\Sample Videos\Wildlife.wmv';

  FilterGraph1.Active:= True;
  DSVideoWindowEx21.FilterGraph := FilterGraph1;
  FilterGraph1.RenderFile(LMediaFile);

  Button1.Caption := 'Play';
  Button2.Caption := 'Pause';
end;

//=============================================================================
//  フォームを閉じる時の処理
//=============================================================================
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  FilterGraph1.ClearGraph;
  FilterGraph1.Active := False;
end;

//=============================================================================
//  Start
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  FilterGraph1.Play;
end;

//=============================================================================
//  Pause
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  FilterGraph1.Pause;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, DSPack;

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    VideoWindow1: TVideoWindow;
    FilterGraph1: TFilterGraph;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    OpenDialog1: TOpenDialog;
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  private
    { Private 宣言 }
    FMediaFile : string;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//
//  Panel1はAlignをalTopにしてからAnchorsのakBottomをTrueにしている
//  Panel1の上にTVideoWindowを配置.AlignはalClient
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Button1.Caption := 'Open';
  Button2.Caption := 'Play';
  Button3.Caption := 'Pause';
end;

//=============================================================================
//  フォームを閉じる時の処理
//=============================================================================
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  FilterGraph1.ClearGraph;
  FilterGraph1.Active := False;
end;

//=============================================================================
//  Open
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LAction : TCloseAction;
begin
  if OpenDialog1.Execute then begin
    LAction := caNone;
    FormClose(nil, LAction);

    FMediaFile := OpenDialog1.FileName;

    FilterGraph1.Active      := True;
    VideoWindow1.FilterGraph := FilterGraph1;
    FilterGraph1.RenderFile(FMediaFile);

    Button2Click(nil);
  end;
end;

//=============================================================================
//  Play
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  FilterGraph1.Play;
end;

//=============================================================================
//  Pause
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
begin
  FilterGraph1.Pause;
end;

end.