unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    LabeledEdit1 : TLabeledEdit;
    LabeledEdit2 : TLabeledEdit;
    LabeledEdit3 : TLabeledEdit;
    LabeledEdit4 : TLabeledEdit;
    LabeledEdit5: TLabeledEdit;
    LabeledEdit6: TLabeledEdit;
    procedure Button1Click(Sender: TObject);
    procedure FormShow(Sender: TObject);
  private
    { Private 宣言 }
    IniFileName  : String;
    FileSize     : Integer;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses IdURI;

{$R *.dfm}

//=============================================================================
//  EditにURI(Uniform Resource Identifier)をセット
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  LabeledEdit1.Text := 'http://mrxray.on.coocan.jp/Delphi/plSamples/index.htm';
end;

//=============================================================================
//  URL(URI)をプロトコルやホスト文字列に分解する
//
//  TIdURIにはusesにIdURIが必要
//  IdURIはコンポーネントではなくクラス
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  uri: TIdURI;
begin
  //LabelEdit1にURLを入力しておく
  uri := TIdURI.Create(LabeledEdit1.Text);
  try
    LabeledEdit2.Text := uri.Protocol;
    LabeledEdit3.Text := uri.Host;
    LabeledEdit4.Text := uri.Port;
    LabeledEdit5.Text := uri.Path;
    LabeledEdit6.Text := uri.Document;
  finally
    uri.Free;
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, IdBaseComponent, IdComponent,
  IdTCPConnection, IdTCPClient, IdHTTP;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    Panel1: TPanel;
    Button1: TButton;
    Button2: TButton;
    Edit1: TEdit;
    IdHTTP1: TIdHTTP;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormShow(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  テスト用のURLをセット
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  Memo1.Lines.Clear;
  Edit1.Text := 'http://mrxray.on.coocan.jp/index.htm';
end;

//=============================================================================
//  指定URLのヘッダ情報を取得
//
//  リダイレクト処理を行っているので，例えばCGI経由のファイルも情報取得可能
//  (ただし少し時間がかかる)
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  URL : String;
  Ret : Boolean;
begin
  Memo1.Lines.Clear;

  Screen.Cursor := crHourGlass;
  URL := Trim(Edit1.Text);
  //リダイレクト処理をTrueに
  IdHTTP1.HandleRedirects := True;

  try
    //このURLが存在しないと，Headメソッド実行でエラーとなる
    //リダイレクト実行後に，URLにリダイレクト先のURLが取得できる
    IdHTTP1.Head(URL);
    Ret := True;
  except
    if IdHTTP1.ResponseCode = 302 then begin
      //リダイレクト後のURLで再度Headメソッドを実行して情報取得
      IdHTTP1.Head(IdHTTP1.Response.Location);
      Ret := True;
    end else begin
      Ret := False;
    end;
  end;

  if Ret then begin
    Memo1.Lines.Add(IdHTTP1.ResponseText);
    Memo1.Lines.Add(IdHTTP1.Response.RawHeaders.Text);
    Memo1.Lines.Add('');
  end else begin
    //エラー時の処理
    MessageDlg('指定したページまたはファイルが見つかりませんでした．',
               mtInformation,
               [mbOK],0);
  end;

  IdHTTP1.Disconnect;
  Screen.Cursor := crDefault;
end;

//=============================================================================
//  指定URLの更新日時とファイルサイズを取得
//
//  リダイレクト処理を行っているので，例えば
//  リダイレクト処理を行っているので，例えばCGI経由のファイルも情報取得可能
//  (ただし少し時間がかかる)
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  URL      : String;
  LastDate : TDateTime;
  DateStr  : String;
  FileSize : Longint;
  Ret      : Boolean;
begin
  Memo1.Lines.Clear;

  Screen.Cursor := crHourGlass;
  URL := Trim(Edit1.Text);
  //リダイレクト処理をTrueに
  IdHTTP1.HandleRedirects := True;

  try
    //このURLが存在しないと，Headメソッド実行でエラーとなる
    //リダイレクト実行後に，URLにリダイレクト先のURLが取得できる
    IdHTTP1.Head(URL);
    Ret := True;
  except
    if IdHTTP1.ResponseCode = 302 then begin
      //リダイレクト後のURLで再度Headメソッドを実行して情報取得
      IdHTTP1.Head(IdHTTP1.Response.Location);
      Ret := True;
    end else begin
      Ret := False;
    end;
  end;

  if Ret then begin
    //ファイルサイズ
    FileSize := IdHTTP1.Response.ContentLength;
    //最終更新日時
    LastDate := IdHTTP1.Response.LastModified;
    DateStr  := FormatDateTime('yyyy年mm月dd日 hh時nn分', LastDate);

    Memo1.Lines.Add('最終更新日時   : ' + DateStr);
    Memo1.Lines.Add('ファイルサイズ : ' + IntToStr(FileSize) + ' バイト' );
    Memo1.Lines.Add('フルパス名     : ' + IdHTTP1.URL.URI);
    Memo1.Lines.Add('ファイル名     : ' + IdHTTP1.URL.Document);
    Memo1.Lines.Add('');
  end else begin
    //エラー時の処理
    MessageDlg('指定したページまたはファイルが見つかりませんでした．',
               mtInformation,
               [mbOK],0);
  end;

  IdHTTP1.Disconnect;
  Screen.Cursor := crDefault;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, IdBaseComponent, IdComponent,
  IdTCPConnection, IdTCPClient, IdHTTP;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    Panel1: TPanel;
    Button1: TButton;
    Button2: TButton;
    Edit1: TEdit;
    IdHTTP1: TIdHTTP;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure IdHTTP1Redirect(Sender: TObject; var dest: string;
      var NumRedirect: Integer; var Handled: Boolean; var VMethod: string);
  private
    { Private 宣言 }
    RealUrl : String;
    function CheckHTTPUrl(var AUrl:String): Boolean;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  テスト用のURLをセット
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  Memo1.Lines.Clear;
  Edit1.Text := 'http://mrxray.on.coocan.jp/index.htm';
end;

//=============================================================================
//  指定URLのヘッダ情報を取得
//
//  リダイレクト処理を行っているので，例えばCGI経由のファイルも情報取得可能
//  (ただし少し時間がかかる)
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  URL : String;
begin
  Memo1.Lines.Clear;
  Screen.Cursor := crHourGlass;
  URL :=Trim(Edit1.Text);

  if CheckHTTPUrl(URL) = False then begin
    MessageDlg('指定したページまたはファイルが見つかりませんでした．',
               mtInformation,
               [mbOK],0);
    Screen.Cursor := crDefault;
    exit;
  end;

  //情報の再取得
  //リダイレクトされた場合はURLはりダイレクト先
  IdHTTP1.Head(URL);

  Memo1.Lines.Add(IdHTTP1.ResponseText);
  Memo1.Lines.Add(IdHTTP1.Response.RawHeaders.Text);
  IdHTTP1.Disconnect;
  Memo1.Lines.Add('');

  IdHTTP1.Disconnect;
  Screen.Cursor := crDefault;
end;

//=============================================================================
//  指定URLの更新日時とファイルサイズを取得
//
//  リダイレクト処理を行っているので，例えばCGI経由のファイルも情報取得可能
//  (ただし少し時間がかかる)
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  URL      : String;
  LastDate : TDateTime;
  DateStr  : String;
  FileSize : Longint;
begin
  Memo1.Lines.Clear;
  Screen.Cursor := crHourGlass;
  URL := Trim(Edit1.Text);

  if CheckHTTPUrl(URL) = False then begin
    MessageDlg('指定したページまたはファイルが見つかりませんでした．',
               mtInformation,
               [mbOK],0);
    Screen.Cursor := crDefault;
    exit;
  end;

  //情報の再取得
  //リダイレクトされた場合はURLはりダイレクト先
  IdHTTP1.Head(URL);

  FileSize := IdHTTP1.Response.ContentLength;
  LastDate := IdHTTP1.Response.LastModified;

  //最終更新日時
  DateStr  :=FormatDateTime('yyyy年mm月dd日 hh時nn分', LastDate);
  Memo1.Lines.Add('最終更新日時   : ' + DateStr);
  Memo1.Lines.Add('ファイルサイズ : ' + IntToStr(FileSize) + ' バイト' );
  Memo1.Lines.Add('フルパス名     : ' + IdHTTP1.URL.URI);
  Memo1.Lines.Add('ファイル名     : ' + IdHTTP1.URL.Document);
  Memo1.Lines.Add('');

  IdHTTP1.Disconnect;
  Screen.Cursor := crDefault;
end;

//=============================================================================
//  引数のAUrlが存在するかチェックする関数
//  RealUrlはグローバル変数．OnRedirectイベントとの連携で取得する
//  成功すればAUrlにリダイレクト先(なければ元のAUrlはそのまま)を返す
//=============================================================================
function TForm1.CheckHTTPUrl(var AUrl: String): Boolean;
begin
  RealUrl := Aurl;
  try
    IdHTTP1.Head(RealUrl);
    AUrl   := RealUrl;
    Result := True;
  except
    AUrl   := '';
    Result := False;
  end;

  //リダイレクトされている場合はエラーとしない
  if IdHTTP1.ResponseCode = 302 then begin
    AUrl   := RealUrl;
    Result := True;
  end;
  Memo1.Lines.Add(RealUrl);
end;

//=============================================================================
//  IdHTTPのOnRedirect(リダイレクト)イベント
//  グローバル変数のRealUrlにリダイレクト先のアドレスを取得してIdHTTPのコマンド
//  の再実行を行うようにしている
//  リダイレクトの回数は，RedirectMaxmum(デフォルトでは15)で設定する
//
//  [参考]
//  リダイレクト(サーバからの応答)のステータスコード
//  301 Moved Permanently -- ページの引越しで完全にない
//  302 Moved Temporarily(HTTP1.1では307に変更?) -- 別の場所にある
//  HTTP/1.1 404 Not Found.の場合はリダイレクトを中止する
//=============================================================================
procedure TForm1.IdHTTP1Redirect(Sender: TObject; var dest: string;
  var NumRedirect: Integer; var Handled: Boolean; var VMethod: string);
begin
  if Pos('404.htm', dest) > 0 then begin
    Handled := False;
    RealUrl := '';
  end else begin
    RealUrl := dest;
    Handled := True;
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, IdBaseComponent, IdComponent, IdTCPConnection, IdTCPClient,
  IdHTTP, StdCtrls, ExtCtrls, ComCtrls;

type
  TForm1 = class(TForm)
    IdHTTP1: TIdHTTP;
    Button1: TButton;
    Memo1: TMemo;
    Panel2: TPanel;
    Panel3: TPanel;
    LabeledEdit1: TLabeledEdit;
    ProgressBar1: TProgressBar;
    SaveDialog1: TSaveDialog;
    Panel1: TPanel;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure IdHTTP1Status(ASender: TObject; const AStatus: TIdStatus;
      const AStatusText: String);
    procedure IdHTTP1Work(Sender: TObject; AWorkMode: TWorkMode;
      AWorkCount: Int64);
    procedure IdHTTP1WorkBegin(Sender: TObject; AWorkMode: TWorkMode;
      AWorkCountMax: Int64);
  private
    { Private 宣言 }
    AStream : TFileStream;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses HTTPApp;

{$R *.dfm}

//=============================================================================
//  ダウンロードファイル名をLabelEditに入力
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  Memo1.Clear;
  LabeledEdit1.Text := 'http://mrxray.on.coocan.jp/Delphi/ZipExe/plSetPrinter.zip';
end;

//=============================================================================
//  IdHTTPでダウンロードする
//
//  リダイレクト処理を行っているので，例えばCGI経由のファイルも情報取得可能
//  (ただし少し時間がかかる)
//  htm,html等の場合はソーステキストの取得となるので画像類はタウンロードしない
//
//  SourceFile : ダウンロードするファイル名
//  SaveFile   : ダウンロード後のファイル名
//               TSaveDialogで変更可能
//
//  UnixPathToDosPath関数にはusesにHTTPAppが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
 SourceFile : String;
 SaveFile   : String;
 Ret        : Boolean;
begin
  Memo1.Lines.Clear;
  Panel1.Caption := '';

  SourceFile            := LabeledEdit1.Text;
  ProgressBar1.Position := 0;
  Screen.Cursor         := crHourGlass;

  //リダイレクト処理をTrueに
  IdHTTP1.HandleRedirects := True;

  //ファイルまたはページが見つかったら保存先を選択してダウンロード
  try
    //このURLが存在しないと，Headメソッド実行でエラーとなる
    //リダイレクト実行後に，URLにリダイレクト先のURLが取得できる
    IdHTTP1.Head(SourceFile);
    Ret := True;
  except
    if IdHTTP1.ResponseCode = 302 then begin
      //リダイレクト後のURLで再度Headメソッドを実行して情報取得
      IdHTTP1.Head(IdHTTP1.Response.Location);
      Ret := True;
    end else begin
      Ret := False;
    end;
  end;

  if Ret then begin
    SourceFile := IdHTTP1.URL.URI;
    SaveFile   := ExtractFilePath(ParamStr(0)) +
                  ExtractFileName(UnixPathToDosPath(SourceFile));
    SaveDialog1.FileName := SaveFile;

    if SaveDialog1.Execute then begin
      Update;
      AStream := TFileStream.Create(SaveDialog1.FileName, fmCreate);
      try
        IdHTTP1.Get(SourceFile, AStream);
      finally
        FreeAndNil(AStream);
      end;
      Panel1.Caption := 'ダウンロード終了';
    end;
  end else begin
    MessageDlg('指定したページまたはファイルが見つかりませんでした．',
               mtInformation,
               [mbOK],0);
  end;
  IdHTTP1.Disconnect;

  Screen.Cursor := crDefault;
end;

//=============================================================================
//  IdHTTPのOnWorkBeginイベント
//  プログレスバーの最大値をセット
//=============================================================================
procedure TForm1.IdHTTP1WorkBegin(Sender: TObject; AWorkMode: TWorkMode;
  AWorkCountMax: Int64);
begin
    ProgressBar1.Max := AWorkCountMax;
end;

//=============================================================================
//  IdHTTPのOnWorkイベント
//  ダウンロードの進捗(進行)状況をプログレスバーに表示
//=============================================================================
procedure TForm1.IdHTTP1Work(Sender: TObject; AWorkMode: TWorkMode;
  AWorkCount: Int64);
var
  StrText : String;
begin
  ProgressBar1.Position := AWorkCount;
  StrText := IntToStr(AStream.Size - AStream.Position);
  Panel1.Caption :='残り　' + StrText + ' バイト';
  Panel1.Update;
end;

//=============================================================================
//  IdHTTPのOnStatusイベント
//  接続やダウンロードの状態をMemoに表示
//=============================================================================
procedure TForm1.IdHTTP1Status(ASender: TObject; const AStatus: TIdStatus;
  const AStatusText: String);
begin
  Memo1.Lines.Add(AStatusText);
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, IdBaseComponent, IdComponent, IdTCPConnection, IdTCPClient,
  IdHTTP, StdCtrls, ExtCtrls, ComCtrls, IdThreadComponent;

type
  TForm1 = class(TForm)
    IdHTTP1: TIdHTTP;
    Panel2: TPanel;
    ProgressBar1: TProgressBar;
    SaveDialog1: TSaveDialog;
    Button1: TButton;
    Button2: TButton;
    LabeledEdit1: TLabeledEdit;
    Panel1: TPanel;
    IdThreadComponent1: TIdThreadComponent;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);
    procedure IdHTTP1Work(ASender: TObject; AWorkMode: TWorkMode;
      AWorkCount: Int64);
    procedure IdHTTP1WorkBegin(ASender: TObject; AWorkMode: TWorkMode;
      AWorkCountMax: Int64);
    procedure IdThreadComponent1Run(Sender: TIdThreadComponent);
  private
    { Private 宣言 }
    FSaveFileName   : String;
    FSourceFile     : String;
    FSourceFileSize : Int64;
    FIsCancel       : Boolean;
    FDownLoadError  : Boolean;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses HTTPApp, IdThread;

{$R *.dfm}

//=============================================================================
//  ダウンロードファイル名をLabelEditに入力
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  LabeledEdit1.Text := 'http://mrxray.on.coocan.jp/Delphi/ZipExe/plSetPrinter.zip';
end;

//=============================================================================
//  フォームを閉じる時の処理
//  接続中の時は接続を切断してスレッドを終了する
//=============================================================================
procedure TForm1.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
begin
  if IdHTTP1.Connected then begin
    IdThreadComponent1.Stop;
    IdHTTP1.Disconnect;
    FIsCancel := True;
  end;
end;

//=============================================================================
//  IdHTTPでダウンロードする
//  リダイレクト処理を行っているので，例えばCGI経由のファイルも情報取得可能
//  (ただし少し時間がかかる)
//  htm,html等の場合はソーステキストの取得となるので画像類はタウンロードしない
//
//  UnixPathToDosPath関数にはusesにHTTPAppが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LIsSrcFile : Boolean;
begin
  FSourceFile := LabeledEdit1.Text;
  ProgressBar1.Position := 0;

  //リダイレクト処理をTrueに
  IdHTTP1.HandleRedirects := True;
  try
    //このURLが存在しないとHeadメソッド実行でエラーとなる
    //リダイレクト実行後に，URLにリダイレクト先のURLが取得できる
    IdHTTP1.Head(FSourceFile);
    LIsSrcFile := True;
  except
    if IdHTTP1.ResponseCode = 302 then begin
      //リダイレクト後のURLで再度Headメソッドを実行して情報取得
      IdHTTP1.Head(IdHTTP1.Response.Location);
      LIsSrcFile := True;
    end else begin
      LIsSrcFile := False;
    end;
  end;

  //ダウンロードするファイルが存在する場合
  if LIsSrcFile then begin
    FSourceFile     := IdHTTP1.URL.URI;
    FSaveFileName   := ExtractFilePath(Application.ExeName) +
                       ExtractFileName(UnixPathToDosPath(FSourceFile));
    FSourceFileSize := IdHTTP1.Response.ContentLength;

    SaveDialog1.FileName := FSaveFileName;
    //ローカルの保存先設定
    if SaveDialog1.Execute then begin
      FSaveFileName := SaveDialog1.FileName;

      Screen.Cursor  := crHourGlass;
      FDownLoadError := False;
      //スレッドを開始してダウンロード開始
      IdThreadComponent1.Start;
      //ダウンロードが終了するまで(スレッドが終了するで)待つ
      //OnTerminateやOnStoppedイベントで処理する方法も考えられる
      while True do begin
        if IdThreadComponent1.Terminated then Break;
        Application.ProcessMessages;
        Sleep(1);
      end;

      if FIsCancel then begin
        MessageDlg('ダウンロードを中止しました', mtInformation, [mbOK],0);
      end else
      //ダウンロードに失敗した場合
      if FDownLoadError then begin
        MessageDlg('ダウンロードに失敗しました', mtInformation,[mbOK],0);
      end else begin
        Panel1.Caption := 'ダウンロード終了';
      end;
    end;
  end else begin
    MessageDlg('指定したページまたはファイルが見つかりませんでした',
               mtInformation,
               [mbOK],0);
  end;

  IdHTTP1.Disconnect;
  Screen.Cursor := crDefault;
end;

//=============================================================================
//  キャンセルボタン
//  ダウンロード途中のファイルが存在するので，削除した方がいいかも知れない
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  if IdHTTP1.Connected then begin
    FIsCancel := True;
    IdHTTP1.Disconnect;
    IdThreadComponent1.Stop;
  end;
end;

//=============================================================================
//  IdThreadComponent1のOnRunイベント
//  このイベント内でダウンロード処理を行う
//=============================================================================
procedure TForm1.IdThreadComponent1Run(Sender: TIdThreadComponent);
var
  LStream : TFileStream;
begin
  LStream := TFileStream.Create(FSaveFileName, fmCreate);
  try
    try
      //FSourceFileをダウンロードしてLStreamに格納
      IdHTTP1.Get(FSourceFile, LStream);
    except
      //ダウンロード失敗
      FDownLoadError := True;
    end;
  finally
    IdThreadComponent1.Terminate;
    if IdHTTP1.Connected then begin
      IdHTTP1.Disconnect;
    end;
    FreeAndNil(LStream);
  end;
end;

//=============================================================================
//  IdHTTP1のOnWorkBeginイベント処理
//  ダウンロードを開始すると発生するイベント
//=============================================================================
procedure TForm1.IdHTTP1WorkBegin(ASender: TObject; AWorkMode: TWorkMode;
  AWorkCountMax: Int64);
begin
  ProgressBar1.Max := FSourceFileSize;
end;

//=============================================================================
//  IdHTTP1のOnWorkイベント処理
//  ダウンロード中に発生するイベント
//=============================================================================
procedure TForm1.IdHTTP1Work(ASender: TObject; AWorkMode: TWorkMode;
  AWorkCount: Int64);
var
  LStrText : String;
begin
  ProgressBar1.Position := AWorkCount;

  LStrText := IntToStr(FSourceFileSize - AWorkCount);
  Form1.Panel1.Caption :='残り　' + LStrText + ' バイト';
end;

end.

unit IndyVersionUnit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, IdBaseComponent, IdComponent, IdTCPConnection, IdTCPClient,
  IdHTTP;

type
  TForm1 = class(TForm)
    Button1: TButton;
    IdHTTP1: TIdHTTP;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  Indyのバージョンを調べる
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  Application.MessageBox(PChar(IdHTTP1.Version), 'バージョン番号');
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, IdBaseComponent, IdComponent, IdTCPConnection, IdTCPClient,
  IdHTTP, StdCtrls, ExtCtrls, ComCtrls, IdIOHandler, IdIOHandlerSocket,
  IdIOHandlerStack, IdSSL, IdSSLOpenSSL;

type
  TForm1 = class(TForm)
    IdHTTP1: TIdHTTP;
    Button1: TButton;
    Memo1: TMemo;
    Panel3: TPanel;
    LabeledEdit1: TLabeledEdit;
    Panel1: TPanel;
    IdSSLIOHandlerSocketOpenSSL1: TIdSSLIOHandlerSocketOpenSSL;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure IdHTTP1Status(ASender: TObject; const AStatus: TIdStatus;
      const AStatusText: String);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  LabeledEdit1.Text := 'https://code.google.com/p/indydocs/';
end;

//=============================================================================
//  IdHTTPでダウンロードする
//
//  SourceFile : ダウンロードするファイル名
//  SaveFile   : ダウンロードしたファイルの保存ファイル名
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LSourceFile : String;
  LSaveFile   : String;
  LStream     : TFileStream;

begin
  Memo1.Lines.Clear;
  Panel1.Caption := '';
  LSourceFile    := LabeledEdit1.Text;
  Screen.Cursor  := crHourGlass;

  //リダイレクト処理をTrueに
  IdHTTP1.HandleRedirects := True;

  LSaveFile := ExtractFilePath(ParamStr(0)) + 'AAA.html';
  LStream   := TFileStream.Create(LSaveFile, fmCreate);
  try
    IdHTTP1.Get(LSourceFile, LStream);
  finally
    FreeAndNil(LStream);
  end;
  Panel1.Caption := 'ダウンロード終了';
  IdHTTP1.Disconnect;

  Screen.Cursor := crDefault;
end;

//=============================================================================
//  IdHTTP1のOnStatusイベント
//  接続等の状態をTMemoに表示
//=============================================================================
procedure TForm1.IdHTTP1Status(ASender: TObject; const AStatus: TIdStatus;
  const AStatusText: String);
begin
  Memo1.Lines.Add(AStatusText);
end;

end.