implementation

uses
  DateUtils;

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Panel1.Caption := '0';
end;

//=============================================================================
//  TDateTime型の値をUnix時間に変換
//  TTimeZoneInformationを使用するコード
//
//  Delphi 6 以降で使用可能なコード
//  DateTimeToUnixの使用には,usesにDateUtilsが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LDateTime     : TDateTime;
  LUnixTime     : Int64;
  LTimeZoneInfo : TTimeZoneInformation;
begin
  Panel2.Caption := '';
  LDateTime := StrToDateTime('2016/01/03 08:09:10');

  GetTimeZoneInformation(LTimeZoneInfo);
  //TTimeZoneInformation.Biasの値を秒数にして加算
  //協定世界時と日本標準時との差は-9時間なのでLTimeZoneInfo.Biasの値は-540
  LUnixTime := DateTimeToUnix(LDateTime) + LTimeZoneInfo.Bias * 60;
  Panel1.Caption := Format('%d', [LUnixTime]);
end;

//=============================================================================
//  Unix時間をTDateTime型の値に変換
//  TTimeZoneInformationを使用するコード
//
//  Delphi 6 以降で使用可能なコード
//  UnixToDateTimeの使用には,usesにDateUtilsが必要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LDateTime     : TDateTime;
  LUnixTime     : Int64;
  LTimeZoneInfo : TTimeZoneInformation;
begin
  GetTimeZoneInformation(LTimeZoneInfo);
  //TTimeZoneInformation.Biasの値を秒数にして減算
  //協定世界時と日本標準時との差は-9時間なのでLTimeZoneInfo.Biasの値は-540
  LUnixTime := StrToInt64(Panel1.Caption) - LTimeZoneInfo.Bias * 60;

  LDateTime := UnixToDateTime(LUnixTime);
  Panel2.Caption := DateTimeToStr(LDateTime);
end;

implementation

uses
  DateUtils;

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Panel1.Caption := '0';
end;

//=============================================================================
//  TDateTime型の値をUnix時間に変換
//  TTimeZoneを使用するコード
//
//  Delphi XE 以降で使用可能なコード
//  DateTimeToUnix,TTimeZoneの使用には,usesにDateUtilsが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LDateTime : TDateTime;
  LUnixTime : Int64;
begin
  Panel2.Caption := '';
  LDateTime := StrToDateTime('2016/01/03 08:09:10');

  //ローカルな日時を協定世界時に変換してからUnix時間に変換
  LUnixTime := DateTimeToUnix(TTimeZone.Local.ToUniversalTime(LDateTime));
  Panel1.Caption := Format('%d', [LUnixTime]);
end;

//=============================================================================
//  Unix時間をTDateTime型の値に変換
//  TTimeZoneを使用するコード
//
//  Delphi XE 以降で使用可能なコード
//  UnixToDateTime,TTimeZoneの使用には,usesにDateUtilsが必要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LDateTime : TDateTime;
  LUnixTime : Int64;
begin
  LUnixTime := StrToInt64(Panel1.Caption);

  //Unix時間をTDateTimeの値に変換したら,ローカルな日時に換算
  LDateTime := TTimeZone.Local.ToLocalTime(UnixToDateTime(LUnixTime));
  Panel2.Caption := DateTimeToStr(LDateTime);
end;

implementation

uses
  DateUtils;

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Panel1.Caption := '0';
end;

//=============================================================================
//  TDateTime型の値をUnix時間に変換
//  DateTimeToUnixの引数で、TDateTime型の値をUTCと解釈するかを指定できる
//
//  Delphi XE6以降専用
//  Delphi XE5以前のDateTimeToUnixには,第2引数はない
//  DateTimeToUnixの使用には,usesにDateUtilsが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LDateTime : TDateTime;
begin
  Panel2.Caption := '';
  LDateTime := StrToDateTime('2016/01/03 08:09:10');

  Panel1.Caption := DateTimeToUnix(LDateTime, False).ToString;
end;

//=============================================================================
//  Unix時間をTDateTime型の値に変換
//  UnixToDateTime(LUnixTimeの引数で、UTCで取得するかを指定できる
//
//  Delphi XE5以前のUnixToDateTimeには,第2引数はない
//  UnixToDateTimeの使用には,usesにDateUtilsが必要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LDateTime : TDateTime;
  LUnixTime : Int64;
begin
  LUnixTime := StrToInt64(Panel1.Caption);

  LDateTime := UnixToDateTime(LUnixTime, False);
  Panel2.Caption := DateTimeToStr(LDateTime);
end;

//=============================================================================
//  フォーム表示開始時の処理
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  plDateEdit1.DisplayError := False;
  plDateEdit1.DateTime := Now;
end;

//=============================================================================
//  和暦の 1 年を元年で表示
//  1 月 1 日を元日で表示
//
//  「元年」の表記理由で言えば、年の最初の日である 1 月 1 日は「元日」である
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LYear     : string;
  LMonthDay : string;
begin
  Memo1.Lines.Clear;

  if plDateEdit1.GengoYear = 1 then begin
    LYear := plDateEdit1.GengoStr + ' 元年';
  end else begin
    LYear := plDateEdit1.GengoStr + ' ' + plDateEdit1.GengoYearStr + ' 年';
  end;

  if (plDateEdit1.Month = 1) and (plDateEdit1.Day = 1) then begin
    LMonthDay := '元日'
  end else begin
    LMonthDay := plDateEdit1.MonthStr + ' 月 ' + plDateEdit1.DayStr + ' 日';
  end;

  Memo1.Lines.Add(LYear + ' ' + LMonthDay);
end;

//=============================================================================
//  TplDateEdit の OnChange イベント
//=============================================================================
procedure TForm1.plDateEdit1Change(Sender: TObject);
begin
  try
    Button1Click(nil);
  except
  end;
end;