//以下のコードは、ueseにMathが必要
  //TFPUExceptionMaskはMathで定義されている
  //したがって、TFPUExceptionMaskを使用する前のuses部にMathが必要

  var
    SaveFPUMask : TFPUExceptionMask;


  //現在の設定を退避
  SaveFPUMask := Math.GetExceptionMask;

  //全ての浮動小数点演算の例外を無視する
  Math.SetExceptionMask([exInvalidOp,
                         exDenormalized,
                         exZeroDivide,
                         exOverflow,
                         exUnderflow,
                         exPrecision]);

  //各種処理コード

  //元の設定に戻す
  Math.SetExceptionMask(SaveFPUMask);

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, OleCtrls, SHDocVw_EWB, EwbCore, EmbeddedWB, Menus,
  AppEvnts;

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    EmbeddedWB1: TEmbeddedWB;
    PopupMenu1: TPopupMenu;
    ApplicationEvents1: TApplicationEvents;
    N1: TMenuItem;
    N2: TMenuItem;
    N3: TMenuItem;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure ApplicationEvents1Message(var Msg: tagMSG; var Handled: Boolean);
    procedure PopupMenu1Popup(Sender: TObject);
    procedure N1Click(Sender: TObject);
    procedure N2Click(Sender: TObject);
    procedure N3Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  TEmbeddedWBを使用してURLを表示
//  TEmbeddedWBはIEオブジェクト関係のメソッドやプロパティをTEmbeddesWBのメソッ
//  ドやプロパティとして実装している他、追加のプロパティ、メソッド、イベントを
//  多く実装している
//
//  UsetInterfaceOptions.DontUse3DBordersをTrue
//  UsetInterfaceOptions.EnableThemesをTrue
//  UsetInterfaceOptions.DisableThemesをFalse
//
//  [注意]
//  TEmbeddedWBでMSHtMLの機能を使用する場合は、MSHTML_EWBを利用する(usesに追加)
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  AURL : String;
begin
  //指定のURLを表示(ここではローカルなHTMLファイル)
  AURL := ExtractFilePath(ParamStr(0)) + 'Delphi_Oracle.htm';
  EmbeddedWB1.Navigate(AURL);

  //表示完了まで待つ
  EmbeddedWB1.Wait;

  //IEのハンドル値とサイトページのTitleを表示
  //ローカルのHTMLの場合にはLocationNameはファイル名となる
  Self.Caption := IntToStr(EmbeddedWB1.HWND) + '  ' + EmbeddedWB1.LocationName;

  //以下のようにするとタイトルとなる
  //Self.Caption := EmbeddedWB1.Doc2.title;

  //デザインモードにする方法
  //EmbeddedWB1.Doc2.designMode := 'On';
end;

//=============================================================================
//  文字列の検索
//
//  SearchTextメソッドはフレームには未対応
//  (利用するにはフレームのDocumentを指定してEwbToolsの同名関数を使用する)
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  EmbeddedWB1.SearchAndHighlight('DELPHI', [], 'red', 'yellow', sivFirstMatch);
end;

//=============================================================================
//  IEドキュメントの操作例
//  HTMLの全ソースや本文のテキスト部分の取得
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
begin

  if not Assigned(EmbeddedWB1.Document) then exit;

  //HTMLコードを取得
  ShowMessage(EmbeddedWB1.DocumentSource);
  //本文のテキスト部分のみ取得(タグではない<>や半角もそのまま取得できる)
  ShowMessage(EmbeddedWB1.Doc2.body.innerText);
end;

//=============================================================================
//  Googleサーチ
//=============================================================================
procedure TForm1.Button4Click(Sender: TObject);
begin
  EmbeddedWB1.GoSearchInGoogle('Delphi');
end;

//=============================================================================
//  コンテキストメニューは表示しないで、自前のボップアップメニューを表示
//=============================================================================
procedure TForm1.ApplicationEvents1Message(var Msg: tagMSG;
  var Handled: Boolean);
var
  APos : TPoint;
begin
  if (Msg.Message = WM_RBUTTONDOWN) or (Msg.Message = WM_RBUTTONDBLCLK) then
  begin
    if IsChild(EmbeddedWB1.Handle, Msg.hwnd) then
    begin
      GetCursorPos(APos);
      PopupMenu1.Popup(APos.X, APos.Y);
      Handled := True;
    end;
  end;
end;

//=============================================================================
//  ボップアップメニューを表示する時はメニュー項目の使用可否を設定
//  N2は[コピー]
//  N3は[切り取り]
//  実用的なアプリではTActionList等の使用が望ましい
//=============================================================================
procedure TForm1.PopupMenu1Popup(Sender: TObject);
var
  Str : String;
begin
  Str := EmbeddedWB1.GetSelectedText();

  N2.Enabled := Str <> '';
  N3.Enabled := Str <> '';
end;

//=============================================================================
//  ボップアップメニューの[全て選択]
//=============================================================================
procedure TForm1.N1Click(Sender: TObject);
begin
  EmbeddedWB1.SelectAll;
end;

//=============================================================================
//  ボップアップメニューの[コピー]
//  本サンプルではテキストだけ対照にしているが、画像も選択すればコピーが可能
//=============================================================================
procedure TForm1.N2Click(Sender: TObject);
begin
  EmbeddedWB1.Copy;
end;

//=============================================================================
//  ボップアップメニューの[切り取り]
//=============================================================================
procedure TForm1.N3Click(Sender: TObject);
begin
  EmbeddedWB1.Cut;
end;

end.

implementation

uses MSHTML_EWB, HTTPApp;

{$R *.dfm}

//=============================================================================
//  TEmbeddedWBを使用してURLを表示
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  AURL : String;
begin
  //指定のURLを表示(ここではローカルなHTMLファイル)
  AURL := ExtractFilePath(Application.ExeName) + 'Image.htm';
  EmbeddedWB1.Navigate(AURL);
end;

//=============================================================================
//  EmbeddedWB1のOnClickイベント
//
//  マウス位置のタグを調査して、画像のタグ(IMG)だったら、そのパス名を取得
//  IHTMLElementの使用には、usesにMSHTML_EWBが必要
//  UnixPathToDosPathの使用には、usesにHTTPAppが必要
//=============================================================================
procedure TForm1.EmbeddedWB1Click(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
var
  iElement : IHTMLElement;
  Path     : String;
  AITem    : TMenuItem;
  APos     : TPoint;
  StrText  : String;
begin
  if Button = mbRight then begin

    //マウス位置のIHTMLElementを取得
    //そのタグがIMGだったら画像のsrc属性の値を取得
    iElement := EmbeddedWB1.Doc2.elementFromPoint(X, Y);
    if iElement.tagName = 'IMG' then begin
      Path := UnixPathToDosPath(iElement.getAttribute('src', 0));

      //ポップアップメニューの項目に画像の名前を追加
      AITem := TMenuItem.Create(Self);
      AITem.Caption := '画像名 ' + ExtractFileName(Path);
      PopupMenu1.Items.Add(AITem);
    end;


    //テキストが選択されていない時は、コピーと切り取りの機能は使用不可とする
    StrText := EmbeddedWB1.GetSelectedText();
    N2.Enabled := StrText <> '';
    N3.Enabled := StrText <> '';

    //ポップアップメニューを表示
    GetCursorPos(APos);
    PopupMenu1.Popup(APos.X, APos.Y);
  end;

  if Assigned(AITem) then FreeAndNil(AITem);
end;

//=============================================================================
//  ボップアップメニューの[全て選択]
//=============================================================================
procedure TForm1.N1Click(Sender: TObject);
begin
  EmbeddedWB1.SelectAll;
end;

//=============================================================================
//  ボップアップメニューの[コピー]
//  本サンプルではテキストだけ対照にしているが、画像も選択すればコピーが可能
//=============================================================================
procedure TForm1.N2Click(Sender: TObject);
begin
  EmbeddedWB1.Copy;
end;

//=============================================================================
//  ボップアップメニューの[切り取り]
//=============================================================================
procedure TForm1.N3Click(Sender: TObject);
begin
  EmbeddedWB1.Cut;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, OleCtrls, SHDocVw_EWB, EwbCore, EmbeddedWB;

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    Button1: TButton;
    Button2: TButton;
    EmbeddedWB1: TEmbeddedWB;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure EmbeddedWB1ShowDialog(Sender: TObject; h: Cardinal;
      StyleEx: Integer; OldCaption: string; var NewCaption: WideString;
      var Cancel: Boolean);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses IEConst;

{$R *.dfm}

//=============================================================================
//  [Webページ表示]ボタン
//  URLを表示
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  AURL : String;
begin
  //指定のURLを表示
  AURL := 'http://www.embarcadero.com/jp/';
  EmbeddedWB1.Navigate(AURL);
end;

//=============================================================================
//  [お気に入りの追加]ダイアログをモーダル表示
//
//  http://www.bsalsa.com/ewb_methods1.html
//  の定数値の一覧を参照
//  この定数値の使用には、usesにIEConstが必要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  IEHandle : HWND;
begin
  //ページを表示しているウィンドウハンドルを取得
  IEHandle := EmbeddedWB1.GetIEHandle(EmbeddedWB1, 'Internet Explorer_Server');
  //お気に入りに追加のダイアログをモーダル表示
  SendMessage(IEHandle, WM_COMMAND, ID_IE_CONTEXTMENU_ADDFAV, 0);
end;

//=============================================================================
//  OnShowDialogイベント処理
//  http://www.bsalsa.com/ewb_on_show_dlg.html参照
//=============================================================================
procedure TForm1.EmbeddedWB1ShowDialog(Sender: TObject; h: Cardinal;
  StyleEx: Integer; OldCaption: string; var NewCaption: WideString;
  var Cancel: Boolean);
begin
  //ダイアログの表示位置を変更
  SetWindowPos(h, 0, Self.Left, Self.Top + 50, 0, 0, SWP_NOSIZE or SWP_NOZORDER);
end;

end.

//=============================================================================
//  任意の場所にインターネットのショートカットを作成
//
//  aFileName : 保存先のフルパス
//              例: [お気に入り]フォルダのパス名 + 表示名.url
//  aURL      : 登録するURL
//=============================================================================
procedure CreateIntShotCut(aFileName, aURL: PChar);
var
  SL : TStringList;
begin
  SL := TStringList.Create;
  try
    SL.Add('[InternetShortcut]');
    SL.Add('URL=' + aURL);
    SL.SaveToFile(aFileName);
  finally
    FreeAndNil(SL);
  end;
end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, OleCtrls, SHDocVw_EWB, EwbCore, EmbeddedWB;

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    Button1: TButton;
    EmbeddedWB1: TEmbeddedWB;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses MSHTML_EWB;

{$R *.dfm}

//=============================================================================
//  フォーム作成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  AURL : String;
begin
  AURL := ExtractFilePath(ParamStr(0)) + 'TestPage.html';
  EmbeddedWB1.Navigate(AURL);
end;

//=============================================================================
//  HTMLコード内の指定位置にHTMLコードを挿入
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  SL          : TStringList;
  iElementCol : IHTMLElementCollection;
  iElement    : IHTMLElement;
begin
  if EmbeddedWB1.Doc3.getElementById('id-link') = nil then begin
    SL := TStringList.Create;
    try
      SL.Add('<a href="http://mrxray.on.coocan.jp/" target="_top" id="id-link">');
      SL.Add('リンク先へジャンプ</a>');
      iElementCol := EmbeddedWB1.Doc3.getElementsByTagName('body');
      iElement    := iElementCol.item(0, 0) as IHTMLElement;
      iElement.insertAdjacentHTML('BeforeEnd', SL.text);
    finally
      FreeAndNil(SL);
    end;
  end;
end;

end.

var
  Doc2 : IHTMLDocument2;
  Doc3 : IHTMLDocument3;
begin
  Doc2 := WebBrowser1.Document as IHTMLDocument2;
  Doc3 := WebBrowser1.Document as IHTMLDocument3;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, OleCtrls, SHDocVw_EWB, EwbCore, EmbeddedWB;

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    EmbeddedWB1: TEmbeddedWB;
    Edit1: TEdit;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム作成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  URL : String;
begin
  URL := 'http://mrxray.on.coocan.jp/Delphi/Others/';
  Edit1.Text := URL;
  Button1Click(nil);
end;

//=============================================================================
//  他のページで動作確認できるように...
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  EmbeddedWB1.Navigate(Trim(Edit1.Text));
end;

//=============================================================================
//  [ページ設定]
//  PageSetupメソッド
//  PrintOptions.EnabledをTrueにしてPageSetupの引数をTrueにして実行すれば
//  オプションの値がダイアログに反映される
//  IE8以降ではヘッダとフッタの設定は無効となる
//  これは、IE7形式のページ設定ダイアログの遠隔操作をしているため
//
//  PageSetupダイアログで表示される用紙の[サイズ]と[給紙方法]は、プリンタによ
//  って異なるので、遠隔操作の場合は注意が必要
//  IE6,7とそれ以降では設定項目と設定方法が違うので、これも注意
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  EmbeddedWB1.PrintOptions.Enabled        := True;
  EmbeddedWB1.PrintOptions.Margins.Left   := 28;
  EmbeddedWB1.PrintOptions.Margins.Top    := 25;
  EmbeddedWB1.PrintOptions.Margins.Right  := 20;
  EmbeddedWB1.PrintOptions.Margins.Bottom := 25;
  EmbeddedWB1.PrintOptions.Orientation    := TPrintOrientationOption.poPortrait;
  EmbeddedWB1.PrintOptions.Header         := '&ヘッダ文字列&b&p/&P ページ&';
  EmbeddedWB1.PrintOptions.Footer         := 'フッタ文字列';

  EmbeddedWB1.PageSetup(True);
end;

//=============================================================================
//  [プレビュー]
//  PrintPreviewメソッド
//  PrintOptionsの値は、あらかじめPageSetupで設定した値が使用される
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
begin
  EmbeddedWB1.PrintPreview;
end;

//=============================================================================
//  [印刷]
//  Printメソッド
//  PrintOptions.EnabledをFalseにすればHeaderとFooterの値だけが有効となる
//  (IE8でも有効)
//  他のPrintOptionsの値はTrueにしてもFalseにしても無効で、PageSetupメソッドで
//  設定した値が使用される
//=============================================================================
procedure TForm1.Button4Click(Sender: TObject);
begin
  EmbeddedWB1.PrintOptions.Enabled := False;
  EmbeddedWB1.PrintOptions.Header  := '&印刷メソッドヘッダ&b&p/&P ページ&';
  EmbeddedWB1.PrintOptions.Footer  := '印刷メソッドフッタ';

  //HideSetupをTrueにすると、プリンタの選択ダイアログを表示しない
  EmbeddedWB1.PrintOptions.HideSetup := True;

  EmbeddedWB1.Print;
end;

end.

//=============================================================================
//  レジストリからIEの印刷のヘッダや余白の設定を読み出す例
//  usesにRegistryが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  Reg          : TRegistry;
  AppKey       : String;
  AppItem      : String;
  StrHeader    : String;
  MarginLeftmm : Double;
begin
  Reg := TRegistry.Create;
  try
    Reg.Access  := KEY_READ;
    Reg.RootKey := HKEY_CURRENT_USER;
    AppKey      := 'Software\Microsoft\Internet Explorer\PageSetup';

    if Reg.OpenKey(AppKey, False) then begin
      try
        //ヘッダ文字列の読み出し
        AppItem   := 'header';
        StrHeader := Reg.ReadString(AppItem);
        Memo1.Lines.Add(StrHeader);

        //左マージンを読み出してmm単位に換算
        AppItem      := 'margin_left';
        MarginLeftmm := StrToCurr(Reg.ReadString(AppItem)) * 25.4;
        Memo1.Lines.Add(FormatFloat('#.#', MarginLeftmm));
      finally
        Reg.CloseKey;
      end;
    end;
  finally
    Reg.Free;
  end;
end;

//=============================================================================
//  レジストリにIEの印刷のヘッダや余白の設定を書き込む例
//  usesにRegistryが必要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  Reg            : TRegistry;
  AppKey         : String;
  AppItem        : String;
  StrHeader      : String;
  MarginLeftInch : Double;
  StrMagin       : String;
begin
  Reg := TRegistry.Create;
  try
    Reg.Access  := KEY_WRITE;
    Reg.RootKey := HKEY_CURRENT_USER;
    AppKey      := 'Software\Microsoft\Internet Explorer\PageSetup';

    if Reg.OpenKey(AppKey, False) then begin
      try
        //ヘッダ文字列の書き込み
        AppItem   := 'header';
        StrHeader := '&左のヘッダ文字列&b&p/&P ページ';
        Reg.WriteString(AppItem, StrHeader);

        //左余白の値の書き込み
        //インチ単位の値を文字列に変換して書き込む
        AppItem        := 'margin_left';
        MarginLeftInch := 22.0 / 25.4;
        StrMagin       := FormatFloat('#0.00000', MarginLeftInch);
        Reg.WriteString(AppItem, StrMagin);
      finally
        Reg.CloseKey;
      end;
    end;
  finally
    Reg.Free;
  end;
end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, OleCtrls, SHDocVw_EWB, EwbCore, EmbeddedWB;

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    Button1: TButton;
    EmbeddedWB1: TEmbeddedWB;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses MSHTML_EWB;

{$R *.dfm}

//=============================================================================
//  フォーム作成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  AURL : String;
begin
  AURL := 'http://mrxray.on.coocan.jp/Delphi/Others/';
  EmbeddedWB1.Navigate(AURL);
end;

//=============================================================================
//  DelphiからScriptXを使用するコードの例
//  XXXXXの部分をsmsx.capが置いてあるサーバ上のディレクトリにし、Versionも使用
//  するsmsx.capのバージョン番号と同じにする
//  IDE上での実行の場合、コンパイルのたびにプロジェクトの[再構築]が必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  SL          : TStringList;
  iElementCol : IHTMLElementCollection;
  iElement    : IHTMLElement;
begin

  SL := TStringList.Create;
  try
    if EmbeddedWB1.Doc3.getElementById('factory') = nil then begin
      //ScriptXのオブジェクト生成用のタグコード
      //idの名前は任意だが、プリンタの設定の時のオブジェクト名となる
      SL.Add('<object id=factory style="display:none"');
      SL.Add('classid="clsid:1663ed61-23eb-11d2-b92f-008048fdd814"');
      SL.Add('codebase="http://XXXXX/smsx.cab#Version=7,0,0,8">');
      SL.Add('</object>');

      //HTMLの最初の<BODY>タグの要素オブジェクトを取得
      iElementCol := EmbeddedWB1.Doc3.getElementsByTagName('body');
      iElement    := iElementCol.item(0, 0) as IHTMLElement;

      //そこの先頭部分にコードを挿入
      iElement.insertAdjacentHTML('AfterBegin', SL.text);
    end;

    SL.Clear;
    //ScriptXによるプリンタの設定用JavaScriptコードを作成
    //印刷余白は、日本の場合、デフォルトではmm単位であることに注意
    //Free版で使用できない設定コードがあると印刷もプレビューもしない
    SL.Add('factory.printing.header       = "ヘッダ文字列";');
    SL.Add('factory.printing.footer       = "フッタ文字列";');
    SL.Add('factory.printing.leftMargin   = 30;');
    SL.Add('factory.printing.topMargin    = 25;');
    SL.Add('factory.printing.rightMargin  = 20;');
    SL.Add('factory.printing.bottomMargin = 40;');
    SL.Add('factory.printing.portrait     = true;');
    SL.Add('factory.printing.Preview();');

    //それを実行
    EmbeddedWB1.ExecScript(SL.text, 'JavaScript');
  finally
    FreeAndNil(SL);
  end;
end;

end.

procedure TForm1.Button2Click(Sender: TObject);
var
  SL          : TStringList;
  iElementCol : IHTMLElementCollection;
  iElement    : IHTMLElement;
  iObjElement : IHTMLObjectElement;
  ObjScriptX  : OleVariant;
begin
  if not Assigned(EmbeddedWB1.Document) then exit;

  if EmbeddedWB1.Doc3.getElementById('factory') = nil then begin
    SL := TStringList.Create;
    try
      //ScriptXのオブジェクト生成用のタグコード
      //idの名前は任意だが、プリンタの設定の時のオブジェクト名となる
      SL.Add('<object id=factory style="display:none"');
      SL.Add('classid="clsid:1663ed61-23eb-11d2-b92f-008048fdd814"');
      SL.Add('codebase="http://www.meadroid.com/scriptx/smsx.cab#Version=7,0,0,8">');
      SL.Add('</object>');

      //HTMLの最初の<BODY>タグの要素オブジェクトを取得
      iElementCol := EmbeddedWB1.Doc3.getElementsByTagName('body');
      iElement    := iElementCol.item(0, 0) as IHTMLElement;

      //そこの先頭部分にコードを挿入
      iElement.insertAdjacentHTML('AfterBegin', SL.text);
    finally
      FreeAndNil(SL);
    end;
  end;

  iElement    := EmbeddedWB1.Doc3.getElementById('factory');
  iObjElement := iElement as IHTMLObjectElement;

  if iObjElement <> nil then begin
    ObjScriptX := OleVariant(iObjElement.object_);

    ObjScriptX.printing.header       := 'ヘッダ文字列';
    ObjScriptX.printing.footer       := 'フッタ文字列';
    ObjScriptX.printing.portrait     := false;
    ObjScriptX.printing.leftMargin   := 25;
    ObjScriptX.printing.topMargin    := 23;
    ObjScriptX.printing.rightMargin  := 20;
    ObjScriptX.printing.bottomMargin := 25;
    ObjScriptX.printing.Preview;
  end;
end;