unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private 宣言 }
    IniFileName : String;
    StrWinState : String;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  IniFiles,
  TypInfo;

{$R *.DFM}

//=============================================================================
//  フォームのCreate時に保存したWindowStateの値を読み出して設定
//  このサンプルは．列挙型の値の保存と読み出しの方法の１つの例
//
//  ただし，このサンプルでは，最小化して保存し，次回最小化の状態で起動すると
//  タスクバーにアイコンが表示されない場合があるので注意
//
//  Iniファイル関係の操作にはusesにIniFilesが必要
//  TyppeInfoの使用にはusesにTypInfoが必要
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  LIniFile : TInifile;
begin
  IniFileName := ExtractFilePath(Application.ExeName) + 'FormInfo.ini';
  LIniFile    := TIniFile.Create(IniFileName);
  try
   if FileExists(IniFileName) then begin
     //保存してあるWindowStateの値を文字列として読み出す
     StrWinState := LIniFile.ReadString('AppInfo', 'WindowState', '');

     //その文字列をTWindowState型の値に変換する
     WindowState := TWindowState(GetEnumValue(TypeInfo(TWindowState), StrWinState));
   end;
  finally
    FreeAndNil(LIniFile);
  end;
end;

//=============================================================================
//  フォームを閉じる時は，WindowsStateの値をIniファイルに保存
//  Iniファイル関係の操作にはusesにIniFilesが必要
//  TyppeInfoの使用にはusesにTypInfoが必要
//=============================================================================
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
var
  LIniFile : TInifile;
begin
  //このフォームのWindowStateプロパティの値を文字列に変換
  StrWinState := GetEnumName(TypeInfo(TWindowState), Ord(WindowState));

  //その文字列をIniファイルに保存
  LIniFile := TIniFile.Create(IniFileName);
  try
    try
      LIniFile.WriteString('AppInfo', 'WindowState', StrWinState);
    except
    end;
  finally
    FreeAndNil(LIniFile);
  end;
end;

end.

uses
  TypInfo;

{$R *.DFM}

//=============================================================================
//  列挙体の値をリストするサンプル
//  ここではTWindowState型のメンバの値を列挙
//
//  usesにTypInfoが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LpInfo : PTypeInfo;
  LpData : PTypeData;
  i     : Integer;
begin
  Memo1.Clear;

  LpInfo := TypeInfo(TWindowState);

  //列挙型であれば調査
  if LpInfo^.Kind = tkEnumeration then begin
    LpData := GetTypeData(LpInfo);
    for i := LpData^.MinValue to LpData^.MaxValue do begin
      Memo1.Lines.Add(GetEnumName(LpInfo, i));
    end;
  end;
end;