program Project1;

{$R *.dres}

uses
  Forms,
  Vcl.Themes,
  Vcl.Styles,
  Unit1 in 'Unit1.pas' {Form1};

{$R *.res}

//-----------------------------------------------------------------------------
//  VCLスタイルを設定する関数
//-----------------------------------------------------------------------------
function SetVCLStyle: Boolean;
var
  VCLH: TStyleManager.TStyleServicesHandle;
begin
  Result := False;
  if FindResource(HInstance, 'Resource_1', 'VCLSTYLE') <> 0 then begin
    VCLH := TStyleManager.LoadFromResource(HInstance, 'Resource_1', 'VCLSTYLE');
    if VCLH <> nil then begin
      TStyleManager.SetStyle(VCLH);
      Result := True;
    end;
  end;
end;

begin
  //VCLスタイルを設定
  SetVCLStyle;

  Application.Initialize;
  Application.MainFormOnTaskbar := True;
  Application.CreateForm(TForm1, Form1);
  Application.Run;
end.

library DllTest_DLL;

{$R *.dres}

uses
  Winapi.Windows,
  Vcl.Dialogs,
  System.Classes,
  Vcl.Themes,
  VCL.Styles,
  Vcl.Controls,
  Vcl.Forms,
  DllFormUnit in 'DllFormUnit.pas' {DllForm};

{$R *.res}

var
  SaveDllProc : procedure(Reason: Integer);
  SaveApplication : TApplication;
  SaveScreen      : TScreen;

//-----------------------------------------------------------------------------
//  DllProc関数の処理
//  本サンプルでは、DllEntryという名前に置き換えている
//-----------------------------------------------------------------------------
procedure DLLEntry(Reason: Integer);
var
  VclH : TStyleManager.TStyleServicesHandle;
begin
  if Reason = DLL_PROCESS_ATTACH then begin
    //元のTApplicationとTScreenを退避
    //本サンプルでは必要ないが参考用として
    SaveApplication := Application;
    SaveScreen      := Screen;

    //DLLのプロセス生成時の処理
    //リソースからVCLスタイルの情報を取得してセット
    if FindResource(HInstance, 'Resource_2', 'VCLSTYLE') <> 0 then begin
      if TStyleManager.TryLoadFromResource(HInstance,
                                           'Resource_2',
                                           'VCLSTYLE',
                                           VclH) then begin
        if VclH <> nil then TStyleManager.SetStyle(VclH);
      end;
    end;
  end else
  if Reason = DLL_PROCESS_DETACH then begin
    //退避したTApplicationとTScreen変数を元に戻す
    Application := SaveApplication;
    Screen      := SaveScreen;

    //その他のDLLプロセス終了時の処理
  end;

  //元のDllProcを実行
  if Assigned(SaveDllProc) then begin
    if Reason >= 0 then begin
      SaveDllProc(Reason);
    end;
  end;
end;

//-----------------------------------------------------------------------------
//  外部から呼び出して実行する関数
//  DllFormというフォームをモーダル表示
//  引数に文字列を追加する場合は、PCharにする
//-----------------------------------------------------------------------------
function ShowTestForm(hOwner: HWND): TModalResult; stdcall;
var
  ARect : TRect;
begin
  GetWindowRect(hOwner, ARect);

  //この代入のコードは、TDllForm.Createの引数をnilにすれば必要ないが参考として
  Application.Handle := hOwner;
  DllForm := TDllForm.Create(Application);
  try
    //表示位置を変更できるようpoDesignedにして、表示位置を変更
    DllForm.Position := poDesigned;
    DllForm.Left := ARect.Left + 100;
    DllForm.Top  := ARect.Top  + 50;
    Result := DllForm.ShowModal;
  finally
    DllForm.Free;
  end;
  Application.Handle := 0;
end;

//-----------------------------------------------------------------------------
exports
  ShowTestForm;

//-----------------------------------------------------------------------------
//  DLL初期化時の処理
//  DllProcはDLLのプロセス、スレッドの開始。終了時に自動実行される(SysInit.pas)
//-----------------------------------------------------------------------------
begin
  //元のDllProcを退避
  SaveDllProc := @DllProc; 
  DllProc     := @DLLEntry; 
  //DLL初期化時に1回だけ実行
  DLLEntry(DLL_PROCESS_ATTACH);
end.

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, 
  System.Classes, Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

function ShowTestForm(hOwner: HWND): TModalResult; stdcall; external 'DllTest_DLL.dll';

//-----------------------------------------------------------------------------
//  DLL内のShowTestForm関数を実行する
//-----------------------------------------------------------------------------
procedure TForm1.Button1Click(Sender: TObject);
begin
  ShowTestForm(Application.Handle);
end;

end.

//-----------------------------------------------------------------------------
//  外部から呼び出して実行する関数
//  VCLのスタイルを変更する
//  AStyleはリソース名
//-----------------------------------------------------------------------------
function ChangeVCLStyle(AStyle: PChar): Boolean; stdcall;
var
  VclH : TStyleManager.TStyleServicesHandle;
begin
  Result := False;
  //問題が発生する可能性があるので、VCLスタイルが適用されていない場合は変更しない
  //DLL生成時に何かしらのVCLスタイルを適用しておくこと
  if not TStyleManager.IsCustomStyleActive then exit;


  //リソースからVCLスタイルの情報を取得してセット
  if FindResource(HInstance, AStyle, 'VCLSTYLE') <> 0 then begin
    if TStyleManager.TryLoadFromResource(HInstance,
                                         AStyle,
                                         'VCLSTYLE',
                                         VclH) then begin
      if VclH <> nil then begin
        TStyleManager.SetStyle(VclH);
        Result := True;
      end;
    end;
  end;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  ChangeVCLStyle('Resource_4');
end;

    TCustomStyleEngine.UnRegisterSysStyleHook('#32768', TSysPopupStyleHook);

library DllTest_DLL;

{$R *.dres}

uses
  Winapi.Windows,
  System.Classes,
  Vcl.Themes,
  VCL.Styles,
  Vcl.Controls,
  Vcl.Forms,
  DllFormUnit in 'DllFormUnit.pas' {DllForm};

{$R *.res}

var
  SaveDllProc : procedure(Reason: Integer);
  SaveApplication : TApplication;
  SaveScreen      : TScreen;

//-----------------------------------------------------------------------------
//  DllProc関数の処理
//  本サンプルでは、DllEntryという名前に置き換えている
//-----------------------------------------------------------------------------
procedure DLLEntry(Reason: Integer);
var
  VclH : TStyleManager.TStyleServicesHandle;
begin
  if Reason = DLL_PROCESS_ATTACH then begin
    //元のTApplicationとTScreen変数を退避
    SaveApplication := Application;
    SaveScreen      := Screen;

    //DLLのプロセス生成時の処理
    //リソースからVCLスタイルの情報を取得してセット
    if FindResource(HInstance, 'Resource_2', 'VCLSTYLE') <> 0 then begin
      if TStyleManager.TryLoadFromResource(HInstance,
                                           'Resource_2',
                                           'VCLSTYLE',
                                           VclH) then begin
        if VclH <> nil then TStyleManager.SetStyle(VclH);
      end;
    end;
  end else
  if Reason = DLL_PROCESS_DETACH then begin
    //退避したTApplicationとTScreen変数を元に戻す
    Application := SaveApplication;
    Screen      := SaveScreen;

    //その他のDLLプロセス終了時の処理

  end;

  //元のDllProcを実行
  if Assigned(SaveDllProc) then begin
    if Reason >= 0 then begin
      SaveDllProc(Reason);
    end;
  end;
end;

//-----------------------------------------------------------------------------
//  外部から呼び出して実行する関数
//  DllFormというフォームを表示
//-----------------------------------------------------------------------------
function ShowTestForm(App: TApplication; AScreen: TScreen): HWND; stdcall;
begin
  Application := App;
  Screen      := AScreen;
  DllForm := TDllForm.Create(Application);
  DllForm.Show;

  Result := DllForm.Handle;
end;

//-----------------------------------------------------------------------------
exports
  ShowTestForm;

//-----------------------------------------------------------------------------
//  DLL初期化時の処理
//  DllProcはDLLのプロセス、スレッドの開始。終了時に自動実行される(SysInit.pas)
//-----------------------------------------------------------------------------
begin
  //元のDllProcを退避
  SaveDllProc := @DllProc; 
  DllProc     := @DLLEntry; 
  //DLL初期化時に1回だけ実行
  DLLEntry(DLL_PROCESS_ATTACH);
end.

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, 
  System.Classes, Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

function ShowTestForm(App: TApplication; AScreen: TScreen): HWND;
  stdcall; external 'DllTest_DLL.dll';

//-----------------------------------------------------------------------------
//  DLL内のShowTestForm関数を実行する
//-----------------------------------------------------------------------------
procedure TForm1.Button1Click(Sender: TObject);
begin
  ShowTestForm(Application, Screen);
end;

end.