unit Word_TWordAppUnit;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, OleServer, Word2000;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    WordApplication1: TWordApplication;
    WordDocument1: TWordDocument;
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  操作しやすいように，このFormを最前面に表示
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  Self.FormStyle := fsStayOnTop;
end;

//=============================================================================
//  FormのOnCloseイベント
//  終了処理(Delphi言語の例外で停止が無効でないとtry～end部分無効)
//  Wordの切断
//  try～except,endを使用しているのは，このフォームを閉じる前にワードを終了して
//  してしまった場合を考慮して
//=============================================================================
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  try
    if WordApplication1.Documents.Count > 0 then begin
      WordDocument1.Close;
      WordDocument1.Disconnect;
    end;

    //Quitがないと，WINWORD.EXEのプロセスがメモリ上に残ってしまう
    WordApplication1.Quit;
    WordApplication1.Disconnect;
  except
  end;
end;

//=============================================================================
//  [ワードを新規起動]ボタン
//  Wordアプリケーションの接続と指定文書の表示
//  Openメソッドの引数の数はインストールしている[Servers]タブのOfficeのパッケ
//  ージによって異なる．このコードはWord2000の場合．WordXPの場合は後3つ必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  FilePath : OleVariant;
begin
  FilePath := ExtractFilePath(Application.ExeName) + 'テスト文書.doc';
  WordApplication1.Connect;
  WordApplication1.Visible := True;

  //文書を開く
  WordApplication1.Documents.Open(FilePath,
                                  EmptyParam,
                                  EmptyParam,
                                  EmptyParam,
                                  EmptyParam,
                                  EmptyParam,
                                  EmptyParam,
                                  EmptyParam,
                                  EmptyParam,
                                  EmptyParam,
                                  EmptyParam,
                                  EmptyParam);

  //開いている文書に接続し，それをWordDocument1オブジェクトとする
  WordDocument1.ConnectTo(WordApplication1.ActiveDocument as WordDocument);
end;
//=============================================================================
//  [終了]ボタン
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  Close;
end;

//=============================================================================
//  現在表示中の文書のフルパス名を表示
//  WordDocument1(TWordDocument)の使用例の１つとして
//  ワード操作の他のコードは，拙作ワード操作フォームExのソースコードまたは
//  オンライン・マニュアル参照
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
var
  ADocName : String;
begin
  ADocName := WordDocument1.FullName;
  Application.MessageBox(PChar(ADocName), '文書のパス名');
end;

end.

//=============================================================================
//  [ワードを新規起動]ボタン
//  Wordアプリケーションの接続と指定文書の表示
//
//  OleVariant型を使用すると引数を省略可能．ここではOpenメソッドで使用
//  この方法だと，使用する[Servers]タブのバージョンに関係ないコードが使用可能
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  FilePath : OleVariant;
  ADoc     : OleVariant;
begin
  FilePath := ExtractFilePath(Application.ExeName) + 'テスト文書.doc';
  WordApplication1.Connect;
  WordApplication1.Visible := True;

  //文書を開く
  ADoc := WordApplication1.Documents;
  ADoc.Open(FileName := FilePath);

  //開いている文書に接続し，それをWordDocument1オブジェクトとする
  WordDocument1.ConnectTo(WordApplication1.ActiveDocument as WordDocument);
end;