unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, WbemScripting_TLB;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
    ComputerName : String;
    UserName     : String;
    PassWord     : String;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses ComObj, ActiveX;

{$R *.dfm}

{ TForm1 }

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  //これらの文字列を空文字にすればローカルコンピュータが対象となる
  ComputerName := 'VM-WIN7-32';
  UserName     := 'XXXXX';
  PassWord     := 'XXXXX';
end;

//=============================================================================
//  ネットワーク上のコンピュータの論理ディスクのプロパティの一部を取得して表示
//
//  usesにComObj,ActiveX,WbemScripting_TLBが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  objWMILocator  : ISWbemLocator;
  objWMIService  : ISWbemServices;
  objPropSet     : ISWbemObjectSet;
  objPropSetEnum : IEnumVariant;
  objTemp        : OleVariant;
  iValue         : LongWord;
begin
  Memo1.Lines.Clear;
  Memo1.Lines.BeginUpdate;

  //Wbemのオブジェクトを生成
  objWMILocator := CoSWbemLocator.Create;

  //WMIサービスに接続。引数は必要に応じて設定
  objWMIService := objWMILocator.ConnectServer(
                     ComputerName,
                     'root\cimv2',
                     UserName,
                     Password,
                     '',
                     '',
                     0,
                     nil);

  //クエリーを実行して、プロパティのセットのオブジェクトを取得
  objPropSet := objWMIService.ExecQuery(
                     'SELECT * FROM Win32_LogicalDisk',
                     'WQL',
                     wbemFlagReturnImmediately,
                     nil);

  //プロパティのセットのコレクションを取得
  objPropSetEnum := objPropSet._NewEnum as IEnumVariant;

  //-------------------------------------------------------------------------
  //  以下がプロパティの取得コード
  //-------------------------------------------------------------------------

    //順番に取り出す
  while objPropSetEnum.Next(1, objTemp, iValue) = 0 do begin
    Memo1.Lines.Add('DeviceID            ' + VarToStrDef(objTemp.DeviceID, ''));
    Memo1.Lines.Add('Size                ' + VarToStrDef(objTemp.Size, ''));
    Memo1.Lines.Add('FreeSapce           ' + VarToStrDef(objTemp.FreeSpace, ''));
    Memo1.Lines.Add('---------------------------------------');
  end;

  Memo1.Lines.EndUpdate;
end;

end.

  try
    objWMIService := objWMILocator.ConnectServer(
                       ComputerName,
                       'root\cimv2',
                       UserName,
                       Password,
                       '',
                       '',
                       0,
                       nil);
  except
    on E:Exception do begin
      if (E is EOleException) or (E is EOleSysError) then begin
        Memo1.Lines.Add(IntToHex((E as EOleException).ErrorCode, 8)
                        + ' (' + IntToStr((E as EOleException).ErrorCode) + ')');
        Memo1.Lines.Add(E.Message);
        Memo1.Lines.EndUpdate;
        exit;
      end;
    end;
  end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, WbemScripting_TLB;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private 宣言 }
    ComputerName : String;
    UserName     : String;
    PassWord     : String;
    function WbemToTDateTime(V : OleVariant): TDateTime;
    function DateTimeString(V : OleVariant): String;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses ComObj, ActiveX;

{$R *.dfm}

{ TForm1 }

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  //これらの文字列を空文字にすればローカルコンピュータが対象となる
  ComputerName := 'VM-WIN7-32';
  UserName     := 'XXXXX';
  PassWord     := 'XXXXX';
end;

//=============================================================================
//  ネットワークコンピュータのOSの起動日時と経過時間をミリ秒まで取得
//
//  usesにComObj,ActiveX,WbemScripting_TLBが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  objWMILocator  : ISWbemLocator;
  objWMIService  : ISWbemServices;
  objPropSet     : ISWbemObjectSet;
  objPropSetEnum : IEnumVariant;
  objTemp        : OleVariant;
  iValue         : LongWord;
  wmiPropSet     : ISWbemPropertySet;
  wmiProperty    : ISWbemProperty;
  fmtStrStr      : String;
  fmtStrDateTime : String;
  ADateTime      : TDateTime;
  TimeDay        : Integer;
  TimeMili       : Integer;
  IntTemp        : Integer;
  Hour           : Integer;
  Minute         : Integer;
  Second         : Integer;
  MiliSecond     : Integer;
begin
  Memo1.Lines.Clear;
  Memo1.Lines.BeginUpdate;

  //Wbemのオブジェクトを生成
  objWMILocator := CoSWbemLocator.Create;

  //WMIサービスに接続。引数は必要に応じて設定
  objWMIService := objWMILocator.ConnectServer(
                     ComputerName,
                     'root\cimv2',
                     UserName,
                     Password,
                     '',
                     '',
                     0,
                     nil);

  //クエリーを実行して、プロパティのセットのオブジェクトを取得
  objPropSet := objWMIService.ExecQuery(
                     'Select * From Win32_OperatingSystem',
                     'WQL',
                     wbemFlagReturnImmediately,
                     nil);

  //プロパティのセットのコレクションを取得
  objPropSetEnum := objPropSet._NewEnum as IEnumVariant;

  //-------------------------------------------------------------------------
  //  以下がプロパティの取得コード
  //-------------------------------------------------------------------------

  //順番に取り出す
  while objPropSetEnum.Next(1, objTemp, iValue) = 0 do begin

    //プロパティのセットを取得
    wmiPropSet := (IUnknown(objTemp) as ISWBemObject).Properties_;

    //CSName(コンピュータ名)プロパティを取得
    wmiProperty := wmiPropSet.Item('CSName', 0);
    fmtStrStr   := Format('%-17s', [wmiProperty.Name]);
    Memo1.Lines.Add(fmtStrStr + VarToStrDef(wmiProperty.Get_Value, ''));

    //Caption(OS名)プロパティを取得
    wmiProperty := wmiPropSet.Item('Caption', 0);
    fmtStrStr   := Format('%-17s', [wmiProperty.Name]);
    Memo1.Lines.Add(fmtStrStr + VarToStrDef(wmiProperty.Get_Value, ''));


    //最後に起動した日時(LastBootUpTime)を取得
    wmiProperty    := wmiPropSet.Item('LastBootUpTime', 0);
    fmtStrStr      := Format('%-17s', [wmiProperty.Name]);
    fmtStrDateTime := DateTimeString(wmiProperty.Get_Value);
    Memo1.Lines.Add(fmtStrStr + fmtStrDateTime);


    //最後に起動した日時をTDateTime型の値に変換
    ADateTime := WbemToTDateTime(wmiProperty.Get_Value);

    //その日時と現在の日時をTTimeStamp型に変換して、日とミリ秒の差を計算
    TimeDay  := DateTimeToTimeStamp(Now).Date - DateTimeToTimeStamp(ADateTime).Date;
    TimeMili := DateTimeToTimeStamp(Now).Time - DateTimeToTimeStamp(ADateTime).Time;
    if TimeMili < 0 then begin
      TimeDay  := TimeDay - 1;
      TimeMili := TimeMili + 3600 * 24 * 1000;
    end;
    //時,分,秒,ミリセコンドを計算
    Hour       := TimeMili div (3600 * 1000);
    IntTemp    := TimeMili mod (3600 * 1000);
    Minute     := IntTemp  div (60 * 1000);
    IntTemp    := IntTemp  mod (60 * 1000);
    Second     := IntTemp  div 1000;
    MiliSecond := IntTemp  mod 1000;

    Memo1.Lines.Add('経過日時         '
                    + IntToStr(TimeDay)    + '日'
                    + IntToStr(Hour)       + '時間'
                    + IntToStr(Minute)     + '分'
                    + IntToStr(Second)     + '秒'
                    + IntToStr(MiliSecond) + 'ミリ秒');
  end;

  Memo1.Lines.EndUpdate;
end;

//=============================================================================
//  CIM_DATETIMEの日付時刻型の日時を書式付き文字列に変換
//=============================================================================
function TForm1.DateTimeString(V: OleVariant): String;
var
  WMIDateTime : ISWbemDateTime;
begin
  Result := '';
  if VarIsNull(V) then exit;

  WMIDateTime := CoSWbemDateTime.Create;
  WMIDateTime.Value := V;
  Result := Format('%.4d/%.2d/%.2d %.2d:%.2d:%.2d.%.3d',
                   [WMIDateTime.Year,
                    WMIDateTime.Month,
                    WMIDateTime.Day,
                    WMIDateTime.Hours,
                    WMIDateTime.Minutes,
                    WMIDateTime.Seconds,
                    WMIDateTime.MicroSeconds * 1000]);
end;

//=============================================================================
//  CIM_DATETIMEの日付時刻型をDelphiのTDateTime型に変換する関数
//  OleVariantで返して、呼び出し側でTDateTime型に変換した方がいいかも知れない
//=============================================================================
function TForm1.WbemToTDateTime(V: OleVariant): TDateTime;
var
  WMIDateTime : ISWbemDateTime;
begin
  Result := 0;
  if VarIsNull(V) then exit;

  WMIDateTime := CoSWbemDateTime.Create;
  WMIDateTime.Value := V;
  Result := WMIDateTime.GetVarDate(True);
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, WbemScripting_TLB;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
    ComputerName : String;
    UserName     : String;
    PassWord     : String;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses ComObj, ActiveX;

{$R *.dfm}

{ TForm1 }

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  //これらの文字列を空文字にすればローカルコンピュータが対象となる
  ComputerName := 'VM-WIN7-32';
  UserName     := 'XXXXX';
  PassWord     := 'XXXXX';
end;

//=============================================================================
//  ネットワークコンピュータをシャットダウン
//  Win32_OperatingSystemのShutdownメソッドを使用する例
//
//  usesにComObj,ActiveX,WbemScripting_TLBが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  objWMILocator  : ISWbemLocator;
  objWMISecurity : ISWbemSecurity;
  objWMIService  : ISWbemServices;
  objPropSet     : ISWbemObjectSet;
  objPropSetEnum : IEnumVariant;
  objTemp        : OleVariant;
  iValue         : LongWord;
  wmiObject      : ISWbemObject;
begin
  //Wbemのオブジェクトを生成
  objWMILocator := CoSWbemLocator.Create;

  //シャットダウン特権を付与
  //ローカルコンピュータの場合に必要
  objWMISecurity := objWMILocator.Security_;
  objWMISecurity.Privileges.Add(wbemPrivilegeShutdown, True);

  //WMIサービスに接続。引数は必要に応じて設定
  objWMIService := objWMILocator.ConnectServer(
                     ComputerName,
                     'root\cimv2',
                     UserName,
                     Password,
                     '',
                     '',
                     0,
                     nil);


  //クエリーを実行して、プロパティのセットのオブジェクトを取得
  objPropSet := objWMIService.ExecQuery(
                     'SELECT * FROM Win32_OperatingSystem',
                     'WQL',
                     wbemFlagReturnImmediately,
                     nil);

  //プロパティのセットのコレクションを取得
  objPropSetEnum := objPropSet._NewEnum as IEnumVariant;

  //-------------------------------------------------------------------------
  //  以下がメソッドの実行関係
  //-------------------------------------------------------------------------

  while objPropSetEnum.Next(1, objTemp, iValue) = 0 do begin
    wmiObject := IUnknown(objTemp) as ISWBemObject;
    wmiObject.ExecMethod_('Shutdown', nil, 0, nil);
  end;
end;

end.

  //-------------------------------------------------------------------------
  //  以下がメソッドの実行関係
  //  OleVariant型を使用する場合の例
  //-------------------------------------------------------------------------

  while objPropSetEnum.Next(1, objTemp, iValue) = 0 do begin
    objTemp.ExecMethod_('Shutdown');
  end;

  //-------------------------------------------------------------------------
  //  以下がメソッドの実行関係
  //  OleVariant型を使用する場合の例
  //-------------------------------------------------------------------------

  while objPropSetEnum.Next(1, objTemp, iValue) = 0 do begin
    objTemp.Shutdown;
  end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, WbemScripting_TLB;

type
  TForm1 = class(TForm)
    Button4: TButton;
    Button5: TButton;
    Button6: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure Button5Click(Sender: TObject);
    procedure Button6Click(Sender: TObject);
  private
    { Private 宣言 }
    ComputerName : String;
    UserName     : String;
    PassWord     : String;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses ComObj, ActiveX;

{$R *.dfm}

{ TForm1 }

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  //これらの文字列を空文字にすればローカルコンピュータが対象となる
  ComputerName := 'VM-WIN7-32';
  UserName     := 'XXXXX';
  PassWord     := 'XXXXX';
end;

//-----------------------------------------------------------------------------
//  ネットワークコンピュータのシャットダウン等を実行する関数
//  Win32_OperatingSystemのWin32Shutdownメソッドを使用する例
//
//  usesにComObj,ActiveX,WbemScripting_TLBが必要
//-----------------------------------------------------------------------------
function WMIExecute_Win32Shutdown(PCName, UserName, Password: String;
  KindValue: Integer): Boolean;
var
  objWMILocator  : ISWbemLocator;
  objWMISecurity : ISWbemSecurity;
  objWMIService  : ISWbemServices;
  objPropSet     : ISWbemObjectSet;
  objPropSetEnum : IEnumVariant;
  objTemp        : OleVariant;
  iValue         : LongWord;
  wmiObject      : ISWbemObject;
  wmiParameters  : ISWbemObject;
  wmiShutdown    : ISWbemObject;
  wmiProperty    : ISWbemProperty;
  VariantTemp    : OleVariant;
  A : ISWbemPropertySet
begin
  Result := False;

  //Wbemのオブジェクトを生成
  objWMILocator := CoSWbemLocator.Create;

  //シャットダウン特権を付与
  //ローカルコンピュータの場合に必要
  objWMISecurity := objWMILocator.Security_;
  objWMISecurity.Privileges.Add(wbemPrivilegeShutdown, True);

  //WMIサービスに接続。引数は必要に応じて設定
  objWMIService := objWMILocator.ConnectServer(
                     PCName,
                     'root\cimv2',
                     UserName,
                     Password,
                     '',
                     '',
                     0,
                     nil);

  //クエリーを実行して、プロパティのセットのオブジェクトを取得
  objPropSet := objWMIService.ExecQuery(
                     'SELECT * FROM Win32_OperatingSystem',
                     'WQL',
                     wbemFlagReturnImmediately,
                     nil);


  //プロパティのセットのコレクションを取得
  objPropSetEnum := objPropSet._NewEnum as IEnumVariant;

  //-------------------------------------------------------------------------
  //  以下がメソッドとメソッドの引数の設定関係
  //  引数の名前と型はMSDNオンラインの該当メソッドの記事等で確認する
  //-------------------------------------------------------------------------

  while objPropSetEnum.Next(1, objTemp, iValue) = 0 do begin
    //最初のオブジェクトをISWbemObjectとして取得
    WmiObject := IUnknown(objTemp) as ISWbemObject;

    //メソッド名からパラメータ(引数)のオブジェクトのインスタンスを取得
    //SpawnInstance_で取得する
    wmiParameters := wmiObject.Methods_.Item('Win32Shutdown', 0).InParameters;
    wmiShutdown   := wmiParameters.SpawnInstance_(0);

    //引数Flagsをセット
    VariantTemp := KindValue;
    //wmiProperty := wmiShutdown.Properties_.Item('Flags', 0);でも可
    wmiProperty := wmiShutdown.Properties_.Add('Flags', wbemCimtypeSint32, False, 0);
    wmiProperty.Set_Value(VariantTemp);

    //引数Reservedをセット
    VariantTemp := 0;
    //wmiProperty := wmiShutdown.Properties_.Item('Reserved', 0);でも可
    wmiProperty := wmiShutdown.Properties_.Add('Reserved', wbemCimtypeSint32, False, 0);
    wmiProperty.Set_Value(VariantTemp);

    try
      //メソッドの実行
      wmiObject.ExecMethod_('Win32Shutdown', wmiShutdown, 0, nil);
      Result:= True;
    except
      Break;
    end;
  end;
end;

//=============================================================================
//  シャットダウン
//=============================================================================
procedure TForm1.Button4Click(Sender: TObject);
begin
  WMIExecute_Win32Shutdown(ComputerName, UserName, PassWord, 12);
end;

//=============================================================================
//  再起動
//=============================================================================
procedure TForm1.Button5Click(Sender: TObject);
begin
  WMIExecute_Win32Shutdown(ComputerName, UserName, PassWord, 6);
end;

//=============================================================================
//  ログオフ
//=============================================================================
procedure TForm1.Button6Click(Sender: TObject);
begin
  WMIExecute_Win32Shutdown(ComputerName, UserName, PassWord, 4);
end;

end.

  //-------------------------------------------------------------------------
  //  以下がメソッドとメソッドの引数の設定関係
  //  引数の名前と型はMSDNオンラインの該当メソッドの記事等で確認する
  //  OleVariant型で処理する場合
  //-------------------------------------------------------------------------

  while objPropSetEnum.Next(1, objTemp, iValue) = 0 do begin

    //メソッド名からパラメータのオブジェクトのインスタンスを取得
    //SpawnInstance_で取得する
    wmiParameters := objTemp.Methods_.Item('Win32Shutdown', 0).InParameters;
    wmiShutdown   := wmiParameters.SpawnInstance_;

    //引数の値を設定
    //以下のようなコードでも同じ
    //wmiShutdown.Properties_.Item('Flags') := KindValue;
    //wmiShutdown.Properties_('Flags') := KindValue;
    wmiShutdown.Flags    := KindValue;
    wmiShutdown.Reserved := 0;

    try
      //メソッドの実行
      objTemp.ExecMethod_('Win32Shutdown', wmiShutdown);
      Result:= True;
    except
      Break;
    end;
  end;

  //-------------------------------------------------------------------------
  //  以下がメソッドとメソッドの引数の設定関係
  //  引数の名前と型はMSDNオンラインの該当メソッドの記事等で確認する
  //  OleVariant型で処理する場合
  //-------------------------------------------------------------------------

  while objPropSetEnum.Next(1, objTemp, iValue) = 0 do begin

    //引数の値を設定
    Flags    := KindValue;
    Reserved := 0;

    try
      //メソッドの実行
      //VCLのメソッドと同じような使用方法
      objTemp.Win32Shutdown(Flags, Reserved);
      Result:= True;
    except
      Break;
    end;
  end;

  //シャットダウン特権を付与
  //ローカルコンピュータの場合に必要
  objWMISecurity := objWMILocator.Security_;
  objWMISecurity.Privileges.Add(wbemPrivilegeShutdown, True); 

  //呼び出し元の資格情報を使用(推奨偽装レベル)
  objWMILocator.Security_.Set_ImpersonationLevel(wbemImpersonationLevelImpersonate);
  //Windowsのデフォルトの認証
  objWMILocator.Security_.Set_AuthenticationLevel(wbemAuthenticationLevelDefault);

  //シャットダウン特権を付与
  //ローカルコンピュータの場合に必要
  objWMISecurity := objWMILocator.Security_;
  objWMISecurity.Privileges.Add(wbemPrivilegeShutdown, True);

  //呼び出し元の資格情報を使用(推奨偽装レベル)
  objWMILocator.Security_.ImpersonationLevel := wbemImpersonationLevelImpersonate;
  //Windowsのデフォルトの認証
  objWMILocator.Security_.AuthenticationLevel := wbemAuthenticationLevelDefault;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, WbemScripting_TLB;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
    ComputerName : String;
    UserName     : String;
    PassWord     : String;
    function VarToString(const OleVar: OleVariant): String;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses ComObj, ActiveX;

{$R *.dfm}

{ TForm1 }

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  //これらの文字列を空文字にすればローカルコンピュータが対象となる
  ComputerName := 'VM-WIN7-32';
  UserName     := 'XXXXX';
  PassWord     := 'XXXXX';
end;

//=============================================================================
//  ネットワークアダプタの情報の取得
//  ここでは、クエリーのwhere句で特定のコンピュータだけを指定している
//
//  usesにComObj,ActiveX,WbemScripting_TLBが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);

  //---------------------------------------------------------------------------
  //  コンピュータ名を取得する関数
  //---------------------------------------------------------------------------
  function GetSelfComputerName: String;
  var
    Buff  : array [0..MAX_COMPUTERNAME_LENGTH-1] of Char;
    ASize : Cardinal;
  begin
    ASize := SizeOf(buff);
    if Windows.GetComputerName(Buff, ASize) then begin
      Result := String(Buff);
    end else begin
      Result := '';
    end;
  end;
  //---------------------------------------------------------------------------

var
  objWMILocator  : ISWbemLocator;
  objWMIService  : ISWbemServices;
  objPropSet     : ISWbemObjectSet;
  objPropSetEnum : IEnumVariant;
  objTemp        : OleVariant;
  iValue         : LongWord;
  wmiPropSetEnum : IEnumVariant;
  wmiProperty    : ISWbemProperty;
  fmtStrStr      : String;
begin
  Memo1.Lines.Clear;
  Memo1.Lines.BeginUpdate;

  //Wbemのオブジェクトを生成
  objWMILocator := CoSWbemLocator.Create;

  //WMIサービスに接続。引数は必要に応じて設定
  objWMIService := objWMILocator.ConnectServer(
                     ComputerName,
                     'root\cimv2',
                     UserName,
                     Password,
                     '',
                     '',
                     0,
                     nil);

  //クエリーを実行して、プロパティのセットのオブジェクトを取得
  if Trim(ComputerName) = '' then ComputerName := GetSelfComputerName;
  ShowMessage(ComputerName);
  objPropSet := objWMIService.ExecQuery(
                     'SELECT * FROM Win32_NetworkAdapterConfiguration '
                     + 'where DNSHostName = "' + ComputerName + '"',
                     'WQL',
                     wbemFlagReturnImmediately,
                     nil);

  //プロパティのセットのコレクションを取得
  objPropSetEnum := objPropSet._NewEnum as IEnumVariant;

  //-------------------------------------------------------------------------
  //  以下がプロパティの取得コード
  //-------------------------------------------------------------------------

  //順番に取り出す
  while objPropSetEnum.Next(1, objTemp, iValue) = 0 do begin

    //各オブジェクトのプロパティの列挙を取得
    wmiPropSetEnum := IUnknown(objTemp.Properties_._NewEnum) as IEnumVariant;

    while wmiPropSetEnum.Next(1, objTemp, iValue) = 0 do begin
      //プロパティを取得
      wmiProperty := IUnknown(objTemp) as ISWBemProperty;

      //プロパティの名前と実際の値を文字列にして表示
      fmtStrStr := Format('%-30s', [wmiProperty.Name]);
      Memo1.Lines.Add(fmtStrStr + VarToString(wmiProperty.Get_Value));
    end;
    Memo1.Lines.Add('---------------------------------------');
  end;

  Memo1.Lines.EndUpdate;
end;

//=============================================================================
//  OleVariantの値をString型に変換(再帰処理)
//  複数の値を持つプロパティがある。そこでこれを[]で括った結果を返すことにする
//  そのためVarArrayも扱えるようにしたVarToStr関数
//=============================================================================
function TForm1.VarToString(const OleVar: OleVariant): String;
var
  LowBound  : Integer;
  HighBound : Integer;
  i         : Integer;
begin
  Result := '';

  //配列の場合
  if VarIsArray(OleVar) then begin
    LowBound  := VarArrayLowBound(OleVar, 1);
    HighBound := VarArrayHighBound(OleVar, 1);

    for i := LowBound to HighBound do begin
      if i = HighBound then begin
        Result := Result + VarToString(OleVar[i]);
      end else begin
        Result := Result + VarToString(OleVar[i]) + ',';
      end;
    end;

    Result:='[' + Result + ']';

  //単一の値を持つプロパティの場合
  end else begin
    Result := VarToStr(OleVar);
  end;
  if Result = '' then  Result := '';
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, WbemScripting_TLB;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
    ComputerName : String;
    UserName     : String;
    PassWord     : String;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses ComObj, ActiveX;

{$R *.dfm}

{ TForm1 }

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  //これらの文字列を空文字にすればローカルコンピュータが対象となる
  ComputerName := 'VM-WIN7-32';
  UserName     := 'XXXXX';
  PassWord     := 'XXXXX';
end;

//=============================================================================
//  ネットワーク上のコンピュータのIPアドレスを設定
//  ここでは、クエリーのwhere句で特定のコンピュータだけを指定している
//
//  usesにComObj,ActiveX,WbemScripting_TLBが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);

  //---------------------------------------------------------------------------
  //  コンピュータ名を取得する関数
  //---------------------------------------------------------------------------
  function GetSelfComputerName: String;
  var
    Buff  : array [0..MAX_COMPUTERNAME_LENGTH-1] of Char;
    ASize : Cardinal;
  begin
    ASize := SizeOf(buff);
    if Windows.GetComputerName(Buff, ASize) then begin
      Result := String(Buff);
    end else begin
      Result := '';
    end;
  end;

  //---------------------------------------------------------------------------
  //  文字列のバリアント型の配列を作成
  //---------------------------------------------------------------------------
  function ArrayToVarArray(Arr : array of String): OleVariant; overload;
  var
    i : integer;
  begin
    Result := VarArrayCreate([0, High(Arr)], varVariant);
    for i := Low(Arr) to High(Arr) do begin
      Result[i] := Arr[i];
    end;
  end;

  //---------------------------------------------------------------------------
  //  WORD値(32ビット値)のバリアント型の配列を作成
  //  本サンプルでは使用していない。参考用のコード
  //---------------------------------------------------------------------------
  function ArrayToVarArray(Arr : array of WORD): OleVariant; overload;
  var
    i : integer;
  begin
    Result := VarArrayCreate([0, High(Arr)], varVariant);
    for i := Low(Arr) to High(Arr) do begin
      Result[i] := Arr[i];
    end;
  end;
  //---------------------------------------------------------------------------

var
  objWMILocator  : ISWbemLocator;
  objWMIService  : ISWbemServices;
  objPropSet     : ISWbemObjectSet;
  objPropSetEnum : IEnumVariant;
  objTemp        : OleVariant;
  iValue         : LongWord;
  wmiObject      : ISWbemObject;
  wmiParameters  : ISWbemObject;
  wmiIPAddress   : ISWbemObject;
  wmiProperty    : ISWbemProperty;
  VariantTemp    : OleVariant;
  RetValue       : ISWbemObject;
begin
  Memo1.Lines.Clear;
  Memo1.Lines.BeginUpdate;

  //Wbemのオブジェクトを生成
  objWMILocator := CoSWbemLocator.Create;

  //WMIサービスに接続。引数は必要に応じて設定
  objWMIService := objWMILocator.ConnectServer(
                     ComputerName,
                     'root\cimv2',
                     UserName,
                     Password,
                     '',
                     '',
                     0,
                     nil);

  //クエリーを実行して、プロパティのセットのオブジェクトを取得
  if Trim(ComputerName) = '' then ComputerName := GetSelfComputerName;
  objPropSet := objWMIService.ExecQuery(
                     'SELECT * FROM Win32_NetworkAdapterConfiguration '
                     + 'where DNSHostName = "' + ComputerName + '"',
                     'WQL',
                     wbemFlagReturnImmediately,
                     nil);

  //プロパティのセットのコレクションを取得
  objPropSetEnum := objPropSet._NewEnum as IEnumVariant;

  //-------------------------------------------------------------------------
  //  以下がIPアドレスの設定コード
  //  配列型の引数を持つメソッドの実行例
  //  引数の名前と型はMSDNオンラインの該当メソッドの記事等で確認する
  //-------------------------------------------------------------------------

  //順番に取り出す
  while objPropSetEnum.Next(1, objTemp, iValue) = 0 do begin
    //最初のオブジェクトをISWbemObjectとして取得
    wmiObject := IUnknown(objTemp) as ISWbemObject;

    //メソッド名からパラメータ(引数)のオブジェクトのインスタンスを取得
    //SpawnInstance_で取得する
    wmiParameters := wmiObject.Methods_.Item('EnableStatic', 0).InParameters;
    wmiIPAddress  := wmiParameters.SpawnInstance_(0);

    //引数IPAddressをセット
    VariantTemp := ArrayToVarArray(['192.168.0.50']);
    wmiProperty := wmiIPAddress.Properties_.Item('IPAddress', 0);
    wmiProperty.Set_Value(VariantTemp);

    //引数SubnetMaskをセット
    VariantTemp := ArrayToVarArray(['255.255.255.0']);
    wmiProperty := wmiIPAddress.Properties_.Item('SubnetMask', 0);
    wmiProperty.Set_Value(VariantTemp);

    try
      //メソッドの実行
      RetValue := wmiObject.ExecMethod_('EnableStatic', wmiIPAddress, 0, nil);
    except
    end;

    VarClear(VariantTemp);
    //メソッドの実行結果を表示
    Memo1.Lines.Add(RetValue.GetObjectText_(0));
  end;

  Memo1.Lines.EndUpdate;
end;

end.

  //-------------------------------------------------------------------------
  //  以下がIPアドレスの設定コード
  //  配列型の引数を持つメソッドの実行例
  //  引数の名前と型はMSDNオンラインの該当メソッドの記事等で確認する
  //  OleVariant型で処理する場合
  //-------------------------------------------------------------------------

  //順番に取り出す
  while objPropSetEnum.Next(1, objTemp, iValue) = 0 do begin

    //メソッド名からパラメータ(引数)のオブジェクトのインスタンスを取得
    //SpawnInstance_で取得する
    wmiParameters := objTemp.Methods_.Item('EnableStatic', 0).InParameters;
    wmiIPAddress  := wmiParameters.SpawnInstance_;

    //引数の値をセット
    wmiIPAddress.IPAddress  := VarArrayOf(['192.168.0.50']);
    wmiIPAddress.SubnetMask := VarArrayOf(['255.255.255.0']);

    try
      //メソッドの実行
      RetValue := objTemp.ExecMethod_('EnableStatic', wmiIPAddress);
    except
    end;

    VarClear(wmiIPAddress);
    //メソッドの実行結果を表示
    Memo1.Lines.Add(RetValue.GetObjectText_);
  end;

  //-------------------------------------------------------------------------
  //  以下がIPアドレスの設定コード
  //  配列型の引数を持つメソッドの実行例
  //  引数の名前と型はMSDNオンラインの該当メソッドの記事等で確認する
  //  OleVariant型で処理する場合
  //-------------------------------------------------------------------------

  //順番に取り出す
  while objPropSetEnum.Next(1, objTemp, iValue) = 0 do begin

    //引数の値をセット
    IPAddress  := VarArrayOf(['192.168.0.50']);
    SubnetMask := VarArrayOf(['255.255.255.0']);

    try
      //メソッドの実行
      //VCLのメソッドと同じような使用方法
      RetValue := objTemp.EnableStatic(IPAddress, SubnetMask);
    except
    end;

    VarClear(IPAddress);
    VarClear(SubnetMask);
    //メソッドの実行結果(戻り値の整数値)を表示
    Memo1.Lines.Add(VarToStr(RetValue));
  end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, WbemScripting_TLB;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
    ComputerName : String;
    UserName     : String;
    PassWord     : String;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses ComObj, ActiveX;

{$R *.dfm}

{ TForm1 }

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  //これらの文字列を空文字にすればローカルコンピュータが対象となる
  ComputerName := 'VM-WIN7-32';
  UserName     := 'XXXXX';
  PassWord     := 'XXXXX';
end;

//=============================================================================
//  ネットワーク上のDHCPを有効(IPアドレスを自動的に取得する)にする
//  ここでは、クエリーのwhere句で特定のコンピュータだけを指定している
//
//  usesにComObj,ActiveX,WbemScripting_TLBが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);

  //---------------------------------------------------------------------------
  //  コンピュータ名を取得する関数
  //---------------------------------------------------------------------------
  function GetSelfComputerName: String;
  var
    Buff  : array [0..MAX_COMPUTERNAME_LENGTH-1] of Char;
    ASize : Cardinal;
  begin
    ASize := SizeOf(buff);
    if Windows.GetComputerName(Buff, ASize) then begin
      Result := String(Buff);
    end else begin
      Result := '';
    end;

  end;
  //---------------------------------------------------------------------------

var
  objWMILocator  : ISWbemLocator;
  objWMIService  : ISWbemServices;
  objPropSet     : ISWbemObjectSet;
  objPropSetEnum : IEnumVariant;
  objTemp        : OleVariant;
  iValue         : LongWord;
  wmiObject      : ISWbemObject;
  RetValue       : ISWbemObject;
begin
  Memo1.Lines.Clear;
  Memo1.Lines.BeginUpdate;

  //Wbemのオブジェクトを生成
  objWMILocator := CoSWbemLocator.Create;

  //WMIサービスに接続。引数は必要に応じて設定
  objWMIService := objWMILocator.ConnectServer(
                     ComputerName,
                     'root\cimv2',
                     UserName,
                     Password,
                     '',
                     '',
                     0,
                     nil);

  //クエリーを実行して、プロパティのセットのオブジェクトを取得
  if Trim(ComputerName) = '' then ComputerName := GetSelfComputerName;
  objPropSet := objWMIService.ExecQuery(
                     'SELECT * FROM Win32_NetworkAdapterConfiguration '
                     + 'where DNSHostName = "' + ComputerName + '"',
                     'WQL',
                     wbemFlagReturnImmediately,
                     nil);

  //プロパティのセットのコレクションを取得
  objPropSetEnum := objPropSet._NewEnum as IEnumVariant;

  //-------------------------------------------------------------------------
  //  以下がメソッドの実行コード
  //-------------------------------------------------------------------------

  //順番に取り出す
  while objPropSetEnum.Next(1, objTemp, iValue) = 0 do begin
    wmiObject := IUnknown(objTemp) as ISWbemObject;
    try
      RetValue := wmiObject.ExecMethod_('EnableDHCP', nil, 0, nil);
    except
    end;
    //メソッドの実行結果を表示
    Memo1.Lines.Add(RetValue.GetObjectText_(0));
  end;

  Memo1.Lines.EndUpdate;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, ComCtrls, Buttons, StdCtrls, ImgList;

type
  TForm1 = class(TForm)
    StatusBar1: TStatusBar;
    pnlTop: TPanel;
    pnlBody: TPanel;
    Panel4: TPanel;
    TreeView1: TTreeView;
    btnEnum: TSpeedButton;
    ImageList1: TImageList;
    Memo1: TMemo;
    Splitter1: TSplitter;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure btnEnumClick(Sender: TObject);
    procedure TreeView1Click(Sender: TObject);
  private
    { Private 宣言 }
    sltNetEnum  : TStringList;  {各リソースのコメント退避用}
    function EnumerateFunc(lpnr: PNetResource; Node: TTreeNode): Boolean;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

//=============================================================================
//  初期処理
//  コメント用のリストsltNetEnum(TStringList)を作成
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  sltNetEnum := TStringList.Create;
  Memo1.Lines.Clear;
end;

//=============================================================================
//  終了処理
//=============================================================================
procedure TForm1.FormDestroy(Sender: TObject);
begin
  if (Assigned(sltNetEnum)) then sltNetEnum.Free;
end;

//=============================================================================
//  列挙開始
//=============================================================================
procedure TForm1.btnEnumClick(Sender: TObject);
begin
  Screen.Cursor := crHourGlass;

  sltNetEnum.Clear;
  sltNetEnum.BeginUpdate;

  TreeView1.Items.Clear;
  TreeView1.Items.BeginUpdate;

  //列挙関数の呼び出し
  EnumerateFunc(nil, nil);

  TreeView1.Items.EndUpdate;
  sltNetEnum.EndUpdate;
  Statusbar1.Panels[0].Text := '';

  Screen.Cursor :=  crDefault;
end;

//=============================================================================
//  ノードを選択したらコメント表示を表示
//=============================================================================
procedure TForm1.TreeView1Click(Sender: TObject);
var
  SelNode : TTreeNode;
begin
  SelNode := TreeView1.Selected;
  if (SelNode <> nil) then begin
    Memo1.Text := sltNetEnum[SelNode.AbsoluteIndex];
  end;
end;

//-----------------------------------------------------------------------------
//  ネットワーク列挙関数
//
//  オリジナルからの変更点
//  (1) WNetEnumResourceの第2引数をDWORDでキャスト
//  (2) 配列を静的配列に変更
//  (3) RESOURCETYPE_ANYをRESOURCETYPE_DISKに変更
//  (4) TImageListのビットマップをWindows XP用に変更
//  (5) 変数のBufSizeをBuffSizeに変更
//  (6) 関数の最後の列挙ハンドルを閉じる時の処理にResult := True, Falseを追加
//-----------------------------------------------------------------------------
function TForm1.EnumerateFunc(lpnr: PNetResource; Node: TTreeNode): Boolean;
const
  lpBuffLen = 16384;
var
  lpBuffer     : array [0..lpBuffLen div SizeOf(TNetResource)] of TNetResource;
  hEnum        : THandle;
  dwResult     : DWORD;
  cEntries     : Integer;
  BuffSize     : DWORD;
  ix           : Integer;
  NewNode      : TTreeNode;
  strName      : String;
  strName1     : String;
  strName2     : String;
  ContinueFlag : Cardinal;
begin
  //ネットワークリソースの列挙開始
  dwResult := WNetOpenEnum(RESOURCE_GLOBALNET, RESOURCETYPE_DISK, 0, lpnr, hEnum);
  if dwResult <> NO_ERROR  then begin
    WNetCloseEnum(hEnum);
    Result := False;
    exit;
  end;

  //バッファの初期化
  BuffSize := lpBuffLen;
  FillChar(lpBuffer, BuffSize, #0);
  cEntries := -1;

  //リソース情報の取得
  dwResult := WNetEnumResource(hEnum, DWORD(cEntries), @lpBuffer, BuffSize);
  if dwResult <> NO_ERROR then begin
    WNetCloseEnum(hEnum);
    Result := False;
    exit;
  end;

  //取得したリソース情報の処理
  for ix := 0 to cEntries - 1 do begin

    //リソース名を取得
    strName1 := lpBuffer[ix].lpLocalName;
    strName2 := lpBuffer[ix].lpRemoteName;
    strName  := strName1 + strName2;
    //共有ドライブの場合は最後の￥以降の文字列だけとする
    if (Node <> nil) then begin
      if (Node.Level = 2) then begin
        strName :=  ExtractFileName(strName);
      end;
    end;

    //コメントはslNetEnum(StringList)へ格納
    sltNetEnum.Add(lpBuffer[ix].lpComment);

    //ツリーへ追加
    NewNode               :=  TreeView1.items.AddChild(Node,strName);
    NewNode.ImageIndex    :=  NewNode.Level;
    NewNode.SelectedIndex :=  NewNode.Level;

    //ステータスバーにメッセージ
    StatusBar1.Panels[0].Text :=  strName + '....';
    Refresh;

    //さらに下の階層がある場合は再帰的にこの関数を呼び出して処理
    ContinueFlag := lpBuffer[ix].dwUsage and RESOURCEUSAGE_CONTAINER;
    if ContinueFlag = RESOURCEUSAGE_CONTAINER then begin
      EnumerateFunc(@lpBuffer[ix], NewNode);
    end;
  end;

  //列挙ハンドルを閉じる
  dwResult := WNetCloseEnum(hEnum);
  if dwResult <> NO_ERROR then begin
    Result := False;
  end else begin
    Result := True;
  end;
end;

end.