unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private 宣言 }
    FFilePath : string;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Memo1.Lines.Clear;

  //文字列をセット
  Memo1.Lines.Add(#$4F60#$597D + ' !!');
  Memo1.Lines.Add(#$D842#$DFB7 + ' (サロゲートペアな文字)');
  Memo1.Lines.Add('テキストをバイナリ形式で保存');

  FFilePath := ExpandFileName('..\000.bin');
end;

//=============================================================================
//  文字列を TBinaryWriter を使用して，テキストをバイナリ形式で保存
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LFileStream : TFileStream;
  LBinWriter  : TBinaryWriter;
  LText       : string;
begin
  // ファイルストリームとTBinaryWriterを生成
  LFileStream := TFileStream.Create(FFilePath, fmOpenWrite or fmCreate);
  LBinWriter  := TBinaryWriter.Create(LFileStream, TEncoding.Unicode, False);
  try
    LText := Memo1.Lines.Text;

    // 文字列を書き込む
    LBinWriter.Write(LText);
    LBinWriter.Close;
  finally
    FreeAndNil(LBinWriter);
    FreeAndNil(LFileStream);
  end;
end;

//=============================================================================
//  保存したデータを TBinaryReader を使用して読み出す
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LFileStream : TFileStream;
  LBinReader  : TBinaryReader;
  LText       : string;
begin
  Memo1.Lines.Clear;

  // ファイルストリームとTBinaryReaderを生成
  LFileStream := TFileStream.Create(FFilePath, fmOpenRead or fmShareDenyNone);
  LBinReader  := TBinaryReader.Create(LFileStream, TEncoding.Unicode, False);
  try
    // バイナリデータを文字列として読み込む
    LText := LBinReader.ReadString;
    LBinReader.Close;
  finally
    FreeAndNil(LBinReader);
    FreeAndNil(LFileStream);
  end;
  // 目的の文字列に代入
  Memo1.Lines.Text := LText;
end;

end.

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  FFilePath := ExpandFileName('..\000.bin');
  OpenDialog1.InitialDir := ExtractFileDir(FFilePath);
end;

//=============================================================================
//  TBinaryWriter を使用して保存したデータを読み込む
//  TMemo1.Lines.LoadFromFile メソッドを使用
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  Memo1.Lines.Clear;
  OpenDialog1.FileName := ExtractFileName(FFilePath);
  if not OpenDialog1.Execute then exit;

  OpenDialog1.InitialDir := ExtractFileDir(OpenDialog1.FileName);
  FFilePath := OpenDialog1.FileName;

  Memo1.Lines.LoadFromFile(FFilePath);
end;

//=============================================================================
//  TBinaryWriter を使用して保存したデータを読み込む
//  TFileStream のストリームを TMemo1.Lines.LoadFromFile メソッドで読み込む
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LFileStream : TFileStream;
  LMemStream  : TMemoryStream;
  LText       : string;
begin
  Memo1.Lines.Clear;
  OpenDialog1.FileName := ExtractFileName(FFilePath);
  if not OpenDialog1.Execute then exit;

  LFileStream := TFileStream.Create(FFilePath, fmOpenRead or fmShareDenyNone);
  try
    Memo1.Lines.LoadFromStream(LFileStream);
  finally
    FreeAndNil(LFileStream);
  end;
end;

//=============================================================================
//  TBinaryWriter を使用して保存したデータを読み込む
//  TFileStream のストリームを TMemo1.Lines.LoadFromFile メソッドで読み込む
//  Unicode として読み込む
//  TBinaryWriter では文字列を Unicode で保存している
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
var
  LFileStream : TFileStream;
begin
  Memo1.Lines.Clear;
  OpenDialog1.FileName := ExtractFileName(FFilePath);
  if not OpenDialog1.Execute then exit;

  OpenDialog1.InitialDir := ExtractFileDir(OpenDialog1.FileName);
  FFilePath := OpenDialog1.FileName;

  LFileStream := TFileStream.Create(FFilePath, fmOpenRead or fmShareDenyNone);
  try
    Memo1.Lines.LoadFromStream(LFileStream, TEncoding.Unicode);
  finally
    FreeAndNil(LFileStream);
  end;
end;

type
  TMyBinReader = class(TBinaryReader);

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  FFilePath := ExpandFileName('..\000.bin');
  OpenDialog1.InitialDir := ExtractFileDir(FFilePath);
end;

//=============================================================================
//  TBinaryWriter を使用して保存したデータを読み込む
//
//  TBinaryWriter は Write7BitEncodedInt でファイルの先頭にバイト数を書き込む
//  そのバイト数が実際の文字列のバイナリデータのバイト数
//  そのバイト数を TBinaryReader.Read7BitEncodedInt メソッドで取得
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LBinReader  : TBinaryReader;
  LFileStream : TFileStream;
  LStartByte  : Integer;
  LMemStream  : TMemoryStream;
  LText       : string;
begin
  Memo1.Lines.Clear; 

  OpenDialog1.FileName := ExtractFileName(FFilePath);
  if not OpenDialog1.Execute then exit;

  OpenDialog1.InitialDir := ExtractFileDir(OpenDialog1.FileName);
  FFilePath := OpenDialog1.FileName;

  LFileStream := TFileStream.Create(FFilePath, fmOpenRead or fmShareDenyNone);
  LBinReader  := TBinaryReader.Create(LFileStream, TEncoding.Unicode, False);
  try
    // 実際の文字列のバイナリデータの保存開始位置を取得
    LStartByte := LFileStream.Size - TMyBinReader(LBinReader).Read7BitEncodedInt;
  finally
    FreeAndNil(LBinReader);
    FreeAndNil(LFileStream);
  end;

  LMemStream := TMemoryStream.Create;
  try
    // ファイルのデータをメモリストリームに読み込む
    LMemStream.LoadFromFile(FFilePath);

    // 文字列のエレメント数を設定
    SetLength(Ltext, (LMemStream.Size - LStartByte) div SizeOf(Char));

    // 読出し開始位置まで移動して文字列型の変数に読み込む
    LMemStream.Position := LStartByte;
    LMemStream.Read(LText[1], Length(LText) * SizeOf(Char));

    // メモリストリームから読み出した文字列を TMemo で表示
    Memo1.Lines.Text := LText;
  finally
    FreeAndNil(LMemStream);
  end;
end;

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Memo1.Lines.Clear;

  //文字列をセット
  Memo1.Lines.Add(#$4F60#$597D + ' !!');
  Memo1.Lines.Add(#$D842#$DFB7 + ' (サロゲートペアな文字)');
  Memo1.Lines.Add('テキストをバイナリ形式で保存');

  FFilePath := ExpandFileName('..\000.txt');
end;

//=============================================================================
//  TMemo に表示しているテキストをファイルに保存
//  先頭にバイトテータ ( $08 ) を書き込む
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LMemStream : TMemoryStream;
  LByte      : Byte;
  LText      : string;
begin
  LMemStream := TMemoryStream.Create;
  try
    LText := Memo1.Lines.Text;

    LByte := $08;
    LMemStream.Write(LByte, 1);

    LMemStream.Write(LText[1], Length(LText) * SizeOf(Char));
    LMemStream.SaveToFile(FFilePath);
  finally
    FreeAndNil(LMemStream);
  end;
end;

//=============================================================================
//  ファイルのデータをメモリストリームに読み込む
//  先頭の余分なデータを削除して，元のテキストを取得
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LMemStream : TMemoryStream;
  LByte      : Byte;
  LText      : string;
begin
  Memo1.Lines.Clear;

  LMemStream := TMemoryStream.Create;
  try
    LMemStream.LoadFromFile(FFilePath);

    LMemStream.Read(LByte, 1);

    SetLength(LText, (LMemStream.Size - 1) div 2);
    LMemStream.Read(LText[1], LMemStream.Size - 1);
    Memo1.Lines.Text := LText;
  finally
    FreeAndNil(LMemStream);
  end;
  Memo1.Lines.Text := LText;
end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    OpenDialog1: TOpenDialog;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private 宣言 }
    FFilePath : string;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Memo1.Font.Charset := ANSI_CHARSET;
  Memo1.Font.Name    := 'Courier New';
  Memo1.Font.Size    := 9;

  FFilePath := ExpandFileName('..\000.bin');
  OpenDialog1.InitialDir := ExtractFileDir(FFilePath);
end;

//=============================================================================
//  ファイルのデータをバイナリ値で表示
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LStream   : TBytesStream;
  LStrList  : TStringList;
  LLineText : string;
  LIndex    : Integer;
begin
  Memo1.Lines.Clear;
  OpenDialog1.FileName := ExtractFileName(FFilePath);
  if not OpenDialog1.Execute then exit;

  FFilePath := OpenDialog1.FileName;
  OpenDialog1.InitialDir := ExtractFileDir(FFilePath);

  LStream  := TBytesStream.Create;
  LStrList := TStringList.Create;
  try
    //ファイルの内容をストリームに読み出す
    LStream.LoadFromFile(FFilePath);

    //バイト配列の各要素(バイナリデータ)の値を16進数の文字に変換
    LLineText := '';
    for LIndex := 0 to LStream.Size - 1 do begin
      if ((LIndex mod 16) = 0) and (LIndex <> 0) then begin
        LStrList.Add(TrimRight(LLineText));
        LLineText := '';
      end else
      if (LIndex mod 8) = 0 then begin
        LLineText := LLineText + ' ';
      end;
      LLineText := LLineText + IntToHex(LStream.Bytes[LIndex], 2) + ' ';

      Application.ProcessMessages;
    end;
    if LLineText <> '' then LStrList.Add(TrimRight(LLineText));

    Memo1.Text := LStrList.Text;
  finally
    FreeAndNil(LStrList);
    FreeAndNil(LStream);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private 宣言 }
    FFilePath : string;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Memo1.Lines.Clear;

  //文字列をセット
  Memo1.Lines.Add(#$4F60#$597D + ' !!');
  Memo1.Lines.Add(#$D842#$DFB7 + ' (サロゲートペアな文字)');
  Memo1.Lines.Add('バイナリデータを 16 進数文字列にして保存');

  FFilePath := ExtractFilePath(Application.ExeName) + '000.txt';
end;

//=============================================================================
//  文字列のバイナリデータはコードポイントの値
//  それをバイナリダンプ形式の 16 進数の文字列にして保存
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LStream   : TBytesStream;
  LStrList  : TStringList;
  LLineText : string;
  LIndex    : Integer;
begin
  LStream  := TBytesStream.Create;
  LStrList := TStringList.Create;
  try
    // テキストをストリームに格納
    Memo1.Lines.SaveToStream(LStream, TEncoding.Unicode);

    // バイト配列の各要素(バイナリデータ)の値を 16 進数の文字に変換
    LLineText := '';
    for LIndex := 0 to LStream.Size - 1 do begin
      if ((LIndex mod 16) = 0) and (LIndex <> 0) then begin
        LStrList.Add(TrimRight(LLineText));
        LLineText := '';
      end else
      if (LIndex mod 8) = 0 then begin
        LLineText := LLineText + ' ';
      end;
      LLineText := LLineText + IntToHex(LStream.Bytes[LIndex], 2) + ' ';

      Application.ProcessMessages;
    end;
    if LLineText <> '' then LStrList.Add(TrimRight(LLineText));

    LStrList.SaveToFile(FFilePath);
  finally
    FreeAndNil(LStrList);
    FreeAndNil(LStream);
  end;
end;

//=============================================================================
//  保存した 16 進数の文字列を読み出して処理
//  16 進数の 4 桁の文字列を整数に変換して，それを Char で変換
//  
//  バイナリデータにデータに型の情報はない
//  保存する時に型情報も保存しないと元に戻せない
//  Unicode の文字 1 エレメントは 2 バイト (16 進数の 4 桁) だから型情報は不要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LStrList : TStringList;
  LLoadTxt : string;
  LBOMText : string;
  LText    : string;
  LBinText : string;
  LIndex   : Integer;
begin
  Memo1.Lines.Clear;

  LStrList := TStringList.Create;
  try
    // 保存した文字列を読み込む
    LStrList.LoadFromFile(FFilePath);

    // 不要な文字を削除
    // 文字単位で検索して処理した方が速いかも知れない
    LLoadTxt := LStrList.Text;
    LLoadTxt := StringReplace(LLoadTxt, ' ', '', [rfReplaceAll]);
    LLoadTxt := StringReplace(LLoadTxt, '-', '', [rfReplaceAll]);
    LLoadTxt := StringReplace(LLoadTxt, sLineBreak,'', [rfReplaceAll]);

    // BOM ( U+FEFF - ZERO WIDTH NO-BREAK SPACE ) 判定用文字列
    LBOMText := Copy(LLoadTxt, 1, 4);
    // BOM の文字列は除外
    LLoadTxt := copy(LLoadTxt, 5, Length(LLoadTxt));

    LText := '';
    for LIndex := 0 to Length(LLoadTxt) div 4 - 1 do begin
      LBinText := '$' + Copy(LLoadTxt, LIndex * 4 + 1, 4);

      // リトルエンディアンの時はバイトオーダを逆にする
      if LBOMText = 'FFFE' then begin
        LText := LText + Char(Swap(StrToInt(LBinText)));
      end else begin
        LText := LText + Char(StrToInt(LBinText));
      end;
    end;
    Memo1.Lines.Add(LText);
  finally
    FreeAndNil(LStrList);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private 宣言 }
    FFilePath : string;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Memo1.Lines.Clear;

  //文字列をセット
  Memo1.Lines.Add(#$4F60#$597D + ' !!');
  Memo1.Lines.Add(#$D842#$DFB7 + ' (サロゲートペアな文字)');
  Memo1.Lines.Add('バイナリデータを 16 進数文字列にして保存');

  FFilePath := ExtractFilePath(Application.ExeName) + '000.txt';
end;

//=============================================================================
//  文字列のバイナリデータはコードポイントの値
//  それを 16 進数の文字列にして保存
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LStrList : TStringList;
  LText    : string;
  LBinText : string;
  LIndex   : Integer;
begin
  LStrList := TStringList.Create;
  try
    LText := Memo1.Lines.Text;

    LBinText := '';
    for LIndex := 1 to Length(LText) do begin
      LBinText := LBinText + IntToHex(Ord(LText[LIndex]), 4);
    end;
    LStrList.Add(LBinText);
    // Shift_JIS で保存
    LStrList.SaveToFile(FFilePath);
  finally
    FreeAndNil(LStrList);
  end;
end;

//=============================================================================
//  保存した 16 進数の文字列を読み出して処理
//  16 進数の 4 桁の文字列を整数に変換して，それを Char で変換
//  Unicode の文字 1 エレメントは 2 バイト (16 進数の 4 桁)
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LStrList : TStringList;
  LText    : string;
  LBinText : string;
  LIndex   : Integer;
begin
  Memo1.Lines.Clear;

  LStrList := TStringList.Create;
  try
    LStrList.LoadFromFile(FFilePath);

    LText := '';
    for LIndex := 0 to Length(LStrList.Text) div 4 - 1 do begin
      LBinText := '$' + Copy(LStrList.Text, LIndex * 4 + 1, 4);
      LText := LText + Char(StrToInt(LBinText));
    end;
    Memo1.Lines.Add(LText);
  finally
    FreeAndNil(LStrList);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private 宣言 }
    FFilePath : string;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Memo1.Lines.Clear;

  //文字列をセット
  Memo1.Lines.Add(#$4F60#$597D + ' !!');
  Memo1.Lines.Add(#$D842#$DFB7 + ' (サロゲートペアな文字)');
  Memo1.Lines.Add('バイナリデータを 16 進数文字列にして保存');

  FFilePath := ExtractFilePath(Application.ExeName) + '000.txt';
end;

//=============================================================================
//  文字列のバイナリデータはコードポイントの値
//  それを 16 進数の文字列にして保存
//  BinToHex 関数を使用する例
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LStrList : TStringList;
  LText    : string;
  LBinText : string;
begin
  LStrList := TStringList.Create;
  try
    LText := Memo1.Lines.Text;

    // 出力の 16 進数の桁数を設定
    SetLength(LBinText, Length(Memo1.Lines.Text) * SizeOf(Char) * 2);
    BinToHex(@Memo1.Lines.Text[1], PWideChar(LBinText), Length(LBinText));

    LStrList.Add(LBinText);
    LStrList.SaveToFile(FFilePath);
  finally
    FreeAndNil(LStrList);
  end;
end;

//=============================================================================
//  保存した 16 進数の文字列を読み出して処理
//  HexToBin 関数を使用する例
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LStrList : TStringList;
  LLoadTxt : string;
  LText    : string;
begin
  Memo1.Lines.Clear;

  LStrList := TStringList.Create;
  try
    LStrList.LoadFromFile(FFilePath);
    // 16 進数の文字に小文字があっても処理可能にする
    LLoadTxt := UpperCase(LStrList.Text);

    // 出力の文字のエレメント数を設定
    SetLength(LText, Length(LLoadTxt) div (SizeOf(Char) * 2));
    HexToBin(PWideChar(LLoadTxt), @LText[1], Length(LLoadTxt));

    Memo1.Lines.Add(LText);
  finally
    FreeAndNil(LStrList);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private 宣言 }
    FFilePath : string;
    FXorValue : Byte;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Memo1.Lines.Clear;

  //文字列をセット
  Memo1.Lines.Add(#$4F60#$597D + ' !!');
  Memo1.Lines.Add(#$D842#$DFB7 + ' (サロゲートペアな文字)');
  Memo1.Lines.Add('テキストを暗号化して保存');

  FFilePath := ExtractFilePath(Application.ExeName) +'000.bin';
  FXorValue := 23;
end;

//-----------------------------------------------------------------------------
//  簡易暗号化復号化のルーチン
//  各バイト値に対してxorしているので，もう一度xorすれば元のバイト値に戻る
//  xorする値は任意(バイト値の範囲内)
//-----------------------------------------------------------------------------
procedure XorBytesStream(AStream: TBytesStream; AByte: Byte);
var
  i : integer;
begin
  for i := 0 to AStream.Size - 1 do begin
    AStream.Bytes[i] := AStream.Bytes[i] xor AByte;
  end;
end;

//=============================================================================
//  TMemoに表示しているテキストを暗号化してファイルに保存
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LStream : TBytesStream;
begin
  LStream := TBytesStream.Create;
  try
    Memo1.Lines.SaveToStream(LStream, TEncoding.Unicode);
    XorBytesStream(LStream, FXorValue);
    LStream.SaveToFile(FFilePath);
  finally
    FreeAndNil(LStream);
  end;
end;

//=============================================================================
//  ファイルから読み出した暗号化したテキストを復号化して表示
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LStream : TBytesStream;
begin
  Memo1.Lines.Clear;

  LStream := TBytesStream.Create;
  try
    LStream.LoadFromFile(FFilePath);
    XorBytesStream(LStream, FXorValue);
    Memo1.Lines.LoadFromStream(LStream, TEncoding.Unicode);
  finally
    FreeAndNil(LStream);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private 宣言 }
    FFilePath : string;
    FXorValue : Byte;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Memo1.Lines.Clear;

  //文字列をセット
  Memo1.Lines.Add(#$4F60#$597D + ' !!');
  Memo1.Lines.Add(#$D842#$DFB7 + ' (サロゲートペアな文字)');
  Memo1.Lines.Add('テキストを暗号化して保存');

  FFilePath := ExtractFilePath(Application.ExeName) +'000.bin';
  FXorValue := 23;
end;


//  TBytesが実装されていないDelphiではこれを定義する
type
  TBytes = array of Byte;

//-----------------------------------------------------------------------------
//  簡易暗号化復号化のルーチン
//  各バイト値に対してxorしているので，もう一度xorすれば元のバイト値に戻る
//  xorする値は任意(バイト値の範囲内)
//
//  TMemoryStreamの読み出しと書き込み位置の設定に注意
//  TMemoryStreamのの値を1バイトづつ処理してもよい
//-----------------------------------------------------------------------------
procedure XorBytesStreamEx(AStream: TMemoryStream; AByte: Byte);
var
  LBytes : TBytes;
  i      : integer;
begin
  //バイト配列のサイズを設定
  SetLength(LBytes, AStream.Size);

  //ストリームの内容をバイト配列に読み出す
  AStream.Position := 0;
  AStream.ReadBuffer(LBytes[0], AStream.Size);

  //暗号化または復号化
  for i := 0 to Length(LBytes) - 1 do begin
    LBytes[i] := LBytes[i] xor AByte;
  end;

  //バイト配列のデータをストリームに書き込む
  AStream.Position := 0;
  AStream.WriteBuffer(LBytes[0], Length(LBytes));
  AStream.Position := 0;
end;

//=============================================================================
//  TMemoに表示しているテキストを暗号化してファイルに保存
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LStream : TMemoryStream;
begin
  LStream := TMemoryStream.Create;
  try
    Memo1.Lines.SaveToStream(LStream);
    XorBytesStreamEx(LStream, FXorValue);
    LStream.SaveToFile(FFilePath);
  finally
    FreeAndNil(LStream);
  end;
end;

//=============================================================================
//  ファイルから読み出した暗号化したテキストを復号化して表示
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LStream : TMemoryStream;
begin
  Memo1.Lines.Clear;

  LStream := TMemoryStream.Create;
  try
    LStream.LoadFromFile(FFilePath);
    XorBytesStreamEx(LStream, FXorValue);
    Memo1.Lines.LoadFromStream(LStream);
  finally
    FreeAndNil(LStream);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private 宣言 }
    FFilePath : string;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Memo1.Lines.Clear;

  //文字列をセット
  Memo1.Lines.Add(#$4F60#$597D + ' !!');
  Memo1.Lines.Add(#$D842#$DFB7 + ' (サロゲートペアな文字)');
  Memo1.Lines.Add('テキストを UTF-7 でエンコードして保存');

  FFilePath := ExpandFileName('.\000.txt');
end;

//=============================================================================
//  テキストを UTF-7 でエンコードして保存
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  Memo1.Lines.SaveToFile(FFilePath, TEncoding.UTF7);
end;

//=============================================================================
//  UTF-7 でエンコードして保存したテキストファイルを読み出す
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  Memo1.Lines.Clear;

  Memo1.Lines.LoadFromFile(FFilePath, TEncoding.UTF7);
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, AppEvnts;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Edit1: TEdit;
    ApplicationEvents1: TApplicationEvents;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure ApplicationEvents1Message(var Msg: tagMSG; var Handled: Boolean);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
    function IsBinaryFile(Filename: string): Boolean;
    function IsBinaryFileByMIME(AFilename: string): Boolean;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  ShellAPI,
  UrlMon,
  StrUtils;

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  //ドラッグアンドドロップを許可
  //usesにShellAPIが必要
  DragAcceptFiles(Edit1.Handle, True);
end;

//=============================================================================
//  ファイルがバイナリかテキストかを判定する
//  ファイルのMIMEタイプで調べる
//  調べるファイルは，Edit1に入力するか，ドラッグ&ドロップする
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  if IsBinaryFileByMIME(Edit1.Text) then begin
    MessageBox(Handle, 'バイナリ', '結果', MB_ICONINFORMATION);
  end else begin
    MessageBox(Handle, 'テキスト', '結果', MB_ICONINFORMATION);
  end;
end;

//=============================================================================
//  ファイルがバイナリかテキストかを判定する
//  調べるファイルは，Edit1に入力するか，ドラッグ&ドロップする
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  if IsBinaryFile(Edit1.Text) then begin
    MessageBox(Handle, 'バイナリ', '結果', MB_ICONINFORMATION);
  end else begin
    MessageBox(Handle, 'テキスト', '結果', MB_ICONINFORMATION);
  end;
end;

//=============================================================================
//  TApplicationEventsコンポのOnMessageイベント処理
//  エクスプローラからEdit1にドラッグ&ドロップした時の処理
//
//  このプログラムを管理者権限で実行した場合はドラッグ & ドロップできない
//=============================================================================
procedure TForm1.ApplicationEvents1Message(var Msg: tagMSG;
  var Handled: Boolean);
var
  LBuffer   : array [0..MAX_PATH-1] of Char;
  LFilePath : String;
begin
  if Msg.message = WM_DROPFILES then begin
    if (FindDragTarget(Msg.pt, False) = Edit1) then begin
      try
        if DragQueryFile(Msg.wParam, High(DWORD), nil, 0) = 1 then begin
          DragQueryFile(Msg.WParam, 0, @LBuffer, MAX_PATH);
          LFilePath  := LBuffer;
          Edit1.Text := LFilePath;
        end;
      finally
        //ドロップが完了したことを伝える
        DragFinish(msg.WParam);
      end;
    end;
  end;
end;

//-----------------------------------------------------------------------------
//  バイナリかテキストファイルかを自動判定(自動判別)する関数
//  ファイルのMIMEタイプで調べる
//
//  FindMimeFromDataの使用にはusesにUrlMonが必要
//-----------------------------------------------------------------------------
function TForm1.IsBinaryFileByMIME(AFilename: string): Boolean;
const
  MAX_COUNT = 256;
var
  LStream    : TFileStream;
  LMimeType  : PWideChar;
  LBinReader : TBinaryReader;
  LBinArray  : TArray<Byte>;
  LReadSize  : Cardinal;
  LRet       : HRESULT;
begin
  Result := False;

  //ファイルストリームを生成
  LStream := TFileStream.Create(AFileName, fmOpenRead or fmShareDenyNone);
  if LStream.Size > MAX_COUNT then begin
    LReadSize := MAX_COUNT;
  end else begin
    LReadSize := LStream.Size;
  end;

  //TBinaryReaderのインスタンス生成
  LBinReader := TBinaryReader.Create(LStream, TEncoding.Default, False);
  try
    //バイト型配列に格納
    LBinArray := LBinReader.ReadBytes(LReadSize);

    LMimeType := nil;
    LRet := FindMimeFromData(nil, nil, LBinArray, LReadSize, nil, 0, LMimeType, 0);
    if LRet = S_OK then begin
      //プレインテキストだけを判定する場合は text/plain とする
      if not StrUtils.ContainsText(LMimeType, 'text/') then begin
        Result := True;
      end;
    end;
  finally
    FreeAndNil(LBinReader);
    FreeAndNil(LStream);
  end;
end;

//-----------------------------------------------------------------------------
//  バイナリかプレインテキストファイルかを自動判定(自動判別)する関数
//　ファイルの先頭255バイト内にコントロールコードでなおかつ改行，タブ以外のもの
//  が6つ以上あればバイナリーファイルと判定
//  判定に使用するバイト数を大きくすればより確実となる
//
//  NiftyのFDELPHI 16番会議室 玉石混淆みんなで作るSample蔵
//  [01104] ぶんぶん鈴木さんのコードより検出部分を改変
//-----------------------------------------------------------------------------
function TForm1.IsBinaryFile(Filename: String): Boolean;
const
  ReadSize = 255;
var
  LFile      : File;
  LNumRead   : Integer;
  i          : Integer;
  LCtrlCount : integer;
  LOrdInt    : Integer;
  LReadBuff  : array [0..ReadSize-1] of Byte;
begin
  Result := False;

  AssignFile(LFile, Filename );
  Reset(LFile, 1);
  BlockRead( LFile, LReadBuff, ReadSize, LNumRead );
  CloseFile(LFile);

  LCtrlCount := 0;
  for i := 0 to LNumRead do begin
    LOrdInt := Ord(LReadBuff[i]);
    if (LOrdInt in [0..$1F,$7F,$FD..$FF]) and not (LOrdInt in [9..$0D,$20]) then begin
      Inc(LCtrlCount);
    end;
    if LCtrlCount > 5 then Result := True;
  end;
end;

end.

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,
  Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private 宣言 }
    FFilePath : string;
    FXorValue : Byte;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  System.Zip;

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Memo1.Lines.Clear;

  //文字列をセット
  Memo1.Lines.Add(#$4F60#$597D + ' !!');
  Memo1.Lines.Add(#$D842#$DFB7 + ' (サロゲートペアな文字)');
  Memo1.Lines.Add('テキストを ZIP 書庫で保存');

  FFilePath := ExtractFilePath(Application.ExeName) +'000.bin';
  FXorValue := 23;
end;

//=============================================================================
//  TMemoに表示しているテキストをZIP書庫を作成してそこに保存
//  Delpoi XE2以降用
//
//  usesにSystem.Zipが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LStream  : TStream;
  LZipFile : TZipFile;
begin
  LStream  := TMemoryStream.Create;
  LZipFile := TZipFile.Create;
  try
    //TMemoのテキストをストリームに保存
    Memo1.Lines.SaveToStream(LStream, TEncoding.Unicode);

    //ZIP書庫を開く(なければ作成)
    LZipFile.Open(FFilePath, zmWrite);
    //作成したZIP書庫にストリームのデータをTest.txtという名前で追加
    LStream.Position := 0;
    LZipFile.Add(LStream, 'Test.txt');
  finally
    FreeAndNil(LStream);
    FreeAndNil(LZipFile);
  end;
end;

//=============================================================================
//  ZIP書庫内の特定のファイルを取り出す
//  Delpoi XE2以降用
//
//  usesにSystem.Zipが必要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LStream       : TStream;
  LZipFile      : TZipFile;
  LLocalHeader  : TZipHeader;
begin
  Memo1.Lines.Clear;

  LStream  := TMemoryStream.Create;
  LZipFile := TZipFile.Create;
  try
    //ZIP書庫を開く
    LZipFile.Open(FFilePath, zmRead);
    //ZIP書庫内の指定したファイルの内容をストリームに読み込む
    LZipFile.Read('Test.txt', LStream, LLocalHeader);

    //TMemoに表示
    Memo1.Lines.LoadFromStream(LStream, TEncoding.Unicode);
  finally
    FreeAndNil(LStream);
    FreeAndNil(LZipFile);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls, AbZipper, AbBase, AbBrowse, AbZBrows, AbUnzper;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    Button2: TButton;
    AbUnZipper1: TAbUnZipper;
    AbZipper1: TAbZipper;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private 宣言 }
    FFilePath : string;
    FXorValue : Byte;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  AbUtils,
  AbArcTyp;

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Memo1.Lines.Clear;

  //文字列をセット
  Memo1.Lines.Add(#$4F60#$597D + ' !!');
  Memo1.Lines.Add(#$D842#$DFB7 + ' (サロゲートペアな文字)');
  Memo1.Lines.Add('テキストを書庫ファイルで保存');

  FFilePath := ExtractFilePath(Application.ExeName) +'000.bin';
  FXorValue := 23;
end;

//=============================================================================
//  TMemoに表示しているテキストをZIP書庫を作成してそこに保存
//  拡張子が.ZIPでないと保存できないようなので，拡張子を変更して操作
//
//  atZip等の定数名の使用するにはusesに AbUtilsが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LFilePath : string;
  LStream   : TStream;
begin
  //ファイルの拡張子を.ZIPに変更
  LFilePath := ChangeFileExt(FFilePath, '.zip');
  if FileExists(FFilePath) then begin
    RenameFile(FFilePath, LFilePath);
  end;

  LStream  := TMemoryStream.Create;
  try
    //TMemoのテキストをストリームに保存
    Memo1.Lines.SaveToStream(LStream, TEncoding.Unicode);

    //ZIP書庫の設定
    AbZipper1.ArchiveType   := atZip;
    AbZipper1.BaseDirectory := ExtractFilePath(LFilePath);
    AbZipper1.FileName      := ExtractFileName(LFilePath);
    AbZipper1.Password      := '';
    AbZipper1.AutoSave      := False;
    //格納するファイルは置き換えとする
    AbZipper1.StoreOptions  := AbZipper1.StoreOptions + [soReplace];

    //ZIP書庫にファイルを追加して保存
    LStream.Position := 0;
    AbZipper1.AddFromStream('Test.txt', LStream);
    AbZipper1.Save;
    //保存したら閉じる
    AbZipper1.CloseArchive;

    //ファイルの拡張子を.BINに変更
    RenameFile(LFilePath, FFilePath);
  finally
    FreeAndNil(LStream);
  end;
end;

//=============================================================================
//  ZIP書庫内の特定のファイルを取り出す
//
//  atZip等の定数名の使用するにはusesに AbUtilsが必要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LStream : TStream;
begin
  Memo1.Lines.Clear;

  LStream  := TMemoryStream.Create;
  try
    //既存のZIP書庫の設定
    AbUnZipper1.ArchiveType   := atZip;
    AbUnZipper1.BaseDirectory := ExtractFilePath(FFilePath);
    AbUnZipper1.FileName      := ExtractFileName(FFilePath);
    AbUnZipper1.Password      := '';

    //ZIP書庫内の指定のファイルをストリームに読み込む
    AbUnZipper1.ExtractToStream('Test.txt', LStream);
    //処理が終わったら閉じる
    AbUnZipper1.CloseArchive;

    //ストリームから読み出して表示
    LStream.Position := 0;
    Memo1.Lines.LoadFromStream(LStream, TEncoding.Unicode);
  finally
    FreeAndNil(LStream);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private 宣言 }
    FFilePath : string;
    FXorValue : Byte;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  SciZipFile;

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Memo1.Lines.Clear;

  //文字列をセット
  Memo1.Lines.Add(#$4F60#$597D + ' !!');
  Memo1.Lines.Add(#$D842#$DFB7 + ' (サロゲートペアな文字)');
  Memo1.Lines.Add('テキストを ZIP 書庫ファイルで保存');

  FFilePath := ExtractFilePath(Application.ExeName) +'000.bin';
  FXorValue := 23;
end;

//=============================================================================
//  TMemoに表示しているテキストをZIP書庫を作成してそこに保存
//  SciZipFileを使用
//  SciZipFileはAnsi版なのでユニコードな文字は扱えない
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LStream  : TMemoryStream;
  LZipFile : TZipFile;
  {$IFDEF UNICODE}
  LRawStr : RawByteString;
  {$ELSE}
  LRawStr : AnsiString;
  {$ENDIF}
begin
  LStream  := TMemoryStream.Create;
  LZipFile := TZipFile.Create;
  try
    //TMemoのテキストをストリームに保存
    Memo1.Lines.SaveToStream(LStream);

    //ZIP書庫にファイルを追加
    //既に存在する場合は上書きとなる
    LZipFile.AddFile('Test.txt');

    //追加したファイルの内容を設定
    LStream.Position := 0;
    SetLength(LRawStr, LStream.Size);
    LStream.Read(LRawStr[1], LStream.Size);
    LZipFile.Data[0] := LRawStr;

    //保存
    LZipFile.SaveToFile(FFilePath);
  finally
    FreeAndNil(LStream);
    FreeAndNil(LZipFile);
  end;
end;

//=============================================================================
//  ZIP書庫内の特定のファイルを取り出す
//  SciZipFileを使用
//  SciZipFileはAnsi版なのでユニコードな文字は扱えない
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LStream  : TStringStream;
  LZipFile : TZipFile;
begin
  Memo1.Lines.Clear;

  LZipFile := TZipFile.Create;
  try
    //ZIP書庫を読み出す
    LZipFile.LoadFromFile(FFilePath);

    //書庫の最初のファイルをストリームに読み出す
    LStream := TStringStream.Create(LZipFile.Data[0]);
    try
      //ストリームから読み出して表示
      LStream.Position := 0;
      Memo1.Lines.LoadFromStream(LStream);
    finally
      FreeAndNil(LStream);
    end;
  finally
    FreeAndNil(LZipFile);
  end;
end;

end.