//ダブルクォーテーションで括らないパス名
  //C:\Program を 1 つの文字列として解釈される場合がある
  C:\Program Files (x86)\Microsoft Office\Office14\EXCEL.EXE

  //ダブルクォーテーションで括ったパス名
  //ダブルクォーテーションの中を 1 つの文字列として解釈してくれる
  "C:\Program Files (x86)\Microsoft Office\Office14\EXCEL.EXE"

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  ShellAPI;

{$R *.dfm}

//=============================================================================
//  ShellExecute関数でエクセルのブックを開く
//  第3引数に開くファイルを指定する場合
//  第3引数は1つの文字列と認識するので、二重引用符(ダブルクォーテーション " )
//  で囲まなくてもよい
//
//  ShellExecute関数は、拡張子に関連付けされたアプリを起動できる
//  ShellExecuteの使用には、usesにShellAPIが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LFilePath  : String;
  LParams    : String;
  LhInstance : Cardinal;
begin
  //起動ファイルのパス
  LFilePath := '..\App Files\テスト.xls';
  LParams := '';

  LhInstance := ShellExecute(Handle,
                             'open',
                             PChar(LFilePath),
                             PChar(LParams),
                             nil,
                             SW_SHOW);
  if LhInstance <= 32 then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

end.

procedure TForm1.Button1Click(Sender: TObject);
var
  LExePath   : String;
  LFilePath  : String;
  LhInstance : Cardinal;
begin
  //エクスプローラの実行名(実際には起動しない)
  LExePath  := 'explorer.exe';
  //表示するプログラムのEXE名またはファイル名
  LFilePath := 'Acro_Test.pdf';

  LhInstance := ShellExecute(Handle,
                             nil,
                             PChar(LExePath),
                             PChar(LFilePath),
                             nil,
                             SW_SHOW);
  if LhInstance <= 32 then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses 
  ShellAPI;

{$R *.dfm}

//=============================================================================
//  指定したアプリケーションでファイルを開く
//
//  開くファイルのパスに空白文字が含まれているので、SysUtilsのAnsiQuotedStr関
//  数を使用して、ファイル名の文字列を二重引用符(ダブルクォーテーション)で囲む
//  ただし、アプリケーションによっては不要の場合もある
//  それは、アプリケーションが、引数をどのように解釈するかによる
//
//  ShellExecuteの使用には、usesにShellAPIが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LExePath   : String;
  LParams    : String;
  LhInstance : Cardinal;
begin
  //起動プログラムのパス
  //システム環境でパスが通っているのでフルパスでなくても起動する
  LExePath := 'EXCEL.EXE';
  //起動アプリの起動時パラメータ。ここではエクセルのブックのファイル名
  //エクセルを起動するだけの場合はLParamsの値を空文字とする
  LParams := '..\App Files\テスト.xls';
  LParams := SysUtils.AnsiQuotedStr(LParams, '"');

  LhInstance := ShellExecute(Handle,
                             'open',
                             PChar(LExePath),
                             PChar(LParams),
                             nil,
                             SW_SHOW);
  if LhInstance <= 32 then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

end.

procedure TForm1.Button1Click(Sender: TObject);

  //---------------------------------------------------------------------------
  //  環境変数文字列から実際のフルパスを取得する関数
  //---------------------------------------------------------------------------
  function ExpandEnvironmentString(S: String): String;
  var
    LDestChar : array [0..MAX_PATH-1] of Char;
  begin
    ExpandEnvironmentStrings(PChar(S), LDestChar, MAX_PATH);
    Result := LDestChar;
  end;
  //---------------------------------------------------------------------------

var
  LExePath   : String;
  LParams    : String;
  LhInstance : Cardinal;
begin
  //起動プログラムのパス
  LExePath := '%ProgramFiles%\Microsoft Office\Office12\EXCEL.EXE';
  LExePath := ExpandEnvironmentString(LExePath);
  //起動アプリの起動時パラメータ。ここではエクセルのブックのファイル名
  //エクセルを起動するだけの場合はLParamsの値を空文字とする
  LParams := '..\App Files\テスト.xls';
  LParams := SysUtils.AnsiQuotedStr(LParams, '"');

  LhInstance := ShellExecute(Handle,
                             'open',
                             PChar(LExePath),
                             PChar(LParams),
                             nil,
                             SW_SHOW);
  //起動失敗
  if LhInstance <= 32 then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  ShellAPI;

{$R *.dfm}

//=============================================================================
//  任意のアプリケーションをShellExecute関数で起動する例
//  ここでは、MyImgViewer.exeというプログラムを起動して画像を表示
//
//  ShellExecuteの使用には、usesにShellAPIが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LExePath   : String;
  LParams    : String;
  LhInstance : Cardinal;
begin
  //起動プログラムのパス
  //相対パスで指定
  LExePath := '..\App Files\MyImgViewer.exe';
  //起動時のオプションパラメータ
  //相対パスで指定
  //パス名に空白文字があるので、ダブルクォーテーションで囲む
  LParams := '..\App Files\Parrots.gif';
  LParams := SysUtils.AnsiQuotedStr(LParams, '"');

  LhInstance := ShellExecute(Handle,
                             'open',
                             PChar(LExePath),
                             PChar(LParams),
                             nil,
                             SW_SHOW);
  if LhInstance <= 32 then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  ShellAPI;

{$R *.dfm}

//=============================================================================
//  デフォルトのブラウザを起動して、指定のウェブページを表示
//  筆者の環境ではFireFox
//
//  ShellExecuteの使用には、usesにShellAPIが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LFilePath  : String;
  LParams    : String;
  LhInstance : Cardinal;
begin
  //表示するウェブページのアドレス
  LFilePath := 'http://mrxray.on.coocan.jp/index.htm';
  LParams   := '';

  LhInstance := ShellExecute(Handle,
                             'open',
                             PChar(LFilePath),
                             PChar(LParams),
                             nil,
                             SW_SHOW);
  if LhInstance <= 32 then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

//=============================================================================
//  IE(InternetExplorer)を起動して、指定のページを表示
//
//  ShellExecuteの使用には、usesにShellAPIが必要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);

  //---------------------------------------------------------------------------
  //  環境変数文字列から実際のフルパスを取得する関数
  //---------------------------------------------------------------------------
  function ExpandEnvironmentString(S: String): String;
  var
    LDestChar : array [0..MAX_PATH-1] of Char;
  begin
    ExpandEnvironmentStrings(PChar(S), LDestChar, MAX_PATH);
    Result := LDestChar;
  end;
  //---------------------------------------------------------------------------

var
  LExePath   : String;
  LParams    : String;
  LhInstance : Cardinal;
begin
  //起動アプリのパス
  LExePath := '%ProgramFiles%\Internet Explorer\iexplore.exe';
  LExePath := ExpandEnvironmentString(LExePath);

  //パラメータの設定
  //ここでは表示するウェブページ
  LParams := 'http://mrxray.on.coocan.jp/index.htm';

  LhInstance := ShellExecute(Handle,
                             'open',
                             PChar(LExePath),
                             PChar(LParams),
                             nil,
                             SW_SHOW);
  if LhInstance <= 32 then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

end.

procedure TForm1.Button2Click(Sender: TObject);

  //---------------------------------------------------------------------------
  //  環境変数文字列から実際のフルパスを取得する関数
  //---------------------------------------------------------------------------
  function ExpandEnvironmentString(S: String): String;
  var
    LDestChar : array [0..MAX_PATH-1] of Char;
  begin
    ExpandEnvironmentStrings(PChar(S), LDestChar, MAX_PATH);
    Result := LDestChar;
  end;
  //---------------------------------------------------------------------------

var
  LExePath   : String;
  LParams    : String;
  LhInstance : Cardinal;
begin
  //起動アプリのパス
  LExePath := '%ProgramFiles%\HidemaruMail\TuruKame.exe';
  LExePath := ExpandEnvironmentString(LExePath);
  //起動パラメータ(メールの新規作成)
  LParams := 'mailto:';

  LhInstance := ShellExecute(Handle,
                             'open',
                             PChar(LExePath),
                             PChar(LParams),
                             nil,
                             SW_SHOW);
  if LhInstance <= 32 then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  LCmdText   : String;
  LParams    : String;
  LhInstance : Cardinal;
begin
  LCmdText := 'mailto:';
  LParams  := '';

  LhInstance := ShellExecute(Handle,
                             'open',
                             PChar(LCmdText),
                             PChar(LParams),
                             nil,
                             SW_SHOW);
  if LhInstance <= 32 then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  ShellAPI;

{$R *.dfm}

//=============================================================================
//  システム既定のメールソフトでメールを新規作成
//  筆者の環境では、Windows Live メール Version 2009
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LCmdText   : String;
  LParams    : String;
  LhInstance : Cardinal;
  LBodyText  : String;
begin
  LBodyText := 'メール新規作成 ? と %26 と改行文字には注意' + '%0D%0A'
             + 'サンプルプログラムです';

  //開くファイルとしてのメールの各項目値
  //区切り文字は ? と &
  LCmdText := 'mailto:'   + '宛先メールアドレス'
            + '?subject=' + 'メールテスト'
            + '&bcc='     + 'BCC メールアドレス'
            + '&bcc='     + 'BCC メールアドレス'
            + '&body='    + LBodyText;
  LParams := '';

  LhInstance := ShellExecute(Handle,
                             'open',
                             PChar(LCmdText),
                             PChar(LParams),
                             nil,
                             SW_SHOW);
  if LhInstance <= 32 then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

//=============================================================================
//  筆者の使用しているメールソフトでメールの新規作成
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);

  //---------------------------------------------------------------------------
  //  環境変数文字列から実際のフルパスを取得する関数
  //---------------------------------------------------------------------------
  function ExpandEnvironmentString(S: String): String;
  var
    LDestChar : array [0..MAX_PATH-1] of Char;
  begin
    ExpandEnvironmentStrings(PChar(S), LDestChar, MAX_PATH);
    Result := LDestChar;
  end;
  //---------------------------------------------------------------------------

var
  LExePath   : String;
  LParams    : String;
  LhInstance : Cardinal;
  LBodyText  : String;
begin
  //起動アプリのパス
  LExePath := '%ProgramFiles%\HidemaruMail\TuruKame.exe';
  LExePath := ExpandEnvironmentString(LExePath);

  LBodyText := 'メール新規作成 ' + '%3F と %26 には注意' + sLineBreak
             + 'サンプルプログラムです';

  //パラメータの設定(メールの各項目値)
  //項目の区切り文字は ?
  LParams := 'mailto:'   + '宛先メールアドレス'
           + '?subject=' + 'メールテスト'
           + '?bcc='     + 'BCC メールアドレス'
           + '?bcc='     + 'BCC メールアドレス'
           + '?body='    + LBodyText;

  LhInstance := ShellExecute(Handle,
                             'open',
                             PChar(LExePath),
                             PChar(LParams),
                             nil,
                             SW_SHOW);
  if LhInstance <= 32 then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

end.

//=============================================================================
//  ShellExecute関数でファイルをダウンロード
//  ファイルの有無はチェックしていない
//
//  ShellExecuteの使用には、usesにShellAPIが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LFilePath  : String;
  LParams    : String;
  LhInstance : Cardinal;
begin
  //ダウンロードファイルの指定
  LFilePath := 'http://mrxray.on.coocan.jp/Delphi/zip/004_TimerTest.zip';
  LParams   := '';

  LhInstance := ShellExecute(Handle,
                             'open',
                             PChar(LFilePath),
                             PChar(LParams),
                             nil,
                             SW_SHOW);
  if LhInstance <= 32 then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    CheckBox1: TCheckBox;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  ShellAPI;

{$R *.dfm}

//-----------------------------------------------------------------------------
//  ShellExecuteExで指定ファイルを実行
//  ShellExcuteExの使用にはusesにShellAPIが必要
//-----------------------------------------------------------------------------
function RunExeFile(hWnd: HWND; AFile: String; AParameters: String;
   Verb: String): Cardinal;
var
  LInfo : TShellExecuteInfo;
  LRet  : Cardinal;
begin
  FillChar(LInfo, SizeOf(LInfo), 0);
  LInfo.cbSize := SizeOf(LInfo);
  LInfo.Wnd    := hWnd;

  LInfo.fMask  := SEE_MASK_FLAG_DDEWAIT
               or SEE_MASK_FLAG_NO_UI
               or SEE_MASK_NOCLOSEPROCESS;
  LInfo.lpVerb := PChar(Verb);

  LInfo.lpFile       := PChar(AFile);
  LInfo.lpParameters := PChar(AParameters);
  LInfo.nShow        := SW_SHOW;

  ShellExecuteEx(@LInfo);

  //ShellExecuteExは成功するとhInstAppに33以上の値を返す
  if LInfo.hInstApp >= 33 then begin
    //プロセスが生成されるまで待つ
    repeat
      LRet := WaitForInputIdle(LInfo.hProcess, 50);
      Application.ProcessMessages;
    until LRet <> WAIT_TIMEOUT;

    CloseHandle(LInfo.hProcess);
  end;

  Result := LInfo.hInstApp;
end;

//=============================================================================
//  ShellExecuteEx関数でテストファイルを開く
//  TShellExecuteInfo.lpFileに開くファイルを指定する場合
//  二重引用符(ダブルクォーテーション)で囲まなくてもよい
//
//  ShellExecuteEx関数は、拡張子に関連付けされたアプリを起動できる
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LFilePath  : String;
  LParams    : String;
  LhInstance : Cardinal;
begin
  //起動ファイルの相対パス
  LFilePath := '..\App Files\テスト.txt';
  //起動アプリの起動オプション
  LParams := '';

  LhInstance := RunExeFile(Handle, LFilePath, LParams, '');

  if LhInstance <= 32 then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

//=============================================================================
//  ShellExecuteEx関数でテストファイルを開く
//  TShellExecuteInfo.lpParametersは空白区切りの引数
//
//  空白文字を含むパラメータは二重引用符(ダブルクォーテーション)で囲む
//  ただし、アプリケーションによっては不要の場合もある
//  それは、アプリケーションが、引数をどのように解釈するかによる
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LExePath   : String;
  LParams    : String;
  LhInstance : Cardinal;
begin
  //起動プログラムのパス
  LExePath := 'notepad.exe';
  //起動アプリの起動オプション
  LParams := '..\App Files\テスト.txt';
  if CheckBox1.Checked then begin
    LParams := SysUtils.AnsiQuotedStr(LParams, '"');
  end;

  LhInstance := RunExeFile(Handle, LExePath, LParams, '');
  if LhInstance <= 32 then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

end.

  //ShellExecuteExは成功するとhInstAppに33以上の値を返す
  if LInfo.hInstApp >= 33 then begin
    //プロセスが生成されるまで待つ
    while WaitForInputIdle(LInfo.hProcess, 50) = WAIT_TIMEOUT do begin
      Application.ProcessMessages;
    end;

    CloseHandle(LInfo.hProcess);
  end;

    //プロセスがアイドル状態になるまで待つ
    repeat
      LRet := WaitForInputIdle(LInfo.hProcess, 50);
      Application.ProcessMessages;
    until LRet <> WAIT_TIMEOUT;

       ↓　以下に変更

    //起動したプロセスが終了するまで待つ
    while WaitForSingleObject(LInfo.hProcess, 100) = WAIT_TIMEOUT do
      Application.ProcessMessages;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
    procedure BringToFrontForm(AHandle: HWND);
  end;

var
  Form1: TForm1;

implementation

uses
  ShellAPI;

{$R *.dfm}

//-----------------------------------------------------------------------------
//  ShellExecuteExで指定ファイルを実行
//  ShellExcuteExの使用にはusesにShellAPIが必要
//-----------------------------------------------------------------------------
function RunExeFile(hWnd: HWND; AFile: String; AParameters: String;
   Verb: String): Cardinal;
var
  LInfo : TShellExecuteInfo;
begin
  FillChar(LInfo, SizeOf(LInfo), 0);
  LInfo.cbSize := SizeOf(LInfo);
  LInfo.Wnd    := hWnd;

  LInfo.fMask  := SEE_MASK_FLAG_DDEWAIT or
                  SEE_MASK_FLAG_NO_UI   or
                  SEE_MASK_NOCLOSEPROCESS;
  LInfo.lpVerb := PChar(Verb);

  LInfo.lpFile       := PChar(AFile);
  LInfo.lpParameters := PChar(AParameters);
  LInfo.nShow        := SW_SHOW;

  ShellExecuteEx(@LInfo);

  //ShellExecuteExは成功するとhInstAppに33以上の値を返す
  //起動したプロセス(アプリ)の終了を待つ処理
  if LInfo.hInstApp >= 33 then begin
    while WaitForSingleObject(LInfo.hProcess, 100) = WAIT_TIMEOUT do begin
      Application.ProcessMessages;
    end;

    CloseHandle(LInfo.hProcess);
  end;

  Result := LInfo.hInstApp;
end;

//=============================================================================
//  ShellExecuteEx関数でテストファイルを開く
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LExePath   : String;
  LParams    : String;
  LhInstance : Cardinal;
begin
  //起動プログラムのパス
  LExePath := 'notepad.exe';
  //起動アプリの起動オプションのパス名を絶対パスに変換
  LParams := ExpandFileName('..\App Files\テスト.txt');
  LParams := SysUtils.AnsiQuotedStr(LParams, '"');

  //起動したアプリが終了するまで、このフォームは操作不可にする
  Self.Enabled := False;

  //アプリ起動
  LhInstance := RunExeFile(Handle, LExePath, LParams, '');
  if LhInstance <= 32 then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end else begin
    BringToFrontForm(Handle);
    Windows.MessageBox(Handle, 'メモ帳が終了しました', '終了', MB_ICONINFORMATION);
  end;
  Self.Enabled := True;
end;

//-----------------------------------------------------------------------------
//  指定フォームを最前面に表示する関数
//
//  起動したプロセスが終了するまで待つ場合
//  起動したアプリが終了しても、必しも本アプリが最前面に表示されるとか限らない
//  そこで強制的に最前面にする
//
//  AHandle : 前面に表示するフォームのハンドル (メインフォーム以外も可)
//  SPI_GETFOREGROUNDLOCKTIMEOUT, SPI_SETFOREGROUNDLOCKTIMEOUT はデバック時無効
//-----------------------------------------------------------------------------
procedure TForm1.BringToFrontForm(AHandle: HWND);
var
  LhForeWnd     : HWND;
  LTimeOut      : DWORD;
  LThreadForeID : Cardinal;
  LThreadSelfID : Cardinal;
begin
  // 現在の最前面のウィンドウハンドルを取得
  // 少しタイムラグがないとウィンドウハンドルが取得できないことがある
  LhForeWnd := 0;
  while True do begin
    LhForeWnd := GetForegroundWindow;
    if LhForeWnd <> 0 then Break;
    Application.ProcessMessages;
    Sleep(10);
  end;
  // 現在の最前面ウィンドウのプロセスIDの値を取得
  LThreadForeID := GetWindowThreadProcessId(LhForeWnd);
  // 前面表示するウィンドウのプロセスのスレッドIDの値を取得
  // LThreadSelfID := GetWindowThreadProcessId(AHandle); でもOK (値は違う)
  LThreadSelfID := GetCurrentThreadId;
  try
    // スレッドのアタッチ
    AttachThreadInput(LThreadSelfID, LThreadForeID, True);
    // タスクバーの点滅時間の設定値を取得 (フォアグランドにするまでの時間)
    // デフォルト値は非常に大きな値.通常は前面に表示しないで点滅するだけ
    SystemParametersInfo(SPI_GETFOREGROUNDLOCKTIMEOUT, 0, @LTimeOut, 0);

    // タスクバーの点滅時間の設定
    // 点滅時間を 0 にして直ちに最前面に表示するようにする
    SystemParametersInfo(SPI_SETFOREGROUNDLOCKTIMEOUT, 0, nil, 0);

    // 最小化されているときは元に戻す
    if IsIconic(AHandle) then begin
      SendMessage(AHandle, WM_SYSCOMMAND, SC_RESTORE, 0);
    end;
    // 最前面に表示する
    SetForegroundWindow(AHandle);
  finally
    // タスクバーの点滅時間の設定を元に戻す
    SystemParametersInfo(SPI_SETFOREGROUNDLOCKTIMEOUT, 0, Pointer(LTimeOut), 0);
    // 終了したらアタッチを切り離す
    AttachThreadInput(LThreadSelfID, LThreadForeID, False);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  ShellAPI;

{$R *.dfm}

//-----------------------------------------------------------------------------
//  ShellExecuteExで指定ファイルを実行
//  ShellExcuteExの使用にはusesにShellAPIが必要
//-----------------------------------------------------------------------------
function RunExeFile(hWnd: HWND; AFile: String; AParameters: String;
   Verb: String): Cardinal;
var
  LInfo : TShellExecuteInfo;
  LRet  : Cardinal;
begin
  FillChar(LInfo, SizeOf(LInfo), 0);
  LInfo.cbSize := SizeOf(LInfo);
  LInfo.Wnd    := hWnd;

  LInfo.fMask  := SEE_MASK_FLAG_DDEWAIT or
                  SEE_MASK_FLAG_NO_UI   or
                  SEE_MASK_NOCLOSEPROCESS;
  LInfo.lpVerb := PChar(Verb);

  LInfo.lpFile       := PChar(AFile);
  LInfo.lpParameters := PChar(AParameters);
  LInfo.nShow        := SW_SHOW;

  ShellExecuteEx(@LInfo);

  //ShellExecuteExは成功するとhInstAppに33以上の値を返す
  if LInfo.hInstApp >= 33 then begin
    //プロセスがアイドル状態になるまで待つ
    repeat
      LRet := WaitForInputIdle(LInfo.hProcess, 50);
      Application.ProcessMessages;
    until LRet <> WAIT_TIMEOUT;

    CloseHandle(LInfo.hProcess);
  end;

 Result := LInfo.hInstApp;
end;

//=============================================================================
//  ShellExecuteEx関数でコマンドプロンプトを管理者権限で起動
//  TShellExecuteInfo.lpParametersは空白区切りの引数
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LExePath   : String;
  LParams    : String;
  LVerbStr   : String;
  LhInstance : Cardinal;
begin
  //起動プログラムのパスと起動オプションの指定
  LExePath := 'Cmd.exe';
  LParams  := '/k cd /d c:\';
  //管理者への昇格ダイアログを表示
  LVerbStr := 'runas';

  LhInstance := RunExeFile(Handle, LExePath, LParams, LVerbStr);
  if LhInstance <= 32 then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

//=============================================================================
//  ShellExecuteEx関数で指定アプリを管理者権限で起動
//  TShellExecuteInfo.lpParametersは空白区切りの引数
//  空白文字を含むパラメータは二重引用符(ダブルクォーテーション)で囲む
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LExePath   : String;
  LParams    : String;
  LVerbStr   : String;
  LhInstance : Cardinal;
begin
  LExePath := '..\App Files\MyImgViewer.exe';
  LParams  := '..\App Files\Parrots.gif';
  LParams  := SysUtils.AnsiQuotedStr(LParams, '"');
  //管理者への昇格ダイアログを表示
  LVerbStr := 'runas';

  LhInstance := RunExeFile(Handle, LExePath, LParams, LVerbStr);
  if LhInstance <= 32 then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//-----------------------------------------------------------------------------
//  CreateProcess関数を使用して、指定したファイルを実行する
//  アプリの起動完了まで待つ
//-----------------------------------------------------------------------------
function WinExecAndWait32V2(FileName: String; Visibility: Integer): DWORD;
var
  LStartupInfo : TStartupInfo;
  LProcessInfo : TProcessInformation;
  LRet         : DWORD;
begin
  Result := 0;

  FillChar(LStartupInfo, SizeOf(LStartupInfo), #0);
  LStartupInfo.cb          := SizeOf(TStartupInfo);
  LStartupInfo.dwFlags     := STARTF_USESHOWWINDOW;
  LStartupInfo.wShowWindow := Visibility;

  SetLength(FileName, Length(FileName));

  //参照カウンタ対策
  UniqueString(FileName);
  if not CreateProcess(nil,
                       PChar(FileName),
                       nil,
                       nil,
                       False,
                       CREATE_NEW_CONSOLE or NORMAL_PRIORITY_CLASS,
                       nil,
                       nil,
                       LStartupInfo,
                       LProcessInfo) then begin
    Result := WAIT_FAILED;
  end else begin
    //プロセスが生成されるまで待つ
    repeat
      LRet := WaitForInputIdle(LProcessInfo.hProcess, 50);
      Application.ProcessMessages;
    until LRet <> WAIT_TIMEOUT;

    GetExitCodeProcess(LProcessInfo.hProcess, Result);
    CloseHandle(LProcessInfo.hProcess);
    CloseHandle(LProcessInfo.hThread);
  end;
end;

//=============================================================================
//  CreateProcess関数で指定アプリを引数付きで起動
//  CreateProcess関数の第2引数は空白区切りの引数
//  したがって、ファイル名、引数のパラメータに空白が含まれている場合は、ダブル
//  クォーテーションで囲んでおく必要がある
//
//  CreateProcess関数は、拡張子の関連付けでの起動はできない
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LExePath : String;
  LParams  : String;
  LRet     : DWORD;
begin
  //起動アプリとその引数の設定
  LExePath := '..\App Files\MyImgViewer.exe';
  LExePath := SysUtils.AnsiQuotedStr(LExePath, '"');
  LParams  := '..\App Files\Parrots.gif';
  LParams  := SysUtils.AnsiQuotedStr(LParams, '"');

  //アプリを起動
  LRet := WinExecAndWait32V2(LExePath + ' ' + LParams, SW_SHOWNORMAL);
  if LRet = WAIT_FAILED then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

end.

procedure TForm1.Button1Click(Sender: TObject);
var
  LExeName : String;
  LParams  : String;
  LRet     : DWORD;
begin
  //起動アプリとその引数の設定
  LExeName := 'C:\Program Files\Windows NT\Accessories\wordpad.exe';
  LExeName := SysUtils.AnsiQuotedStr(LExeName, '"');
  LParams  := 'Acro_Test.pdf';
  LParams  := SysUtils.AnsiQuotedStr(LParams, '"');

  //アプリを起動
  LRet := WinExecAndWait32V2(LExeName + ' ' + LParams, SW_SHOWNORMAL);
  if LRet = WAIT_FAILED then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end;
end;

    //プロセスが生成されるまで待つ
    repeat
      LRet := WaitForInputIdle(LProcessInfo.hProcess, 50);
      Application.ProcessMessages;
    until ret <> WAIT_TIMEOUT;

       ↓　以下に変更

    //起動したプロセスが終了するまで待つ
    while WaitForSingleObject(LProcessInfo.hProcess, 100) = WAIT_TIMEOUT do
      Application.ProcessMessages;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
    procedure BringToFrontForm(AHandle: HWND);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//-----------------------------------------------------------------------------
//  CreateProcess関数を使用して、指定したファイルを実行する
//  起動したアプリが終了するまでこの関数が終了しないコードになっている
//-----------------------------------------------------------------------------
function WinExecAndWait32V2(FileName: String; Visibility: Integer): DWORD;
var
  LStartupInfo : TStartupInfo;
  LProcessInfo : TProcessInformation;
begin
  Result := 0;

  FillChar(LStartupInfo, SizeOf(LStartupInfo), #0);
  LStartupInfo.cb          := SizeOf(TStartupInfo);
  LStartupInfo.dwFlags     := STARTF_USESHOWWINDOW;
  LStartupInfo.wShowWindow := Visibility;

  SetLength(FileName, Length(FileName));

  //参照カウンタ対策
  UniqueString(FileName);
  if not CreateProcess(nil,
                       PChar(FileName),
                       nil,
                       nil,
                       False,
                       CREATE_NEW_CONSOLE or NORMAL_PRIORITY_CLASS,
                       nil,
                       nil,
                       LStartupInfo,
                       LProcessInfo) then begin
    Result := WAIT_FAILED;
  end else begin
    //起動したプロセスが終了するまで待つ
    while WaitForSingleObject(LProcessInfo.hProcess, 100) = WAIT_TIMEOUT do
      Application.ProcessMessages;

    GetExitCodeProcess(LProcessInfo.hProcess, Result);
    CloseHandle(LProcessInfo.hProcess);
    CloseHandle(LProcessInfo.hThread);
  end;
end;

//=============================================================================
//  CreateProcess関数で指定アプリを引数付きで起動
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LExePath : string;
  LParams  : string;
  LRet     : DWORD;
begin
  //起動アプリとその引数の設定
  LExePath := 'notepad.exe';
  LExePath := SysUtils.AnsiQuotedStr(LExePath, '"');
  LParams  := ExpandFileName('..\App Files\テスト.txt');
  LParams  := SysUtils.AnsiQuotedStr(LParams, '"');

  //起動したアプリが終了するまで、このフォームは操作不可にする
  Self.Enabled := False;

  //アプリ起動
  LRet := WinExecAndWait32V2(LExePath + ' ' + LParams, SW_SHOWNORMAL);
  if LRet = WAIT_FAILED then begin
    Windows.MessageBox(Handle, '起動に失敗しました', 'エラー', MB_ICONSTOP);
  end else begin
    BringToFrontForm(Handle);
    Windows.MessageBox(Handle, 'メモ帳が終了しました', '終了', MB_ICONINFORMATION);
    Self.Enabled := True;
  end;
end;

//-----------------------------------------------------------------------------
//  指定フォームを最前面に表示する関数
//
//  起動したプロセスが終了するまで待つ場合
//  起動したアプリが終了しても、必しも本アプリが最前面に表示されるとか限らない
//  そこで強制的に最前面にする
//
//  AHandle : 前面に表示するフォームのハンドル (メインフォーム以外も可)
//  SPI_GETFOREGROUNDLOCKTIMEOUT, SPI_SETFOREGROUNDLOCKTIMEOUT はデバック時無効
//-----------------------------------------------------------------------------
procedure TForm1.BringToFrontForm(AHandle: HWND);
var
  LhForeWnd     : HWND;
  LTimeOut      : DWORD;
  LThreadForeID : Cardinal;
  LThreadSelfID : Cardinal;
begin
  // 現在の最前面のウィンドウハンドルを取得
  // 少しタイムラグがないとウィンドウハンドルが取得できないことがある
  LhForeWnd := 0;
  while True do begin
    LhForeWnd := GetForegroundWindow;
    if LhForeWnd <> 0 then Break;
    Application.ProcessMessages;
    Sleep(10);
  end;
  // 現在の最前面ウィンドウのプロセスIDの値を取得
  LThreadForeID := GetWindowThreadProcessId(LhForeWnd);
  // 前面表示するウィンドウのプロセスのスレッドIDの値を取得
  // LThreadSelfID := GetWindowThreadProcessId(AHandle); でもOK (値は違う)
  LThreadSelfID := GetCurrentThreadId;
  try
    // スレッドのアタッチ
    AttachThreadInput(LThreadSelfID, LThreadForeID, True);
    // タスクバーの点滅時間の設定値を取得 (フォアグランドにするまでの時間)
    // デフォルト値は非常に大きな値.通常は前面に表示しないで点滅するだけ
    SystemParametersInfo(SPI_GETFOREGROUNDLOCKTIMEOUT, 0, @LTimeOut, 0);

    // タスクバーの点滅時間の設定
    // 点滅時間を 0 にして直ちに最前面に表示するようにする
    SystemParametersInfo(SPI_SETFOREGROUNDLOCKTIMEOUT, 0, nil, 0);

    // 最小化されているときは元に戻す
    if IsIconic(AHandle) then begin
      SendMessage(AHandle, WM_SYSCOMMAND, SC_RESTORE, 0);
    end;
    // 最前面に表示する
    SetForegroundWindow(AHandle);
  finally
    // タスクバーの点滅時間の設定を元に戻す
    SystemParametersInfo(SPI_SETFOREGROUNDLOCKTIMEOUT, 0, Pointer(LTimeOut), 0);
    // 終了したらアタッチを切り離す
    AttachThreadInput(LThreadSelfID, LThreadForeID, False);
  end;
end;

end.

procedure TForm1.Button1Click(Sender: TObject);
var
  LExeFullPath : String;
begin
  //自分自身(EXE)の絶対パスを取得
  //基本的にはどちらでも取得可能
  LExeFullPath := Application.ExeName;
  LExeFullPath := ParamStr(0);
end;

const
  PathDelim  = {$IFDEF MSWINDOWS} '\'; {$ELSE} '/'; {$ENDIF}
  DriveDelim = {$IFDEF MSWINDOWS} ':'; {$ELSE} '';  {$ENDIF}
  PathSep    = {$IFDEF MSWINDOWS} ';'; {$ELSE} ':'; {$ENDIF}

const
   sLineBreak = {$IFDEF LINUX} AnsiChar(#10) {$ENDIF}
      {$IFDEF MSWINDOWS} AnsiString(#13#10) {$ENDIF}
      {$IFDEF MACOS} AnsiChar(#10) {$ENDIF};

const
   sLineBreak = {$IFDEF POSIX}} AnsiChar(#10) {$ENDIF}
      {$IFDEF MSWINDOWS} AnsiString(#13#10) {$ENDIF}

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  Registry,
  ShLwApi;

{$R *.dfm}

//=============================================================================
//  デフォルトのブラウザのフルパスをレジストリから取得
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);

  //---------------------------------------------------------------------------
  //  短いパス名を長いパス名に変換する関数
  //  必要がなければ実行しなくてもよい
  //---------------------------------------------------------------------------
  function ChangeLongPathName(ShortPath: String): String;
  var
    LSize : Integer;
  begin
    LSize := GetLongPathName(PChar(ShortPath), nil, 0);
    if LSize > 0 then begin
      SetLength(Result, LSize);
      LSize := GetLongPathName(PChar(ShortPath), PChar(Result), LSize);
      SetLength(Result, LSize);
    end else begin
      Result := '';
    end;
  end;
  //---------------------------------------------------------------------------

var
  LReg     : TRegistry;
  LAppKey  : String;
  LAppItem : String;
  LText    : String;
begin
  LReg         := TRegistry.Create;
  LReg.Access  := KEY_READ;
  LReg.RootKey := HKEY_CLASSES_ROOT;
  try
    //引数を''にして既定値を取得
    LAppKey  := 'http\shell\open\command';
    LAppItem := '';
    if LReg.OpenKey(LAppKey, False) then begin
      try
        LText := LReg.ReadString(LAppItem);

        //文字列から実行ファイル名だけを取得してダブルクォーテーションを取り除く
        ShLwApi.PathRemoveArgs(PChar(LText));
        LText := SysUtils.AnsiDequotedStr(PChar(LText), '"');
        LText := ChangeLongPathName(LText);
        MessageBox(Handle, PChar(LText), '実行パス', MB_ICONINFORMATION);
      finally
        LReg.CloseKey;
      end;
    end;
  finally
    FreeAndNil(LReg);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  Registry,
  ShLwApi;

{$R *.dfm}

//=============================================================================
//  デフォルトのメーラーのフルパスをレジストリから取得
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);

  //---------------------------------------------------------------------------
  //  短いパス名を長いパス名に変換する関数
  //  必要がなければ実行しなくてもよい
  //---------------------------------------------------------------------------
  function ChangeLongPathName(ShortPath: String): String;
  var
    LSize : Integer;
  begin
    LSize := GetLongPathName(PChar(ShortPath), nil, 0);
    if LSize > 0 then begin
      SetLength(Result, LSize);
      LSize := GetLongPathName(PChar(ShortPath), PChar(Result), LSize);
      SetLength(Result, LSize);
    end else begin
      Result := '';
    end;
  end;
  //---------------------------------------------------------------------------

var
  LReg     : TRegistry;
  LAppKey  : String;
  LAppItem : String;
  LText    : String;
begin
  LReg         := TRegistry.Create;
  LReg.Access  := KEY_READ;
  LReg.RootKey := HKEY_CLASSES_ROOT;
  try
    //引数を''にして既定値を取得
    LAppKey  := 'mailto\shell\open\command';
    LAppItem := '';
    if LReg.OpenKey(LAppKey, False) then begin
      try
        LText := LReg.ReadString(LAppItem);

        //文字列から実行ファイル名だけを取得してダブルクォーテーションを取り除く
        ShLwApi.PathRemoveArgs(PChar(LText));
        LText := SysUtils.AnsiDequotedStr(PChar(LText), '"');
        LText := ChangeLongPathName(LText);
        MessageBox(Handle, PChar(LText), '実行パス', MB_ICONINFORMATION);
      finally
        LReg.CloseKey;
      end;
    end;
  finally
    FreeAndNil(LReg);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  ExtActns;

{$R *.dfm}

//=============================================================================
//  TFileRunを使用したアプリの起動
//  TFileRunはTActionListで指定可能なアクションクラス
//  このコードは、指定のエクセルのブックをエクセルで表示する
//
//  TFileRunの使用にはusesにExtActnsが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LActClass : TFileRun;
  LFilePath : String;
begin
  //表示するエクセルのブックのフルパス名
  //途中に空白文字がある場合は、ダブルクォーテーションで括る
  LFilePath := ExpandFileName('../App Files/テスト.xls');
  LFilePath := AnsiQuotedStr(LFilePath, '"');

  LActClass := TFileRun.Create(Self);
  try
    LActClass.FileName   := 'EXCEL.EXE';
    LActClass.Parameters := LFilePath;
    LActClass.Execute;
  finally
    FreeAndNil(LActClass);
  end;
end;

end.

  //---------------------------------------------------------------------------
  //  [ファイル名を指定して実行] ダイアログを表示する関数の定義
  //  この関数は非公開API関数
  //
  //  Shell32.dllを使用するにはusesにShellAPIが必要
  //---------------------------------------------------------------------------
  procedure SH_RunFileDlg(
            Handle     : THandle;
            hIcon      : HICON;
            lpazPaht   : PChar;
            lpszTitle  : PChar;
            lpszPrompt : PChar;
            uFlages    : Integer); stdcall; external 'shell32.dll' index 61;

var
  Form1: TForm1;

implementation

{$R *.DFM}

//=============================================================================
//  フォーム生成時の処理
//  実際にはフォームは表示しない
//  プロジェクトのソースコードに以下の変更をしている
//    Application.ShowMainForm := False;   デフォルトはTrue
//    Application.Run;                     実行しない(削除している)
//  プロジェクトのアイコンも変更している
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  LDlgTitle : PChar;
  LPrompt   : PChar;
begin
  LDlgTitle := 'ファイル名を指定して実行';
  LPrompt   := nil;

  SH_RunFileDlg(Handle, 0, nil, LDlgTitle, LPrompt, 0);
end;

implementation

uses
  ShellAPI;

{$R *.dfm}

//-----------------------------------------------------------------------------
//  環境変数を含む(%等の文字を含む)を実際のパス名に変換
//-----------------------------------------------------------------------------
function ExpandEnvironmentString(S: string): String;
var
  LDstChar : array [0..MAX_PATH - 1] of Char;
begin
  ExpandEnvironmentStrings(PChar(S), LDstChar, MAX_PATH);
  Result := LDstChar;
end;

//=============================================================================
//  フォーム生成時の処理
//
//  コマンドの入力欄を配置して、ShellExecute 関数でコマンドを実行する例
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Self.Caption := 'ファイル名を指定して実行';

  //起動直後にEdit1を編集状態に
  //[Enter]キーで実行
  //[Esc]キーでダイアログを閉じる
  ActiveControl   := Edit1;
  Button1.Default := True;
  Button2.Cancel  := True;

  Edit1.Text := 'control.exe';
  Edit2.Text := '/name Microsoft.DefaultPrograms';
end;

//=============================================================================
//  入力欄に入力したコマンドを実行
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LFilePath : string;
  LParams   : string;
  LResult   : Cardinal;
  LText     : string;
begin
  LFilePath := ExpandEnvironmentString(Trim(Edit1.Text));
  LParams   := ExpandEnvironmentString(Trim(Edit2.Text));

  LResult := ShellExecute(Handle, '', PChar(LFilePath), PChar(LParams), nil, SW_SHOW);

  if LResult <= 32 then begin
    LText := SysErrorMessage(LResult);
    Windows.MessageBox(Handle, PChar(LText), '情報', MB_ICONWARNING);
  end;

  Close;
end;

//=============================================================================
//  [キャンセル]
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  Close;
end;

//=============================================================================
//  入力欄に入力したコマンドを実行
//  1行だけのコマンド文字列を実行ファイル名とパラメータに分解する例
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LStrList  : TStringList;
  LFilePath : string;
  LParams   : string;
  LResult   : Cardinal;
  LText     : string;
  LPos      : Integer;
  i         : Integer;
begin
  if Trim(Edit1.Text) = '' then exit;

  LStrList := TStringList.Create;
  try
    //コマンド文字列を半角空白で区切ったリストを作成
    //TStringList.StrictDelimiterがなくて動作可能
    LStrList.Delimiter       := ' ';
    LStrList.StrictDelimiter := True;
    LStrList.DelimitedText   := Trim(Edit1.Text);
    LStrList.Text := ExpandEnvironmentString(LStrList.Text);

    LFilePath := '';
    LParams   := '';

    if LStrList.Count = 1 then begin
      LFilePath := LStrList[0];
    end else begin
      //実行形式ファイルの検索
      LPos := 0;
      for i := 0 to LStrList.Count - 1 do begin
        LFilePath := LFilePath + LStrList[i];
        if not FileExists(LFilePath) then begin
          if FileExists(LFilePath + '.EXE')
            or FileExists(LFilePath + '.CMD')
            or FileExists(LFilePath + '.BAT') then begin
            LPos := i + 1;
            break;
          end else begin
            LFilePath := LFilePath + ' ';
          end;  
        end else begin
          LPos := i + 1;
          break;
        end;
      end;
      //ディレクトリ名が省略されているパス名の場合
      //ファイル名に空白がある場合は検出不可(そのようなファイルはないと仮定)
      if LPos = 0 then begin
        LFilePath := LStrList[0];
        LPos      := 1;
      end;  

      //パラメータ部分の文字列を作成
      for i := LPos to LStrList.Count - 1 do begin
        LParams := LParams + LStrList[i] + ' ';
      end;
    end;  
  finally
    FreeAndNil(LStrList);
  end;

  LFilePath :=  Trim(LFilePath);
  if Pos(' ', LFilePath) > 0 then begin
    LFilePath := AnsiQuotedStr(LFilePath, '"');
  end;
  LParams := Trim(LParams);

  //コマンド実行
  LResult := ShellExecute(Handle, '', PChar(LFilePath), PChar(LParams), nil, SW_SHOW);

  if LResult <= 32 then begin
    LText := SysErrorMessage(LResult);
    Windows.MessageBox(Handle, PChar(LText), '情報', MB_ICONWARNING);
  end;

  Close;
end;