procedure TForm1.Button1Click(Sender: TObject);
var
  R1 : Single;
begin
  R1 := 0.1;

  if R1 = 0.1 then begin
    MessageBox(Handle, '同じ値です', '結果', MB_ICONINFORMATION);
  end else begin
    MessageBox(Handle, '同じ値ではありません', '結果', MB_ICONWARNING);
  end;
end;

//=============================================================================
//  実数値を四捨五入して表示する例
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  E, F : Double;
begin
  E := 0.5600000000000001;
  F := 0.5599999999999917;

  Memo1.Lines.Add(' E: ' + FormatFloat('##0.00000', E));
  Memo1.Lines.Add(' F: ' + FormatFloat('##0.00000', F));

  // 数値を小数点以下の指定桁で四捨五入する
  // SimpleRoundTo の使用には uses に Math が必要
  Memo1.Lines.Add(' E: ' + FloatToStr(SimpleRoundTo(E, -5)));
  Memo1.Lines.Add(' F: ' + FloatToStr(SimpleRoundTo(F, -5)));
end;

//=============================================================================
//  実数値が指定範囲内にあるかを判定する例
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LValue  : Single;
  LRefVal : Single;
  LIncVal : Single;
  LCount  : Integer;
begin
  Memo1.Lines.Clear;

  // 数学的には LValue と LRefVal は同じ値になる
  LValue  := 0.0;
  for LCount := 1 to 1000 do begin
    LValue := LValue + 0.0001;
  end;
  LRefVal := 0.1;

  // Double 型であれば 1.0E-13 らいまで可能
  LIncVal := Abs(LRefVal * 1.0E-4);
  if (LValue >= (LRefVal - LIncVal)) and (LValue <= (LRefVal + LIncVal)) then begin
    Memo1.Lines.Add('範囲内');
  end else begin
    Memo1.Lines.Add('範囲外');
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  LSingle : UInt64;
  LDouble : UInt64;
begin
  LSingle := $7FFFFF;        // 23 ビット
  LDouble := $FFFFFFFFFFFFF; // 52 ビット

  Memo1.Lines.Add(UIntToStr(LSingle));
  Memo1.Lines.Add(UIntToStr(LDouble));
end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    Button5: TButton;
    Button6: TButton;
    Button7: TButton;
    Panel1: TPanel;
    Panel2: TPanel;
    Panel3: TPanel;
    Panel4: TPanel;
    Panel5: TPanel;
    Panel6: TPanel;
    Panel71: TPanel;
    Panel72: TPanel;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure Button5Click(Sender: TObject);
    procedure Button6Click(Sender: TObject);
    procedure Button7Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses FMTBcd;

{$R *.dfm}

//=============================================================================
//  0.1に10を掛ける
//  Button2Clickのコードと違い、コンパイラが誤差なく計算してくれる。これは言語
//  の仕様によって異なるので、他のコンパイラでも同じ結果となるとは限らない
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  A : Single;
begin
  A:=0.1*10;
  Panel1.Caption := FormatFloat('000.0000000000', A);
end;

//=============================================================================
//  0.1を10回加算しても数学的に意味の1.0とはならない例
//  例えば帳票類で等間隔に罫線を描画する時には注意が必要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  A : Single;
  i : Integer;
begin
  A := 0.0;
  for i:=0 to 9 do begin
    A := A + 0.1;
  end;
  Panel2.Caption := FormatFloat('000.0000000000', A);
end;

//=============================================================================
//  ある値(実数値)を整数倍しても必ずしも数学的な整数倍にならない例
//  例えばButton2Clickの結果1.0000001192を50倍しても  50.000005960にはならない
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
var
  A : Single;
  i : Integer;
begin
  A := 0.0;
  for i:=0 to 9 do begin
    A := A + 0.1;
  end;
  A := A * 50;
  Panel3.Caption := FormatFloat('000.0000000000', A);
end;

//=============================================================================
//  Currency 型
//  DelphiのCurrency型は小数点以下の4桁を整数として格納する固定小数点のデータ型
//  で、金額計算などでの丸め誤差が少なくなる
//  代入文や式で他の実数型と混在させた場合はCurrency型の値に対し自動的に10000で
//  の除算または乗算が行われる
//=============================================================================
procedure TForm1.Button4Click(Sender: TObject);
var
  A : Currency;
  i : Integer;
begin
  A := 0.0;
  for i:=0 to 9 do begin
    A := A + 0.1;
  end;
  A := A * 50;
  Panel4.Caption := FormatFloat('000.0000000000', A);
end;

//=============================================================================
//  FMTBcd.pasのBCD(2進化10進数表記 Binary Coded Decimal)ルーチンを使用すれば
//  誤差なく計算できるが非常に面倒
//  FMTBcdでは4ビットに10進の各桁を保持することにより10進演算を行っている。そ
//  のため長い桁も少なくとも加減算は誤差なしに扱える
//  このコードの実行にはusesにFMTBcdが必要
//=============================================================================
procedure TForm1.Button5Click(Sender: TObject);
var
  A : TBcd;
  B : TBcd;
  i : Integer;
begin
  A := NullBcd;
  B := StrToBcd('0.1');
  for i:=0 to 9 do begin
    BcdAdd(A, B, A);
  end;
  BcdMultiply(A, 50, A);
  Panel5.Caption := FormatBcd('000.0000000000', A);
end;

//=============================================================================
//  有効桁数の激減
//  Singleの有効桁数は7～8桁なので以下の計算では有効桁数が激減してしまう。
//=============================================================================
procedure TForm1.Button6Click(Sender: TObject);
var
  A : Single;
  B : Single;
  C : Single;
begin
  A := 72366.573;
  B := 72366.550;
  C := A - B;
  Panel6.Caption := FormatFloat('00000.000000', C);
end;

//=============================================================================
//  積み残し
//  Singleの有効桁数は7～8桁なので以下の計算では0.00001は事実上、加算されない
//  元のAと加算した結果のCの値は全く同じとなってしまう
//=============================================================================
procedure TForm1.Button7Click(Sender: TObject);
var
  A : Single;
  B : Single;
  C : Single;
begin
  A := 72366.573;
  B :=     0.00001;
  C := A + B;
  Panel71.Caption := FormatFloat('00000.000000', A);
  Panel72.Caption := FormatFloat('00000.000000', C);
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    Button5: TButton;
    Button6: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure Button5Click(Sender: TObject);
    procedure Button6Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  Single(4バイトの単精度)型の場合
//  数値範囲 1.5 x 10^-45 .. 3.4 x 10^38  有効桁数 7～8
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  s : Single;
  i : Integer;
begin
  s := 0;
  for i := 0 to 9 do s := s + 0.01;
  ShowMessage(FloatToStr(s));
end;

//=============================================================================
//  Double型(8バイト)の場合
//  数値範囲 5.0 x 10^-324 .. 1.7 x 10^308  有効桁数 15～16
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  s : Double;
  i : Integer;
begin
  s := 0;
  for i := 0 to 9 do s := s + 0.01;
  ShowMessage(FloatToStr(s));
end;

//=============================================================================
//  Extended型(10バイト)の場合
//  数値範囲 3.6 x 10^-4951 .. 1.1 x 10^4932  有効桁数 19～20
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
var

  s : Extended;
  i : Integer;
begin
  s := 0;
  for i := 0 to 9 do s := s + 0.01;
  ShowMessage(FloatToStr(s));
end;

//=============================================================================
//  Currency型(8バイト)の場合
//  数値範囲 -922337203685477.5808.. 922337203685477.5807 有効桁数 19～20
//  金額を扱うには十分な桁だろう
//=============================================================================
procedure TForm1.Button4Click(Sender: TObject);
var
  s : Currency;
  i : Integer;
begin
  s := 0;
  for i := 0 to 9 do s := s + 0.01;
  ShowMessage(CurrToStr(s));
end;

//=============================================================================
//  Currency型(8バイト)の場合
//  数値範囲 -922337203685477.5808.. 922337203685477.5807 有効桁数 19～20
//  Currency型が扱える小数点以下4桁目の値を加算
//=============================================================================
procedure TForm1.Button5Click(Sender: TObject);
var
  s : Currency;
  i : Integer;
begin
  s := 0;
  for i := 0 to 9 do s := s + 0.0001;
  ShowMessage(CurrToStr(s));
end;

//=============================================================================
//  Currency型(8バイト)の場合
//  数値範囲 -922337203685477.5808.. 922337203685477.5807 有効桁数 19～20
//  Currency型が扱える範囲を越えた小数点以下5桁目の値を加算
//=============================================================================
procedure TForm1.Button6Click(Sender: TObject);
var
  s : Currency;
  i : Integer;
begin
  s := 0;
  for i := 0 to 9 do s := s + 0.00001;
  ShowMessage(CurrToStr(s));
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Edit1: TEdit;
    Edit2: TEdit;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormShow(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  変換元の値をセット
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  Edit1.Text := '1234567890123.56';
end;

//=============================================================================
//  桁落ちの例
//  Extended型の数値をTrunc関数で整数にしてみる
//  Extended型の扱える桁数よりも、Integer(32bit)が扱える有効桁数は少ない
//  したがって結果はとんでもない値となる
//
//  整数型の説明はヘルプの[整数型]で
//  実数型の説明はヘルプの[実数型]で
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  Ret   : Integer;
  Value : Extended;
begin
  //文字列を実数に変換
  Value := StrToFloat(Edit1.Text);

  //整数に変換
  Ret := Trunc(Value);
  Edit2.text := IntToStr(Ret);
end;

//=============================================================================
//  桁落ちしないように整数を64bitにして有効桁数を確保する
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  Ret   : Int64;
  Value : Extended;
begin
  //文字列を実数に変換
  Value := StrToFloat(Edit1.Text);

  //整数に変換
  Ret := Trunc(Value);
  Edit2.text := IntToStr(Ret);
end;

end.

procedure TForm1.Button1Click(Sender: TObject);
var
  E : Extended;
  StrText : String;
begin
  Memo1.Lines.Clear;
  Memo1.Font.Name := 'ＭＳ ゴシック';
  Memo1.Font.Size := 10;
  Memo1.Lines.Add('1 2345678901234567890');
  Memo1.Lines.Add('-----------------------------------------');

  E := 1.00000000000000000612;
  Memo1.Lines.Add('1.00000000000000000612');
  Memo1.Lines.Add(FormatFloat('0.00000000000000000000000E+000' , E));

  System.Str(E: 22: 20, StrText);
  Memo1.Lines.Add(StrText);
  Memo1.Lines.Add(FloatToStr(E));
  E := E - 1.0;
  Memo1.Lines.Add(FormatFloat('0.000E+000', E));
end;

function Roundoff(X: Extended): Integer;
begin
  if X >= 0 then Result := Trunc(X + 0.5)
            else Result := Trunc(X - 0.5);
end;

function Roundoff(X: Extended): Integer;
begin
  Result := SimpleRoundTo(X, 0);
end;

//=============================================================================
//  数値を文字列に変換
//  書式が必要なければTStringHelperが使用できる(Delphi XE3 以降専用
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LValue : Double;
  LText  : string;
begin
  LValue := 123.456;
  LText := string.Parse(LValue);

  Memo1.Lines.Clear;
  Memo1.Lines.Add(LText);
end;

//=============================================================================
//  数値を文字列に変換
//  書式が必要な場合
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LValue : Double;
  LText  : string;
begin
  LValue := 123.456;
  LText := FormatFloat('#0.00000', LValue);

  Memo1.Lines.Clear;
  Memo1.Lines.Add(LText);
end;

//=============================================================================
//  TStringHelperのメソッドを使用して文字列を数値に変換
//  TStringHelperには文字列各種の型の数値に変換するメソッド類がある
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LValue : Double;
  LText  : string;
begin
  LText  := '123.456';
  LValue := LText.ToDouble(LText);

  Memo1.Lines.Clear;
  Memo1.Lines.Add(FormatFloat('#0.000', LValue));
end;

//=============================================================================
//  Trunc関数(小数点以下を切り捨て)の挙動
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LInteger : Integer;
  LDouble  : Double;
begin
  Memo1.Lines.Clear;

  LInteger := Trunc(9.98 * 100);
  Memo1.Lines.Add(IntToStr(LInteger));

  // 数値を明示的に実数型とする場合
  LInteger := Trunc(9.98 * 100.0);
  Memo1.Lines.Add(IntToStr(LInteger));

  // 計算結果の値を実数型の変数に代入してからTrunc関数の引数とする場合
  LDouble  := 9.98 * 100;
  LInteger := Trunc(LDouble);
  Memo1.Lines.Add(IntToStr(LInteger));

  // 各々の数値をそれぞれの型の変数に代入してからTrunc関数の引数とする場合
  LDouble  := 9.98;
  LInteger := 100;
  LInteger := Trunc(LDouble * LInteger);
  Memo1.Lines.Add(IntToStr(LInteger));

  // 末尾の桁の値が 6 の場合
  LDouble  := 9.9799999999999996;
  LInteger := Trunc(LDouble * 100);
  Memo1.Lines.Add(IntToStr(LInteger));

  // 末尾の桁の値が 5 の場合
  LDouble  := 9.9799999999999995;
  LInteger := Trunc(LDouble * 100);
  Memo1.Lines.Add(IntToStr(LInteger));
end;

//=============================================================================
//  Trunc関数(小数点以下を切り捨て)の挙動
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LInteger  : Integer;
  LIntegerB : Integer;
  LDouble   : Double;
begin
  Memo1.Lines.Clear;

  // この結果は 4。これ以降の計算結果は全て 5
  LInteger := Trunc(5 * 0.01 * 100);
  Memo1.Lines.Add(IntToStr(LInteger));

  // 数値を明示的に実数型とする場合
  LInteger := Trunc(5.0 * 0.01  * 100.0);
  Memo1.Lines.Add(IntToStr(LInteger));

  // 数値の大きい値の順に計算する場合
  LInteger := Trunc(100 * 5 * 0.01);
  Memo1.Lines.Add(IntToStr(LInteger));

  // 計算結果の値を実数型の変数に代入してからTrunc関数の引数とする場合
  LDouble  := 5 * 0.01 * 100;
  LInteger := Trunc(LDouble);
  Memo1.Lines.Add(IntToStr(LInteger));

  // 各々の数値をそれぞれの型の変数に代入してからTrunc関数の引数とする場合
  LInteger  := 5;
  LIntegerB := 100;
  LDouble   := 0.01;
  LInteger := Trunc(LInteger * LDouble * LIntegerB);
  Memo1.Lines.Add(IntToStr(LInteger));
end;

//=============================================================================
//  Trunc関数(小数点以下を切り捨て)の挙動
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LInteger : Integer;
begin
  Memo1.Lines.Clear;

  // 引数の値を小数点以下 19 桁目で四捨五入
  // この計算式の場合は小数点以下 19 桁目は実際にはない
  LInteger := Trunc(SimpleRoundTo((5 * 0.01 * 100), -19));
  Memo1.Lines.Add(IntToStr(LInteger));

  // 引数の値を小数点以下 10 桁目で四捨五入
  LInteger := Trunc(SimpleRoundTo((5 * 0.01 * 100), -10));
  Memo1.Lines.Add(IntToStr(LInteger));
end;

//=============================================================================
//  Trunc関数(小数点以下を切り捨て)の挙動
//  64 ビットの EXE の場合
//
//  Delphi XE 5(UP2) Pro    : 997 と 4 になる
//  Delphi XE 7 Pro         : 998 と 5 になる
//  Delphi 10.2.3 Community : 998 と 5 になる
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LInteger : Integer;
begin
  Memo1.Lines.Clear;

  LInteger := Trunc(9.98 * 100);
  Memo1.Lines.Add(IntToStr(LInteger));

  LInteger := Trunc(5 * 0.01 * 100);
  Memo1.Lines.Add(IntToStr(LInteger));
end;

//-----------------------------------------------------------------------------
//  ストリーミング SIMD 拡張命令 (SSE) を使用した Trunc 関数
//  SSE, SSE2,... 関係等の命令セットは Delphi XE2 以降で使用可能
//
//  CVTTSD2SI : Double 値を 64ビット整数値へ変換
//  EAX       : 演算結果の格納用レジスタ (80386以降用)
//-----------------------------------------------------------------------------
function MyTrunc(const X: Double): Integer;
asm
  CVTTSD2SI  EAX, [X]
end;

//=============================================================================
//  Trunc関数(小数点以下を切り捨て)の挙動
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LInteger : Integer;
begin
  Memo1.Lines.Clear;

  LInteger := MyTrunc(9.98 * 100);
  Memo1.Lines.Add(IntToStr(LInteger));

  LInteger := MyTrunc(5 * 0.01 * 100);
  Memo1.Lines.Add(IntToStr(LInteger));
end;

implementation

uses
  Math;

{$R *.dfm}

//=============================================================================
//  使用中のコンピュータの SSE（ストリーミング SIMD 拡張命令）機能の確認
//  usesにMathが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LRes : Cardinal;
begin
  LRes := TestSSE;

  Memo1.Lines.Clear;

  if (LRes and seSSE)       = seSSE       then Memo1.Lines.Add('SSE');
  if (LRes and seSSE2)      = seSSE2      then Memo1.Lines.Add('SSE2');
  if (LRes and seSSE3)      = seSSE3      then Memo1.Lines.Add('SSE3');
  if (LRes and seSSSE3)     = seSSSE3     then Memo1.Lines.Add('Supplemental SSE3');
  if (LRes and seSSE41)     = seSSE41     then Memo1.Lines.Add('SSE4.1');
  if (LRes and seSSE42)     = seSSE42     then Memo1.Lines.Add('SSE4.2');
  if (LRes and sePOPCNT)    = sePOPCNT    then Memo1.Lines.Add('POPCNT');
  if (LRes and seAESNI)     = seAESNI     then Memo1.Lines.Add('AES');
  if (LRes and sePCLMULQDQ) = sePCLMULQDQ then Memo1.Lines.Add('PCLMULQDQ');
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  R1 : Double;
  R2 : Single;
begin
  Memo1.Lines.Clear;

  Set8087CW(Default8087CW);
  R1 := 0.1;
  R2 := 0.1;

  Memo1.Lines.Add(FormatFloat('##0.00000000000000000000', R1));
  Memo1.Lines.Add(FormatFloat('##0.00000000000000000000', R2));

  Set8087CW($1072);
  R1 := 0.1;
  Memo1.Lines.Add(FormatFloat('##0.00000000000000000000', R1));

  Set8087CW($1272);
  R1 := 0.1;
  Memo1.Lines.Add(FormatFloat('##0.00000000000000000000', R1));
end;

implementation

uses
  Math;

{$R *.dfm}

//=============================================================================
//  FPU の現在の制御モードを取得
//  このコードは Delphi XE ではコンパイルできない
//
//  usesにMathが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LFPUPrecis  : TFPUPrecisionMode;
  LRoundMode  : TRoundingMode;
  LExceptions : TFPUExceptionMask;
begin
  Memo1.Lines.Clear;

  Memo1.Lines.Add('$' + IntToHex(Get8087CW, 4));

  LFPUPrecis := GetPrecisionMode;
  if LFPUPrecis = pmSingle   then Memo1.Lines.Add('単精度 - 24 ビット');
  if LFPUPrecis = pmDouble   then Memo1.Lines.Add('倍精度 - 53 ビット');
  if LFPUPrecis = pmExtended then Memo1.Lines.Add('拡張倍精度 - 64 ビット');

  LRoundMode := GetRoundMode;
  if LRoundMode = rmNearest  then Memo1.Lines.Add('もっとも近い整数値への丸め');
  if LRoundMode = rmDown     then Memo1.Lines.Add('切り下げ');
  if LRoundMode = rmUp       then Memo1.Lines.Add('切り上げ');
  if LRoundMode = rmTruncate then Memo1.Lines.Add('切り捨て');

  LExceptions := GetFPUExceptionMask;
  if exInvalidOp in LExceptions    then Memo1.Lines.Add('無効な演算を無視');
  if exDenormalized in LExceptions then Memo1.Lines.Add('非 0 の小さい値を許可');
  if exZeroDivide in LExceptions   then Memo1.Lines.Add('0 による除算許可');
  if exOverflow in LExceptions     then Memo1.Lines.Add('オーバーフロー許可');
  if exUnderflow in LExceptions    then Memo1.Lines.Add('アンダーフロー許可');
  if exPrecision in LExceptions    then Memo1.Lines.Add('有効桁数を超える演算許可');
end;

implementation

{$R *.dfm}

type
  TFPUPrecisionMode = (pmSingle, pmReserved, pmDouble, pmExtended);
  TRoundingMode = (rmNearest, rmDown, rmUp, rmTruncate);
  TFPUException = (exInvalidOp, exDenormalized, exZeroDivide,
                   exOverflow, exUnderflow, exPrecision);
  TFPUExceptionMask = set of TFPUException;

//----------------------------------------------------------------------------- 
// 精度制御の値は9,10ビット目にあるのでシフトして 3(2進数の11)でANDして取得 
//-----------------------------------------------------------------------------  
function GetPrecisionMode: TFPUPrecisionMode;
begin
  Result := TFPUPrecisionMode((Get8087CW shr 8) and 3);
end;

//----------------------------------------------------------------------------- 
// 丸め制御の値は11,12ビット目にあるのでシフトして 3(2進数の11)でANDして取得 
//-----------------------------------------------------------------------------  
function GetRoundMode: TRoundingMode;
begin
  Result := TRoundingMode((Get8087CW shr 10) and 3);
end;

//----------------------------------------------------------------------------- 
// 例外フラグの値は1から6ビット目にあるので3F(2進数の111111)でANDして取得 
// ビットが立っている(1である)と該当例外がマスクされている 
//-----------------------------------------------------------------------------  
function GetFPUExceptionMask: TFPUExceptionMask;
begin
  Byte(Result) := Get8087CW and $3F;
end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    Button2: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
    FDllName : string;
  end;

var
  Form1: TForm1;

implementation

uses
  Math;

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//  ロードする DLL のファイル名を設定
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  FDllName := 'XlsCrt2.DLL';
end;

//=============================================================================
//  LoadLibrary 関数で DLL をロードする場合
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LDllHandle   : THandle;
  LOldCtrlWord : Word;
  LNewCtrlWord : Word;
  LRValue      : Double;
begin
  LOldCtrlWord := Get8087CW;

  // これが現在の設定値になる
  Set8087CW($1072);

  LDllHandle := LoadLibrary(PChar(FDllName));
  try
    // 現在の設定値を取得
    // LoadLibrary で現在の設定値が変わる
    LNewCtrlWord := Get8087CW;

    Memo1.Lines.Clear;
    Memo1.Lines.Add('$' + IntToHex(LOldCtrlWord, 4));
    Memo1.Lines.Add('$' + IntToHex(LNewCtrlWord, 4));

    LRValue := 0.1;
    Memo1.Lines.Add('');
    Memo1.Lines.Add(FormatFloat('##0.00000000000000000000', LRValue));
  finally
    FreeLibrary(LDLLHandle);
  end;
end;

//=============================================================================
//  SafeLoadLibrary 関数で DLL をロードする場合
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LDllHandle   : THandle;
  LOldCtrlWord : Word;
  LNewCtrlWord : Word;
  LRValue      : Double;
begin
  LOldCtrlWord := Get8087CW;

  // これが現在の設定値になる
  Set8087CW($1072);

  LDllHandle := SafeLoadLibrary(PChar(FDllName));
  try
    // 現在の設定値を取得
    // SafeLoadLibrary では設定値は変しない
    LNewCtrlWord := Get8087CW;

    Memo1.Lines.Clear;
    Memo1.Lines.Add('$' + IntToHex(LOldCtrlWord, 4));
    Memo1.Lines.Add('$' + IntToHex(LNewCtrlWord, 4));

    LRValue := 0.1;
    Memo1.Lines.Add('');
    Memo1.Lines.Add(FormatFloat('##0.00000000000000000000', LRValue));
  finally
    FreeLibrary(LDLLHandle);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Panel1: TPanel;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses Data.FMTBcd;

{$R *.DFM}

//=============================================================================
//  Delphi XE2以降のBCD演算
//  通常の算術演算子が使用可能
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  A : TBcd;
  B : TBcd;
  i : Integer;
begin
  A := 0;
  B := 0.1;
  for i := 0 to 9 do begin
    A := A + B;
  end;
  A := A * 50;
  Panel1.Caption := FormatBcd('000.0000000000', A);
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses plLongDigit, MMSystem;

{$R *.dfm}

{ TForm1 }

//=============================================================================
//  多倍長計算ユニットplLongDigitのテスト
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  A : array of Integer;
  B : array of Integer;
  C : array of Integer;
  I : Integer;
  M : Integer;
  N : Integer;
  SL : TStringList;
begin
  M := 10000; //万進法
  N := 5;     //万進法で5桁

  SetLength(A, N + 1);
  SetLength(B, N + 1);
  SetLength(C, N + 1);

  for I := 0 to N do begin
    A[I] := 0;
    B[I] := 0;
    C[I] := 0;
  end;

  //4000000000001006000をセット
  A[5] :=  400;   //万進法の5桁目
  A[4] :=    0;   //万進法の4桁目
  A[3] :=    0;   //万進法の3桁目
  A[2] :=  100;   //万進法の2桁目
  A[1] := 6000;   //万進法の1桁目

   //1000200030004005000をセット
  B[5] :=  100;   //万進法の5桁目
  B[4] :=  200;   //万進法の4桁目
  B[3] :=  300;   //万進法の3桁目
  B[2] :=  400;   //万進法の2桁目
  B[1] := 5000;   //万進法の1桁目

  Memo1.Lines.Clear;
  SL := TStringList.Create;
  //元の値をリスト
  ListOut (A, M, N, SL);
  ListOut (B, M, N, SL);
  SL.Add(' ');
  try
    //加算
    Tasu (A, B, C, M, N);
    ListOut(C, M, N, SL);
    //減算
    Hiku (A, B, C, M, N);
    ListOut (C, M, N, SL);
    //乗算
    Kakeru (A, 4, C, M, N);
    ListOut (C, M, N, SL);
    //除算
    Waru (A, 4, C, M, N);
    ListOut (C, M, N, SL);
    Memo1.Text := SL.Text;
  finally
    FreeAndNil(SL);
  end;
end;

end.

unit plLongDigit;

interface

uses
  SysUtils, Classes, Forms;

  procedure Tasu (A,B : array Of Integer; var C: array of Integer; M,N :Integer);
  procedure Hiku (A,B : array Of Integer; var C: array of Integer; M,N :Integer);
  procedure Kakeru (A: array of Integer; B: Integer; var C: array of Integer;
    M, N: Integer);
  procedure Waru (A: array of Integer; B: Integer; var C: array of Integer;
    M, N: Integer);
  procedure AT(Bunbo,Kousu: Integer; var C: array of Integer; M,N: Integer);
  procedure ListOut (A: array of Integer; M,N: Integer; SL : TStringList);

implementation

uses Math;

//-----------------------------------------------------------------------------
//  M進法N桁の加算(Mは10の整数乗)
//  M進法N桁の数A,Bを配列A,Bに記録。その和Cを計算する
//-----------------------------------------------------------------------------
procedure Tasu(A,B: array of Integer; var C:array of Integer; M,N:Integer);
var
  CK : Integer;
  K  : Integer;
  IC : Integer;
begin
  IC := 0;
  for K := 1 to N do begin
    CK := A[K] + B[K] + IC ;
    if CK >= M then begin
      CK := CK - M;
      IC := 1;
    end else begin
      IC := 0;
    end;
    C[K] := CK;
    Application.ProcessMessages;
  end;
end;

//-----------------------------------------------------------------------------
//  M進法N桁の引き算(Mは10の整数乗)
//  M進法N桁の数A,Bを配列A,Bに記録。その差A-Bをを計算しCに格納する
//-----------------------------------------------------------------------------
procedure Hiku(A,B:array of Integer; var C:array of Integer; M,N:Integer);
var
  IB : Integer;
  AK : Integer;
  BK : Integer;
  K  : Integer;
begin
  IB := 0;
  for K := 1 to N do begin
    AK := A[K];
    BK := B[K] + IB;
    if AK < BK then begin
      AK := AK + M;
      IB := 1;
    end else begin
      IB := 0;
    end;
    C[K] := AK - BK;
    Application.ProcessMessages;
  end;
end;

//-----------------------------------------------------------------------------
//  M進法N桁の乗算(Mは10の整数乗)
//  M進法N桁の数AとM進法1桁の数Bの積を計算し、その結果を配列Cに格納する
//  数Bを大きな桁にすると大変な桁になってしまう。1桁ならM進法で1桁増加のみ
//-----------------------------------------------------------------------------
procedure Kakeru(A: array of Integer; B: Integer; var C: array of Integer;
  M, N: Integer);
var
  CK : Integer;
  IC : Integer;
  K  : Integer;
begin
  IC := 0;
  for K := 1 to N do begin
    CK := A[K] * B + IC;
    if K <> N then begin
      if CK >= M then begin
        IC := CK div M;
        CK := CK -IC * M;
      end else begin
        IC := 0;
      end;
    end;
    C[K] := CK;
    Application.ProcessMessages;
  end;
end;

//-----------------------------------------------------------------------------
//  M進法N桁の乗算(Mは10の整数乗)
//  M進法N桁の数AをM進法1桁の数Bで割り、その結果を配列Cに格納する
//-----------------------------------------------------------------------------
procedure Waru(A: array of Integer; B: Integer; var C: array of Integer;
  M, N: Integer);
var
  P  : Integer;
  Q  : Integer;
  R  : Integer;
  K  : Integer;
begin
  R := 0;
  for K := N downto 1 do begin
    P := A[K] + R * M;
    Q := P div B;
    R := P - Q * B;
    C[K] := Q;
    Application.ProcessMessages;
  end;
end;

//-----------------------------------------------------------------------------
//  M進法N桁の関数例(Mは10の整数乗)
//  逆正接の値を多倍長の級数計算でKousu項まで求め、結果を配列Cに格納する
//  計算はテイラー展開式。CPUのFPU(浮動小数点演算ユニット)では超越関数と呼ばれ
//  ている関数をこのような計算で求めている。ただしarctanの算出アルゴリズにこれ
//  が使用されているとか限らない
//  計算するのはarctan(1/Bunbo)の値
//-----------------------------------------------------------------------------
procedure AT(Bunbo, Kousu: Integer; var C: array of Integer; M,N: Integer);
var
  H    : Integer;
  BB   : Integer;
  I    : Integer;
  KOU  : Integer;
  A    : array of Integer;
  B    : array of Integer;
begin
  H  := 3;
  BB := Bunbo * Bunbo;

  SetLength(A, N + 1);
  SetLength(B, N + 1);
  for I := 0 to N do begin
    C[I] := 0;
  end;

  A[N] := M;
  Waru (A, Bunbo, A, M, N);
  Tasu (C, A, C, M, N);
  for KOU := 1 to (Kousu div 2) do begin
    Waru (A, BB, A, M, N);
    Waru (A, H, B, M, N);
    Hiku (C, B, C, M, N);
    H := H + 2;
    Waru (A, BB, A, M, N);
    Waru (A, H, B, M, N);
    Tasu (C, B, C, M, N);
    H := H + 2;
  end;
end;

//-----------------------------------------------------------------------------
//  M進法N桁の値をTStringListに格納(Mは10の整数乗)
//  万進法であれば10進で4桁ごとに区切り、1行はM進法で5桁とする
//  Log10の使用にはusesにMathが必要
//-----------------------------------------------------------------------------
procedure ListOut(A: array of Integer; M,N: Integer; SL : TStringList);
var
  I    : Integer;
  J    : Integer;
  L    : Integer;
  Str  : String;
  Fmt  : String;
  Keta : Integer;
begin
  Keta := Trunc(Log10(M));
  Fmt  := StringOfChar('0', Keta);
  I    := N;
  for L := 1 to (N div 5) + 1 do begin
    Str := '';
    for J := 1 to 5 do begin
      Str := Str + '  '+ FormatFloat(Fmt, A[I]);
      I := I - 1;
      if I = 0 then begin
        SL.Add(Str);
        exit;
      end;
    end;
    SL.Add(Str);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses plLongDigit, MMSystem;

{$R *.dfm}

{ TForm1 }

//=============================================================================
//  マチンの公式を用いてπの値を10,000桁まで計算する
//  多倍長計算として、万進法(1桁が10進の4桁)を使用
//  M進法の最後の桁はまるめ誤差のため厳密な値ではない
//
//  TimeGetTimeにはusseにMMSystemが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  M       : Integer;
  N       : Integer;
  Keta    : Integer;
  Kou5    : Integer;
  Kou239  : Integer;
  X       : array of Integer;
  XX      : array of Integer;
  Y       : array of Integer;
  Z       : array of Integer;
  ZZ      : array of Integer;
  TStart  : DWORD;
  TEnd    : DWORD;
  SL      : TStringList;
begin
  Memo1.Lines.Clear;
  Memo1.Update;

  TStart := TimeGetTime;

  //計算するπの桁数
  Keta := 10000;

  M := 10000;       //万進法
  N := Keta div 4;  //万進法でN桁

  //arctanの計算に必要なテイラー展開式の概略項数
  Kou5   := Trunc((Keta * 1.403) / 2);
  Kou239 := Trunc((Keta * 0.421) / 2);
  Kou5   := Kou5 + Kou5 div 10;
  Kou239 := Kou239 + Kou239 div 10;

  SetLength (X,  N+1);
  SetLength (XX, N+1);
  SetLength (Y,  N+1);
  SetLength (Z,  N+1);
  SetLength (ZZ, N+1);

  //arctan(1/5)の値をテイラー展開のKou5まで計算して配列Xに格納。それに4を掛ける
  AT (5, Kou5, X, M, N);
  Kakeru (X, 4, XX, M, N);
  //arctan(1/239)の値をテイラー展開のKou239まで計算して配列Yに格納
  AT (239, Kou239, Y, M, N);

  Hiku (XX, Y, Z, M, N);
  Kakeru (Z, 4, ZZ, M, N);

  TEnd := TimeGetTime;

  //結果を表示
  SL := TStringList.Create;
  try
    ListOut (ZZ, M, N, SL);
    SL.Add (' ');
    SL.Add (IntToStr(TEnd-TStart)+' ms ');
    Memo1.Text := SL.Text;
  finally
    FreeAndNil(SL);
  end;
end;

end.