unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, Spin;

type
  TForm1 = class(TForm)
    Button1: TButton;
    SpinEdit1: TSpinEdit;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses CommCtrl, CommonMemoryUnit;

{$R *.dfm}

//=============================================================================
//  [ツールバーのボタンクリック]
//
//  TB_GETITEMRECTの使用には，usesにCommCtrlが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  hTargetWnd : HWND;
  hToolBar   : HWND;
  r          : TRect;
  ALeft      : WORD;
  ATop       : WORD;
  ComMem     : TCommMemNT;
  ASize      : Integer;
begin
  //他のアプリのTToolbarのハンドルを取得
  hTargetWnd := FindWindow('TTargetForm', nil);
  if hTargetWnd = 0 then exit;

  //ツールバーのハンドルを取得
  hToolBar := FindWindowEx(hTargetWnd, 0, 'TToolbar', nil);
  if hToolBar = 0 then exit;

  //TToolbarのボタンのTRect構造体の値を，共有メモリを介して取得
  //ボタンの番号はSpinEdit1の値
  ASize  := SizeOf(r);
  ComMem := TCommMemNT.Create(hToolBar, ASize);
  try
    SendMessage(hToolBar, TB_GETITEMRECT, SpinEdit1.Value, LPARAM(ComMem.MemPtr));
    ComMem.Read(0, @r, ASize);
  finally
    ComMem.Free;
  end;

  //矩形領域r(TToolbarのSpinEdit1.Value番目)のボタンをクリック
  ALeft := r.Left + 2;
  ATop  := r.Top  + 2;
  PostMessage(hToolBar,WM_LBUTTONDOWN, 0, MakeLParam(ALeft, ATop));
  PostMessage(hToolBar,WM_LBUTTONUP,   0, MakeLParam(ALeft, ATop));
end;

//=============================================================================
//  [結果の表示をクリア]
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  hTargetWnd : HWND;
  hMemo      : HWND;
begin
  hTargetWnd := FindWindow('TTargetForm', nil);
  if hTargetWnd = 0 then exit;

  hMemo := FindWindowEx(hTargetWnd, 0, 'TMemo', nil);
  if hMemo = 0 then exit;

  SendMessage(hMemo, WM_SETTEXT, 0, LPARAM(nil));
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, ToolWin, ImgList;

type
  TTargetForm = class(TForm)
    ToolBar1: TToolBar;
    ToolButton1: TToolButton;
    ToolButton2: TToolButton;
    ToolButton3: TToolButton;
    ToolButton4: TToolButton;
    ToolButton5: TToolButton;
    ToolButton6: TToolButton;
    ImageList1: TImageList;
    ToolButton7: TToolButton;
    Memo1: TMemo;
    procedure ToolButton1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  TargetForm: TTargetForm;

implementation

{$R *.dfm}

//=============================================================================
//  ツールバーのボタンクリックイベント
//=============================================================================
procedure TTargetForm.ToolButton1Click(Sender: TObject);
var
  AIndex : Integer;
begin
  AIndex := TToolButton(Sender).Index;
  Memo1.Lines.Add('Clicked No  ' + IntToStr(AIndex));
end;

end.