unit PrintersCountUnit;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Printers, WinSpool, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  使用可能なプリンタ数を求める
//
//  TPrinterのPrinters.Countを使用
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  Cnt : Integer;
begin
  Cnt := Printer.Printers.Count;
  MessageBox(Handle, PChar(IntToStr(Cnt)), '情報', MB_ICONINFORMATION);
end;

//=============================================================================
//  使用可能なプリンタ数を求める
//
//  EnumPrinters APIを使用
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  Flags    : Cardinal;
  dwNeeded : Cardinal;
  dwReturn : Cardinal;
  pPinfo4  : PPrinterInfo4;
begin
  dwNeeded := 0;
  dwReturn := 0;

  //プリンタ情報を得る準備
  Flags := PRINTER_ENUM_CONNECTIONS or PRINTER_ENUM_LOCAL;

  dwNeeded := 0;
  //バッファ長を得る
  EnumPrinters(Flags, nil, 4, nil, 0, dwNeeded, dwReturn);
  if dwNeeded <> 0 then begin
    //構造体の配列に必要なバイト数を確保
    GetMem(pPinfo4, dwNeeded);
    try
      //プリンタ情報(Level=4)を取得
      EnumPrinters(Flags,
                   nil,
                   4,
                   Pointer(pPinfo4),
                   dwNeeded, 
                   dwNeeded, 
                   dwReturn);
    finally
      FreeMem(pPinfo4);
    end;
  end;
  MessageBox(Handle, PChar(IntToStr(dwReturn)), '情報', MB_ICONINFORMATION);
end;

//=============================================================================
//  使用可能なプリンタ数の共有プリンタ数求める
//
//  EnumPrinters APIを使用
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
var
  Flags    : Cardinal;
  dwNeeded : Cardinal;
  dwReturn : Cardinal;
  pPinfo4  : PPrinterInfo4;
begin
  dwNeeded := 0;
  dwReturn := 0;

  //プリンタ情報を得る準備
  Flags := PRINTER_ENUM_LOCAL or PRINTER_ENUM_SHARED;

  dwNeeded := 0;
  //バッファ長を得る
  EnumPrinters(Flags, nil, 4, nil, 0, dwNeeded, dwReturn);
  if dwNeeded <> 0 then begin
    //構造体の配列に必要なバイト数を確保
    GetMem(pPinfo4, dwNeeded);
    try
      //プリンタ情報(Level=4)を取得
      EnumPrinters(Flags,
                   nil,
                   4,
                   Pointer(pPinfo4),
                   dwNeeded, 
                   dwNeeded, 
                   dwReturn);
    finally
      FreeMem(pPinfo4);
    end;
  end;
  MessageBox(Handle, PChar(IntToStr(dwReturn)), '情報', MB_ICONINFORMATION);
end;

end.

unit StopRealPrintUnit;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Printers, WinSpool, ValEdit, ExtCtrls, Grids;

type
  TForm1 = class(TForm)
    Panel2: TPanel;
    ListBox1: TListBox;
    Panel3: TPanel;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  プリンタのリストを作成
//
//  ここでは簡単にしてTPrinterオブジェクト(クラス)を使用
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  ListBox1.Items.Clear;
  ListBox1.Items.Assign(Printer.Printers);

  ListBox1.ItemIndex := 0;
end;

//=============================================================================
//  Listboxで選択したプリンタを一時停止にする
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  hPrinter    : Cardinal;
  Pdef        : PRINTER_DEFAULTS;
  PrinterName : String;
  ACommand    : DWORD;
begin
  if ListBox1.ItemIndex<0 then exit;

  //対象のプリンタ名
  PrinterName := ListBox1.Items[ListBox1.ItemIndex];

  //WindowsNT系の場合アクセス権が必要
  ZeroMemory(@Pdef, Sizeof(PRINTER_DEFAULTS));
  Pdef.DesiredAccess := PRINTER_ALL_ACCESS;

  //アクセス権を指定して対象のプリンタのハンドルを取得　
  WinSpool.OpenPrinter(PChar(PrinterName), hPrinter, @Pdef);
  if hPrinter <> 0 then begin
    try
      ACommand := PRINTER_CONTROL_PAUSE;
      //Commandを使用するのでLevelは0とする
      if WinSpool.SetPrinter(hPrinter, 0, nil, ACommand) then begin
        MessageBox(Handle, '一時停止しました', '情報', MB_ICONINFORMATION);
      end;
    finally
      WinSpool.ClosePrinter(hPrinter);
    end;
  end;
end;

//=============================================================================
//  Listboxで選択したプリンタを一時停止を解除[印刷の再開]にする
//  プリンタの状態が[準備完了]となる
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  hPrinter    : Cardinal;
  Pdef        : PRINTER_DEFAULTS;
  PrinterName : String;
  ACommand    : DWORD;
begin
  if ListBox1.ItemIndex<0 then exit;

  //対象のプリンタ名
  PrinterName := ListBox1.Items[ListBox1.ItemIndex];

  //WindowsNT系の場合アクセス権が必要
  ZeroMemory(@Pdef, Sizeof(PRINTER_DEFAULTS));
  Pdef.DesiredAccess := PRINTER_ALL_ACCESS;

  //アクセス権を指定して対象のプリンタのハンドルを取得　
  WinSpool.OpenPrinter(PChar(PrinterName), hPrinter, @Pdef);
  if hPrinter <> 0 then begin
    try
      ACommand := PRINTER_CONTROL_RESUME;
      //Commandを使用するのでLevelは0とする
      if WinSpool.SetPrinter(hPrinter, 0, nil, ACommand) then begin
        MessageBox(Handle, '一時停止を解除しました', '情報', MB_ICONINFORMATION);
      end;
    finally
      WinSpool.ClosePrinter(hPrinter);
    end;
  end;
end;

//=============================================================================
//  Listboxで選択したプリンタをの状態を取得
//  ここでは一時停止だけを検査
//
//  GetPrinterの説明にはPRINTER_INFO_6は指定できないようになっているであるが，
//  では，PRINTER_INFO_6の情報取得はどうするのか，ということでテスト
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
var
  hPrinter    : Cardinal;
  PrinterName : String;
  dwNeeded    : DWORD;
  InfoLevel   : Cardinal;
  pPinfo6     : PPrinterInfo6;
begin
  if ListBox1.ItemIndex<0 then exit;

  InfoLevel := 6;
  pPinfo6   := nil;
  //対象のプリンタ名
  PrinterName := ListBox1.Items[ListBox1.ItemIndex];
  //対象のプリンタのハンドルを取得　
  WinSpool.OpenPrinter(PChar(PrinterName), hPrinter, nil);

  if hPrinter <> 0 then begin
    try
      //構造体に必要なバッファサイズを取得
      WinSpool.GetPrinter(hPrinter, InfoLevel, nil, 0, @dwNeeded);

      //構造体の配列に必要なバイト数を確保
      GetMem(pPinfo6, dwNeeded);

      //PRINTER_INFO_6構造体の情報を取得して表示
      //時刻など表示形式は指定していないので注意
      if WinSpool.GetPrinter(hPrinter,
                             InfoLevel,
                             pPinfo6,
                             dwNeeded,
                             @dwNeeded) then begin
        if (pPinfo6.dwStatus and
            PRINTER_STATUS_PAUSED) = PRINTER_STATUS_PAUSED then begin
            MessageBox(Handle, '一時停止中です', '情報', MB_ICONINFORMATION);
        end else begin
          MessageBox(Handle, '一時停止中ではありません', '情報', MB_ICONINFORMATION);
        end;
      end;
    finally
      FreeMem(pPinfo6);
      WinSpool.ClosePrinter(hPrinter);
    end;
  end;
end;

end.

unit Printer_Info1_EnumUnit;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Printers, WinSpool;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Memo1: TMemo;
    Memo2: TMemo;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  プリンタの情報取得 PRINTER_INFO_1構造体から
//
//  第2引数をnilにして使用可能なプリントプロバイダを取得する場合
//  ここでは構造体のpNameしか取得していないが，他の値も同様に取得できる
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  Flags    : Cardinal;
  dwNeeded : Cardinal;
  dwReturn : Cardinal;
  pPinfo1  : PPrinterInfo1;
  pWork    : PPrinterInfo1;
  i        : Integer;
  S        : String;
begin
  Memo1.Lines.Clear;

  pPInfo1  := nil;
  dwNeeded := 0;
  dwReturn := 0;
  Flags    := PRINTER_ENUM_NAME;

  //dwNeededを0にして必要なバッファサイズを取得
  //第2引数をnilにして使用可能なプリントプロバイダを取得する場合
  EnumPrinters(Flags,
               nil,
               1,
               pPInfo1,
               dwNeeded,
               dwNeeded,
               dwReturn);
  if dwNeeded=0 then exit;

  //構造体の配列に必要なバイト数を確保
  GetMem(pPinfo1, dwNeeded);
  try
    if EnumPrinters(Flags,
                    nil,
                    1,
                    pPinfo1,
                    dwNeeded,
                    dwNeeded,
                    dwReturn) then begin
      pWork := pPinfo1;
      for i := 0 to dwReturn - 1 do begin
        S := String(pWork.pName);
        Memo1.Lines.Add(S);
        //次の構造体の配列に移動
        Inc(pWork);
      end;
    end else begin
      MessageBox(Handle, PChar(SysErrorMessage(GetLastError)), '', 0);
    end;
  finally
    FreeMem(pPinfo1);
  end;
end;

//=============================================================================
//  プリンタの情報取得 PRINTER_INFO_1構造体から
//
//  プリントプロバイダを指定して，そのプリンタのリストを取得
//  ここでは構造体のpNameしか取得していないが，他の値も同様に取得できる
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  Flags     : Cardinal;
  pName     : PWideChar;
  dwNeeded  : Cardinal;
  dwReturn  : Cardinal;
  pPinfo1   : PPrinterInfo1;
  pWork     : PPrinterInfo1;
  i         : Integer;
  S         : String;
begin
  Memo2.Lines.Clear;

  pPInfo1  := nil;
  dwNeeded := 0;
  dwReturn := 0;
  pName    := 'Windows NT Local Print Providor';
  Flags    := PRINTER_ENUM_NAME;

  //dwNeededを0にして必要なバッファサイズを取得
  EnumPrinters(Flags,
               pName,
               1,
               pPInfo1,
               dwNeeded,
               dwNeeded,
               dwReturn);
  if dwNeeded=0 then exit;

  //構造体の配列に必要なバイト数を確保
  GetMem(pPinfo1, dwNeeded);
  try
    if EnumPrinters(Flags,
                    pName,
                    1,
                    pPinfo1,
                    dwNeeded,
                    dwNeeded,
                    dwReturn) then begin
      pWork := pPinfo1;
      for i := 0 to dwReturn - 1 do begin
        S := string(pWork.pName);
        Memo2.Lines.Add(S);
        //次の構造体の配列に移動
        Inc(pWork);
      end;
    end else begin
      MessageBox(Handle, PChar(SysErrorMessage(GetLastError)), '', 0);
    end;
  finally
    FreeMem(pPinfo1);
  end;
end;

end.

unit Printer_Info1_GetPrinterUnit;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Printers, WinSpool, ValEdit, ExtCtrls, Grids;

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    Button1: TButton;
    Panel2: TPanel;
    ListBox1: TListBox;
    Panel3: TPanel;
    ValueListEditor1: TValueListEditor;
    procedure Button1Click(Sender: TObject);
    procedure ListBox1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  プリンタのリストを作成
//
//  ここでは簡単にしてTPrinterオブジェクト(クラス)を使用
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  PrinterName : String;
  i           : Integer;
begin
  ListBox1.Items.Clear;
  for i := 0 to Printer.Printers.Count - 1 do begin
    PrinterName := Printer.Printers[i];
    ListBox1.Items.Add(PrinterName)
  end;
end;

//=============================================================================
//  ListBox1をクリックしたら，そのプリンタの情報を表示
//=============================================================================
procedure TForm1.ListBox1Click(Sender: TObject);
var
  hPrinter    : Cardinal;
  PrinterName : String;
  dwNeeded    : DWORD;
  pPinfo1     : PPrinterInfo1;
begin
  pPinfo1 := nil;

  //対象のプリンタ名
  PrinterName := ListBox1.Items[ListBox1.ItemIndex];
  //対象のプリンタのハンドルを取得　
  WinSpool.OpenPrinter(PChar(PrinterName), hPrinter, nil);
  if hPrinter <> 0 then begin
    try
      //構造体に必要なバッファサイズを取得
      WinSpool.GetPrinterW(hPrinter, 1, nil, 0, @dwNeeded);

      //構造体の配列に必要なバイト数を確保
      GetMem(pPinfo1, dwNeeded);

      //PRINTER_INFO_1構造体の各メンバーの情報を取得して表示
      if WinSpool.GetPrinter(hPrinter, 1, pPinfo1, dwNeeded, @dwNeeded) then begin
        ValueListEditor1.Cells[1, 1] := pPInfo1.pDescription;
        ValueListEditor1.Cells[1, 2] := pPInfo1.pName;
        ValueListEditor1.Cells[1, 3] := pPInfo1.pComment;
      end;
    finally
      FreeMem(pPinfo1);
      WinSpool.ClosePrinter(hPrinter);
    end;
  end;
end;

end.

unit Printer_Info2_EnumUnit;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Printers, WinSpool, ValEdit, ExtCtrls, Grids;

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    Button1: TButton;
    Panel2: TPanel;
    ListBox1: TListBox;
    Panel3: TPanel;
    ValueListEditor1: TValueListEditor;
    procedure Button1Click(Sender: TObject);
    procedure ListBox1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  プリンタの情報取得 PRINTER_INFO_2構造体から
//
//  第2引数をnilにして使用可能なプリントプロバイダを取得する場合
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  Flags       : Cardinal;
  dwNeeded    : Cardinal;
  dwReturn    : Cardinal;
  pPinfo2     : PPrinterInfo2;
  pWork       : PPrinterInfo2;
  i           : Integer;
  S           : String;
begin
  ListBox1.Items.Clear;

  pPInfo2  := nil;
  dwNeeded := 0;
  dwReturn := 0;
  Flags := PRINTER_ENUM_NAME;

  //dwNeededを0にして必要なバッファサイズを取得
  EnumPrinters(Flags,
               nil,
               2,
               pPInfo2,
               dwNeeded,
               dwNeeded,
               dwReturn);
  if dwNeeded = 0 then exit;

  //構造体の配列に必要なバイト数を確保
  GetMem(pPinfo2, dwNeeded);
  try
    if EnumPrinters(Flags,
                    nil,
                    2,
                    pPinfo2,
                    dwNeeded,
                    dwNeeded,
                    dwReturn) then begin
      pWork := pPinfo2;
      for i := 0 to dwReturn - 1 do begin
        S := String(pWork.pPrinterName);
        ListBox1.Items.Add(S);
        //次の構造体の配列に移動
        Inc(pWork);
      end;
    end else begin
      MessageBox(Handle, PChar(SysErrorMessage(GetLastError)), '', 0);
    end;
  finally
    FreeMem(pPinfo2);
  end;
end;

//=============================================================================
//  ListBox1をクリックしたら，そのプリンタの情報を表示
//=============================================================================
procedure TForm1.ListBox1Click(Sender: TObject);
var
  hPrinter    : Cardinal;
  PrinterName : WideString;
  dwNeeded    : DWORD;
  pPinfo2     : PPrinterInfo2;
begin
  pPinfo2 := nil;

  //対象のプリンタ名
  PrinterName := ListBox1.Items[ListBox1.ItemIndex];
  //対象のプリンタのハンドルを取得　
  WinSpool.OpenPrinter(PChar(PrinterName), hPrinter, nil);
  if hPrinter <> 0 then begin
    try
      //構造体に必要なバッファサイズを取得
      WinSpool.GetPrinter(hPrinter, 2, nil, 0, @dwNeeded);

      //構造体の配列に必要なバイト数を確保
      GetMem(pPinfo2,dwNeeded);

      //PRINTER_INFO_2構造体の各メンバーの情報を取得して表示
      //時刻など表示形式は指定していないので注意
      if WinSpool.GetPrinterW(hPrinter, 2, pPinfo2, dwNeeded, @dwNeeded) then begin
        ValueListEditor1.Cells[1,1]  := pPInfo2.pServerName;
        ValueListEditor1.Cells[1,2]  := pPInfo2.pPrinterName;
        ValueListEditor1.Cells[1,3]  := pPInfo2.pShareName;
        ValueListEditor1.Cells[1,4]  := pPInfo2.pPortName;
        ValueListEditor1.Cells[1,5]  := pPInfo2.pDriverName;
        ValueListEditor1.Cells[1,6]  := pPInfo2.pComment;
        ValueListEditor1.Cells[1,7]  := pPInfo2.pLocation;
        ValueListEditor1.Cells[1,8]  := pPInfo2.pSepFile;
        ValueListEditor1.Cells[1,9]  := pPInfo2.pPrintProcessor;
        ValueListEditor1.Cells[1,10] := pPInfo2.pParameters;
        ValueListEditor1.Cells[1,11] := IntTostr(pPInfo2.DefaultPriority);
        ValueListEditor1.Cells[1,12] := IntToStr(pPInfo2.StartTime);
        ValueListEditor1.Cells[1,13] := IntToStr(pPInfo2.UntilTime);
        ValueListEditor1.Cells[1,14] := IntToStr(pPInfo2.cJobs);
        ValueListEditor1.Cells[1,15] := IntToStr(pPInfo2.AveragePPM);
      end;
    finally
      FreeMem(pPinfo2);
      WinSpool.ClosePrinter(hPrinter);
    end;
  end;
end;

end.

unit Printer_Info4_EnumUnit;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Printers, WinSpool, ExtCtrls;

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    Button1: TButton;
    Panel2: TPanel;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  プリンタの情報取得 PRINTER_INFO_4構造体から
//
//  ローカルのプリンタと現在接続が確立されているもの
//  この場合ネットワークのものも含む
//  PRINTER_INFO_4の時に指定可能なのはこの2つのみ
//
//  中村氏がDelphi MLで見えないプリンタがあると言うので見えないプリンタを表示し
//  ないようにしている．この見えないプリンタは，確認したことがあり，なるほどと
//  その時は思ったのであるが，状況については失念
//  使用可能なプリンタがリストできればいいと考えていたので...
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  Flags     : Cardinal;
  dwNeeded  : Cardinal;
  dwReturn  : Cardinal;
  pPinfo4   : PPrinterInfo4;
  pWork     : PPrinterInfo4;
  i         : Integer;
  S         : String;
begin
  Memo1.Lines.Clear;

  pPInfo4  := nil;
  dwNeeded := 0;
  dwReturn := 0;

  //列挙対象プリンタの種類
  Flags := PRINTER_ENUM_LOCAL or PRINTER_ENUM_CONNECTIONS;

  //dwNeededを0にして必要なバッファサイズを取得
  EnumPrinters(Flags,
               nil,
               4,
               pPInfo4,
               dwNeeded,
               dwNeeded,
               dwReturn);
  if dwNeeded=0 then exit;

  //構造体の配列に必要なバイト数を確保
  GetMem(pPinfo4, dwNeeded);
  try
    if EnumPrinters(Flags,
                    nil,
                    4,
                    pPinfo4,
                    dwNeeded,
                    dwNeeded,
                    dwReturn) then begin
      pWork := pPinfo4;
      for i := 0 to dwReturn - 1 do begin
        if (pWork.Attributes and PRINTER_ATTRIBUTE_HIDDEN) = 0 then begin
          S := string(pWork.pPrinterName);
          Memo1.Lines.Add(S);
        end;
        //次の構造体の配列に移動
        Inc(pWork);
      end;
    end else begin
      MessageBox(Handle, PChar(SysErrorMessage(GetLastError)), '', 0);
    end;
  finally
    FreeMem(pPinfo4);
  end;
end;

end.

unit Printer_Info5_EnumUnit;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Printers, WinSpool, ExtCtrls;

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    Button1: TButton;
    Panel2: TPanel;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  プリンタの情報取得 PRINTER_INFO_5構造体から
//
//  PRINTER_INFO_4はWindows 9X系では使用できないのでこちらを使用することになる
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  Flags     : Cardinal;
  dwNeeded  : Cardinal;
  dwReturn  : Cardinal;
  pPinfo5   : PPrinterInfo5;
  pWork     : PPrinterInfo5;
  i         : Integer;
  S         : String;
begin
  Memo1.Lines.Clear;

  pPInfo5  := nil;
  dwNeeded := 0;
  dwReturn := 0;

  //列挙対象プリンタの種類
  Flags := PRINTER_ENUM_LOCAL or PRINTER_ENUM_CONNECTIONS;

  //dwNeededを0にして必要なバッファサイズを取得
  EnumPrinters(Flags,
               nil,
               5,
               pPInfo5,
               dwNeeded,
               dwNeeded,
               dwReturn);
  if dwNeeded = 0 then exit;

  //構造体の配列に必要なバイト数を確保
  GetMem(pPinfo5, dwNeeded);
  try
    if EnumPrinters(Flags,
                    nil,
                    5,
                    pPinfo5,
                    dwNeeded,
                    dwNeeded,
                    dwReturn) then begin
      pWork := pPinfo5;
      for i := 0 to dwReturn - 1 do begin
        S := string(pWork.pPrinterName);
        Memo1.Lines.Add(S);
        //次の構造体の配列に移動
        Inc(pWork);
      end;
    end else begin
      MessageBox(Handle, PChar(SysErrorMessage(GetLastError)), '', 0);
    end;
  finally
    FreeMem(pPinfo5);
  end;
end;

end.