function(Wnd: HWND; Message: UINT; wParam: WPARAM; lParam: LPARAM): UINT stdcall;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, CommDlg;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses Printers;

{$R *.dfm}

//=============================================================================
//  PringDlg APIで[印刷]ダイアログの表示 1
//  引数の構造体の設定を，ほとんどデフォルトのままで実行
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  PrintDlgRec : TPrintDlg;
begin
  //構造体を0で埋める(つまり初期化)
  FillChar(PrintDlgRec, SizeOf(TPrintDlg), #0);

  //構造体(TPrintDlg)の各メンバの設定
  with PrintDlgRec do begin
    lStructSize := SizeOf(TPrintDlg);
    hWndOwner   := Handle;
    Flags       := 0;
  end;

  //ダイアログ表示
  if PrintDlg(PrintDlgRec) then begin
    //ここに印刷のコードを書く
    //ダイアログの設定内容が，構造体の各メンバーから取得できる
  end;
end;

//-----------------------------------------------------------------------------
//  PringDlg APIのコールバック関数([印刷]ダイアログ用)
//  このコードに実用性はない．このように使用できるというサンプル
//-----------------------------------------------------------------------------
function PrintHookProc(Wnd: HWND; Message: UINT; wParam: WPARAM;
  lParam: LPARAM): UINT stdcall;
var
  hWindow: HWND;
begin
  Result := 0;

  //初期化の時に処理(当然?)
  if Message = WM_INITDIALOG then begin
    //[ファイルへ出力]部分のハンドルを取得
    hWindow := GetDlgItem(Wnd, 1040);
    //そのハンドルのウィンドウを非表示
    ShowWindow(hWindow, SW_HIDE);

    //[部単位で印刷]部分のハンドルを取得
    hWindow := GetDlgItem(Wnd, 1041);
    //そのハンドルのウィンドウを非表示
    ShowWindow(hWindow, SW_HIDE);
  end;
end;

//=============================================================================
//  PringDlg APIを使用した[印刷]ダイアログの表示 2
//  コールバック関数の使用例
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  PrintDlgRec : TPrintDlg;
begin
  //構造体を0で埋める(つまり初期化)
  FillChar(PrintDlgRec, SizeOf(TPrintDlg), #0);

  //構造体(TPrintDlg)の各メンバの設定
  with PrintDlgRec do begin
    lStructSize   := SizeOf(TPrintDlg);
    hWndOwner     := Handle;
    //テストのため頁と部数を設定
    nFromPage     := 1;
    nToPage       := 6;
    //nMinPaeとnMaxPageがなければ[部単位で印刷]は非表示
    nMinPage      := 0;
    nMaxPage      := 4;
    //nCopiesがなければ当然[部単位で印刷]は無効表示となる
    nCopies       := 3;
    //コールバック関数を使用するフラグ
    Flags         := PD_ENABLEPRINTHOOK;
    //使用するコールバック関数のアドレスをセット
    lpfnPrintHook := @PrintHookProc;
  end;

  //ダイアログ表示
  if PrintDlg(PrintDlgRec) then begin
    //ここに印刷のコードを書く
    //ダイアログの設定内容が，構造体の各メンバーから取得できる
  end;
end;

//=============================================================================
//  PringDlg APIを使用した[プリンタの設定]ダイアログの表示 1
//  メンバーのFlagsにPD_PRINTSETUPを含めると，[プリンタ設定]ダイアログとなる
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
var
  PrintDlgRec: TPrintDlg;
begin
  //構造体を0で埋める(つまり初期化)
  FillChar(PrintDlgRec, SizeOf(TPrintDlg), #0);

  //各パラメータ(TPringDlg構造体)の設定
  with PrintDlgRec do begin
    lStructSize := SizeOf(TPrintDlg);
    hWndOwner   := Handle;
    Flags       := PD_PRINTSETUP;
  end;

  //ダイアログ表示
  if PrintDlg(PrintDlgRec) then begin
    //ここに印刷のコードを書く
    //ダイアログの設定内容が，構造体の各メンバーから取得できる
  end;
end;

//=============================================================================
//  PringDlg APIを使用した[プリンタの設定]ダイアログの表示 2
//  メンバーのFlagsにPD_PRINTSETUPを含めると，[プリンタ設定]ダイアログとなる
//
//  用紙サイズと印刷の向きを指定してダイアログを表示する例
//  usesにPrintersが必要
//=============================================================================
procedure TForm1.Button4Click(Sender: TObject);
var
  PrintDlgRec : TPrintDlg;
  ADevice     : array[0..MAX_PATH - 1] of Char;
  ADriver     : array[0..MAX_PATH - 1] of Char;
  APort       : array[0..MAX_PATH - 1] of Char;
  ADeviceMode : THandle;
  ADevMode    : PDeviceMode;
begin
  Printer.GetPrinter(ADevice, ADriver, APort, ADeviceMode);
  //ADeviceModeのメモリをロックしDEVMODE構造体のポインタを取得
  ADevMode := GlobalLock(ADeviceMode);
  try
    //実際には該当メンバーをサポートしているかチェックしてからセットするのがよい
    ADevMode^.dmPaperSize   := DMPAPER_A3;
    ADevMode^.dmOrientation := DMORIENT_LANDSCAPE;
  finally
    GlobalUnlock(ADeviceMode);
  end;

  //構造体を0で埋める(つまり初期化)
  FillChar(PrintDlgRec, SizeOf(TPrintDlg), #0);

  //各パラメータ(TPageSetupDlg構造体)の設定
  with PrintDlgRec do begin
    lStructSize := SizeOf(TPrintDlg);
    hWndOwner   := Handle;
    hDevMode    := ADeviceMode;
    Flags       := PD_PRINTSETUP;
  end;

  //ダイアログ表示
  if PrintDlg(PrintDlgRec) then begin
    //ここに印刷のコードを書く
    //ダイアログの設定内容が，構造体の各メンバーから取得できる
  end;
end;

end.

procedure TForm1.Button4Click(Sender: TObject);
var
  AIndex      : Integer;
  ADevice     : array[0..MAX_PATH - 1] of Char;
  ADriver     : array[0..MAX_PATH - 1] of Char;
  APort       : array[0..MAX_PATH - 1] of Char;
  ADeviceMode : THandle;
  ADevMode    : PDeviceMode;
  PrintDlgRec : TPrintDlg;
begin
  //プリンタのインデックスを求める(簡略法)
  AIndex := Printer.Printers.IndexOf('プリンタ名');
  Printer.PrinterIndex := AIndex;
  //Printer.PrinteIndexのプリンタの初期化
  //この3行で実行しないと，ADeviceModeの内容が更新されない
  Printer.GetPrinter(ADevice, ADriver, APort, ADeviceMode);
  Printer.SetPrinter(ADevice, ADriver, APort, 0);
  Printer.GetPrinter(ADevice, ADriver, APort, ADeviceMode);

  //プリンタのプロパティの設定をしなければこのコードは不要
  ADevMode := GlobalLock(ADeviceMode);
  try
    //必要であればここでプリンタのプロパティの設定を行う
  finally
    GlobalUnlock(ADeviceMode);
  end;

  //構造体を0で埋める(つまり初期化)
  FillChar(PrintDlgRec, SizeOf(TPrintDlg), #0);

  //各パラメータ(TPageSetupDlg構造体)の設定
  with PrintDlgRec do begin
    lStructSize := SizeOf(TPrintDlg);
    hWndOwner   := Handle;
    Flags       := PD_PRINTSETUP;
    hDevMode    := ADeviceMode;
  end;

  //ダイアログ表示
  if PrintDlg(PrintDlgRec) then begin
    //ここに印刷のコードを書く
    //ダイアログの設定内容が，構造体の各メンバーから取得できる
  end;
end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, CommDlg, CommCtrl;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

//-----------------------------------------------------------------------------
//  PrintDlgEx用の定数と構造体(レコード型)と関数の定義
//  Delphi XEにないものだけを追加
//-----------------------------------------------------------------------------
const
  START_PAGE_GENERAL  = $FFFFFFFF;
  PD_RESULT_APPLY     = 2;
  PD_RESULT_CANCEL    = 0;
  PD_RESULT_PRINT     = 1;
  PD_EXCLUSIONFLAGS   = $01000000;
  PD_CURRENTPAGE      = $00400000;
  PD_NOCURRENTPAGE    = $00800000;
  PD_USELARGETEMPLATE = $10000000;

type
  PPRINTPAGERANGE = ^TPRINTPAGERANGE;
  tagPRINTPAGERANGE = packed record
    nFromPage : DWORD;
    nToPage   : DWORD;
  end;
  TPrintPageRange  = tagPRINTPAGERANGE;

  PPRINTDLGEX = ^TPRINTDLGEX;
  tagPDEX = packed record
    lStructSize         : DWORD;
    hwndOwner           : HWND;
    hDevMode            : HGLOBAL;
    hDevNames           : HGLOBAL;
    hDC                 : HDC;
    Flags               : DWORD;
    Flags2              : DWORD;
    ExclusionFlags      : DWORD;
    nPageRanges         : DWORD;
    nMaxPageRanges      : DWORD;
    lpPageRanges        : PPRINTPAGERANGE;
    nMinPage            : DWORD;
    nMaxPage            : DWORD;
    nCopies             : DWORD;
    hInstance           : HINST;
    lpPrintTemplateName : PAnsiChar;
    lpCallback          : PUNKNOWN;
    nPropertyPages      : DWORD;
    lphPropertyPages    : HPropSheetPage; //CommCtrl.pas
    nStartPage          : DWORD;
    dwResultAction      : DWORD;
  end;
  TPrintDlgEx = tagPDEX;

  TPageRange = packed record
    nFromPage, nToPage : DWord;
  end;

  function PrintDlgEx(var PrintDlgEx: TPrintDlgEx): HRESULT; stdcall;
//-----------------------------------------------------------------------------

var
  Form1: TForm1;

implementation

{$R *.dfm}
//リソースをインクルード
{$R TEST.RES}

function PrintDlgEx; external 'comdlg32.dll' name 'PrintDlgExW';

//=============================================================================
//  PringDlgEx APIで[印刷]ダイアログの表示 1
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  PDEXRec : TPrintDlgEx;
begin
  //構造体を0で埋める(つまり初期化)
  FillChar(PDEXRec, SizeOf(PDEXRec), #0);

  //構造体(レコード型)の各メンバーに値をセット
  with PDEXRec do begin
    lStructSize    := SizeOf(TPrintDlgEx);
    hWndOwner      := Handle;
    Flags          := PD_ALLPAGES or PD_NOPAGENUMS;
    nMaxPageRanges := 3;
    nMinPage       := 1;
    nMaxPage       := 10;
    nCopies        := 1;
    nStartPage     := START_PAGE_GENERAL;
  end;

  if PrintDlgEx(PDEXRec) = PD_RESULT_PRINT then begin
    //ここに印刷コードを書く
    //ダイアログで設定した内容は，構造体の各メンバーから取得する
  end;
end;

//=============================================================================
//  PringDlgEx APIで[印刷]ダイアログの表示 2
//  ページ指定を設定してから表示
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  PDEXRec        : TPrintDlgEx;
  PageRangeArray : array[0..1] of TPrintPageRange;
begin

  //構造体を0で埋める(つまり初期化)
  FillChar(PDEXRec, SizeOf(PDEXRec), #0);

  //ページ指定の場合の，ページの範囲を設定
  PageRangeArray[0].nFromPage := 1;
  PageRangeArray[0].nToPage   := 3;
  PageRangeArray[1].nFromPage := 5;
  PageRangeArray[1].nToPage   := 8;

  //構造体(レコード型)の各メンバーに値をセット
  with PDEXRec do begin
    lStructSize    := SizeOf(TPrintDlgEx);
    hWndOwner      := Handle;
    Flags          := PD_PAGENUMS;
    nMaxPageRanges := 3;
    nPageRanges    := Length(PageRangeArray);
    lpPageRanges   := @PageRangeArray[0];
    nMinPage       := 1;
    nMaxPage       := 10;
    nCopies        := 1;
    nStartPage     := START_PAGE_GENERAL;
  end;

  if PrintDlgEx(PDEXRec) = PD_RESULT_PRINT then begin
    //ここに印刷コードを書く
    //ダイアログで設定した内容は，構造体の各メンバーから取得する
  end;
end;

//-----------------------------------------------------------------------------
//  TPropSheetPage(プロパティシート用構造体)のコールバック関数
//  pfnDlgProcメンバの値に，この関数名のポインタを指定する
//
//  この関数内では，EndDialogを呼び出してはいけない．戻り値は通常0とする
//-----------------------------------------------------------------------------
function PropSheetHookProc(Wnd: HWND; Message: UINT; wParam: WPARAM;
      lParam: LPARAM): UINT stdcall;
var
  TextEdit : String;
begin
  Result := 0;

  if Message = WM_COMMAND then begin
    //[OK]ボタンクリック
    //if wParam = IDOK でも可
    if wParam = 1 then begin
      MessageDlg('[ OK ] ボタンを押しましたね　',mtInformation, [mbOK], 0);
    end else
    //[参照]ボタンクリック
    if wParam = 102 then begin
      TextEdit := 'プロパティシート追加のテスト';
      SetDlgItemText(Wnd, 101, PChar(TextEdit));
    end;
  end;
end;

//=============================================================================
//  PringDlgEx APIで[印刷]ダイアログの表示 3
//  ページ指定を設定してから表示
//  ダイアログにユーザ設定のタブシート(プロパティシート)を追加する例
//  ここでは，リソースファイル(.RES)に格納してあるダイアログを表示
//
//  プロパティシート関係のコードには，usesにCommCtrlが必要
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
var
  hpsp    : array[0..0] of PPropSheetPage;
  psp     : TPropSheetPage;
  PDEXRec : TPrintDlgEx;
begin
  //プロパティシート用構造体を初期化
  FillChar(psp, SizeOf(TPropSheetPage), #0);

  with psp do begin
    dwSize      := SizeOf(TPropSheetPage);
    dwFlags     := PSP_USETITLE;
    pszTemplate := MakeIntResource('DIALOG_1');
    pfnDlgProc  := @PropSheetHookProc;
    hInstance   := hInstance;
    //deFlagsにPSP_USETITLEがあると，元のダイアログのCatioonの変更が可能
    pszTitle := '印刷ファイル';
  end;
  //上の設定で0番目のプロパティシートを作成
  hpsp[0] := CreatePropertySheetPage(psp);


  //PrintDlgEXで使用する構造体を0で埋める(つまり初期化)
  FillChar(PDEXRec, SizeOf(PDEXRec), #0);

  with PDEXRec do begin
    lStructSize    := SizeOf(TPrintDlgEx);
    hWndOwner      := Handle;
    Flags          := PD_ALLPAGES or PD_NOPAGENUMS;
    nMaxPageRanges := 3;
    nMinPage       := 1;
    nMaxPage       := 10;
    nCopies        := 1;
    //プロパティシートの最初のタブを起動時にアクティブにする
    //通常は，START_PAGE_GENERALにしておく
    nStartPage     := 0;

    nPropertyPages   := Length(hpsp);
    lphPropertyPages := @hpsp[0];
  end;

  if PrintDlgEx(PDEXRec) = PD_RESULT_PRINT then begin
    //ここに印刷コードを書く
    //ダイアログで設定した内容は，構造体の各メンバーから取得する
  end;
end;

end.

var
  hRes : HRSRC;
begin
  //該当リソースがない場合は，戻りが0となる
  hRes := FindResource(hInstance, 'DIALOG_1', RT_DIALOG);

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, CommDlg;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses Printers;

{$R *.dfm}

//=============================================================================
//  PageSetupDlg APIで[ページ設定]ダイアログの表示 1
//  引数の構造体の設定を，ほとんどデフォルトのままで実行
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  PageSetupDlgRec : TPageSetupDlg;
begin
  //構造体を0で埋める(つまり初期化)
  FillChar(PageSetupDlgRec, SizeOf(TPageSetupDlg), #0);

  //各パラメータ(TPageSetupDlg構造体)の設定
  with PageSetupDlgRec do begin
    lStructSize := SizeOf(TPageSetupDlg);
    hWndOwner   := Handle;
    Flags       := 0;
  end;

  //ダイアログ表示
  if PageSetupDlg(PageSetupDlgRec) then begin
    //構造体の各メンバーから値を取出せる
  end;
end;

//-----------------------------------------------------------------------------
//  PageSetupDlg APIのコールバック関数
//  ダイアログの操作用のlpfnPageSetupHookメンバのコールバック関数
//-----------------------------------------------------------------------------
function PageSetupHookProc(Wnd: HWND; Message: UINT; wParam: WPARAM;
  lParam: LPARAM): UINT stdcall;
var
  TargetRect : TRect;
  hWindowHDC : HDC;
  ACanvas    : TCanvas;
begin
  Result := 0;

  if Message = WM_INITDIALOG then begin
    //ダイアログの表示位置を変更
    SetWindowPos(Wnd, 0, 200, 30, 0, 0, SWP_NOSIZE or SWP_NOZORDER);
  end else
  if Message = WM_CTLCOLORDLG then begin
    hWindowHDC := GetWindowDC(Wnd);

    //ウィンドウのデバイスハンドルを直接操作するコードでもよいが，
    //TCanvasを使用した方が簡単なので，TCanvasを生成して実行
    ACanvas        := TCanvas.Create;
    try
      ACanvas.Handle := hWindowHDC;

      GetClientRect(Wnd, TargetRect);
      ACanvas.Brush.Style := bsClear;
      ACanvas.Font.Color  := clRed;
      ACanvas.Font.Size   := 20;
      TargetRect.Bottom   := 200;

      DrawText(ACanvas.Handle, 'ページ設定ダイアログテスト', -1, TargetRect,
               DT_CENTER  or DT_VCENTER or DT_SINGLELINE);
    finally
      FreeAndNil(ACanvas);
    end;
  end;
end;

//=============================================================================
//  PageSetupDlg APIで[ページ設定]ダイアログの表示 2
//  コールバック関数の使用例
//  構造体のlpfnPageSetupHookを使用した例
//  この他に，サンプルページ描画用のフック関数が使用可能
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  PageSetupDlgRec : TPageSetupDlg;
begin
  //構造体を0で埋める(つまり初期化)
  FillChar(PageSetupDlgRec, SizeOf(TPageSetupDlg), #0);

  //各パラメータ(TPageSetupDlg構造体)の設定
  with PageSetupDlgRec do begin
    lStructSize       := SizeOf(TPageSetupDlg);
    hWndOwner         := Handle;
    Flags             := PSD_ENABLEPAGESETUPHOOK;
    lpfnPageSetupHook := @PageSetupHookProc;
  end;

  //ダイアログ表示
  if PageSetupDlg(PageSetupDlgRec) then begin
    //構造体の各メンバーから値を取出せる
  end;
end;

//=============================================================================
//  PageSetupDlg APIで[ページ設定]ダイアログの表示 3
//  用紙サイズと印刷の方向と余白を設定してからダイアログを表示する例
//  usesにPrintersが必要
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
var
  PageSetupDlgRec : TPageSetupDlg;
  ADevice         : array[0..MAX_PATH - 1] of Char;
  ADriver         : array[0..MAX_PATH - 1] of Char;
  APort           : array[0..MAX_PATH - 1] of Char;
  ADeviceMode     : THandle;
  ADevMode        : PDeviceMode;
begin
  Printer.GetPrinter(ADevice, ADriver, APort, ADeviceMode);
  //ADeviceModeのメモリをロックしDEVMODE構造体のポインタを取得
  ADevMode := GlobalLock(ADeviceMode);
  try
    //実際には該当メンバーをサポートしているかチェックしてからセットするのがよい
    ADevMode^.dmPaperSize   := DMPAPER_A3;
    ADevMode^.dmOrientation := DMORIENT_LANDSCAPE;
  finally
    GlobalUnlock(ADeviceMode);
  end;

  //構造体を0で埋める(つまり初期化)
  FillChar(PageSetupDlgRec, SizeOf(TPageSetupDlg), #0);

  //各パラメータ(TPageSetupDlg構造体)の設定
  with PageSetupDlgRec do begin
    lStructSize     := SizeOf(TPageSetupDlg);
    hWndOwner       := Handle;
    hDevMode        := ADeviceMode;
    rtMargin.Top    := 3000;
    rtMargin.Left   := 2500;
    rtMargin.Right  := 2000;
    rtMargin.Bottom := 3200;
    Flags           := PSD_MARGINS or PSD_INHUNDREDTHSOFMILLIMETERS;
  end;

  //ダイアログ表示
  if PageSetupDlg(PageSetupDlgRec) then begin
    //構造体の各メンバーから値を取出せる
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, CommDlg;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses Printers;

{$R *.dfm}

//=============================================================================
//  TPrinterを使用して印刷する場合の参考コード
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  AIndex      : Integer;
  ADevice     : array[0..MAX_PATH - 1] of Char;
  ADriver     : array[0..MAX_PATH - 1] of Char;
  APort       : array[0..MAX_PATH - 1] of Char;
  ADeviceMode : THandle;
  ADevMode    : PDeviceMode;
  PrintDlgRec : TPrintDlg;
  Offset      : PChar;
  PrinterName : String;
  hPrinter    : THandle;
  Mode        : Cardinal;
  Names       : PDevNames;
begin
  FillChar(PrintDlgRec, SizeOf(TPrintDlg), #0);

  with PrintDlgRec do begin
    lStructSize := SizeOf(TPrintDlg);
    hWndOwner   := Handle;
    Flags       := PD_PRINTSETUP;
  end;

  if PrintDlg(PrintDlgRec) then begin
    Update;
    Names := GlobalLock(PrintDlgRec.hDevNames );
    try
      Offset      := PChar(Names);
      PrinterName := String(Offset + Names.wDeviceOffset);
    finally
      GlobalUnlock(PrintDlgRec.hDevNames);
    end;

    AIndex := Printer.Printers.IndexOf(PrinterName);
    Printer.PrinterIndex := AIndex;
    Printer.GetPrinter(ADevice, ADriver, APort, ADeviceMode);
    Printer.SetPrinter(ADevice, ADriver, APort, 0);
    Printer.GetPrinter(ADevice, ADriver, APort, ADeviceMode);

    ADevMode := GlobalLock(ADeviceMode);
    try
      ADeviceMode := PrintDlgRec.hDevMode;
    finally
      GlobalUnlock(ADeviceMode);
    end;
    Printer.SetPrinter(ADevice, ADriver, APort, ADeviceMode);

    Printer.Title := '印刷テスト';
    Printer.BeginDoc;
    try
      Printer.Canvas.Font.Size := 25;
      Printer.Canvas.TextOut(0, 0, 'プリンタ関係ダイアログAPIのテスト');
    finally
      Printer.EndDoc;
    end;
  end;
end;

end.