unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Image1: TImage;
    procedure FormCreate(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//  起動パラメータ(起動オプション・引数)が1つの場合の例
//
//  2番目のパラメータの値はParamStr(2)
//  3番目のパラメータの値はParamStr(3)
//  n番目のパラメータの値はParamStr(n)
//  のように受け取る
//  該当するパラメータが存在しない場合は、取得結果は空白文字列となる
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  StrText : String;
  WIC     : TWICImage;
begin
  Image1.Left := 0;
  Image1.Top  := 0;
  Image1.AutoSize    := True;
  Image1.Transparent := True;

  //起動時の引数が1つの時だけ、その値を取得して処理
  if ParamCount = 1 then begin
    //1番名のパラメータ(引数)の値を取得(パラメータは文字列で受け取る)
    StrText := ParamStr(1);

    WIC := TWICImage.Create;
    try
      WIC.LoadFromFile(StrText);
      Image1.Picture.Assign(WIC);
    finally
      WIC.Free;
    end;
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, AppEvnts;

type
  TForm1 = class(TForm)
    Image1: TImage;
    ApplicationEvents1: TApplicationEvents;
    procedure FormCreate(Sender: TObject);
    procedure ApplicationEvents1Message(var Msg: tagMSG; var Handled: Boolean);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  ShellAPI;

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//  DragAcceptFilesの使用にはusesにShellAPIが必要
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  //ドラッグアンドドロップを許可
  //対象コントロールはSelf(このフォーム)
  DragAcceptFiles(Self.Handle, True);
end;

//=============================================================================
//  TApplicationEventsのOnMessageイベント処理
//  エクスプローラからのファイルのドラッグ・ドロップ処理
//=============================================================================
procedure TForm1.ApplicationEvents1Message(var Msg: tagMSG;
  var Handled: Boolean);
var
  LCount    : Integer;
  LBuffer   : array [0..MAX_PATH-1] of char;
  LFilePath : string;
  WIC       : TWICImage;
begin
  if Msg.message = WM_DROPFILES then begin
    //FormのOnCreateで受入れコントロールを指定はしているが...
    //ドラッグドロップしたファイル数を取得
    LCount := DragQueryFile(Msg.wParam, High(Cardinal), nil, 0);
    if LCount = 1 then begin
      //ドラッグドロップしたファイル名を取得
      DragQueryFile(Msg.WParam, 0, LBuffer, MAX_PATH);
      LFilePath := LBuffer;

      //ドロップが完了したことを伝える
      DragFinish(msg.wParam);

      //ディスクから画像ファイルを読み込んで表示する
      WIC := TWICImage.Create;
      try
        WIC.LoadFromFile(LFilePath);
        Image1.AutoSize := True;
        Image1.Picture.Assign(WIC);
      finally
        WIC.Free;
      end;
    end;
  end;
end;

end.

  if Msg.message = WM_DROPFILES then begin
    if FindDragTarget(Msg.pt, False) <> Image1 then exit;