// VBA のリファレンス内を検索
AddPicture site:https://docs.microsoft.com/ja-jp/office/vba/api/ [検索]

Set myDocument = Worksheets(1) 
myDocument.Shapes.AddPicture _ 
    "c:\microsoft office\clipart\music.bmp", _ 
    True, True, 100, 100, 70, 70

// Constants for enum MsoTriState
type
  MsoTriState = TOleEnum;
const
  msoTrue = $FFFFFFFF;
  msoFalse = $00000000;
  msoCTrue = $00000001;
  msoTriStateToggle = $FFFFFFFD;
  msoTriStateMixed = $FFFFFFFE;

//=============================================================================
//  MSDNに掲載されているVBAのコードをDelphiのコードに変換
//
//  定数類の使用にはusesにOffic2000等が必要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
   ExcelWorksheet1.Shapes.AddPicture(
         ExtractFilePath(Application.ExeName) + '501.bmp',
         msoTrue, msoTrue, 100, 100, 70, 70);
end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Excel2000, Office2000, OleServer;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    ExcelApplication1: TExcelApplication;
    ExcelWorkbook1: TExcelWorkbook;
    ExcelWorksheet1: TExcelWorksheet;
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

//=============================================================================
//  フォームを閉じる時はエクセルの終了処理も実行
//  もし複数のブック,シートオブジェクトを生成している場合はそれらのClose
//  やDisconnect処理も必要
//  エクセルを閉じないでこのアプリを終了する場合でも、
//  各オブジェクトのDisconnectの実行は必要
//=============================================================================
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
var
  LBookNo : Integer;
begin
  if Assigned(ExcelApplication1) then begin

    for LBookNo := ExcelApplication1.Workbooks.Count downto 1 do begin
      ExcelApplication1.Workbooks[LBookNo].Close(False, EmptyParam, False, 0);
      Application.ProcessMessages;
    end;

    if Assigned(ExcelWorkbook1) then begin
      ExcelWorkbook1.Disconnect;
    end;
    if Assigned(ExcelWorksheet1) then begin
      ExcelWorksheet1.Disconnect;
    end;

    ExcelApplication1.Disconnect;
    ExcelApplication1.Quit;
  end;
end;

//=============================================================================
//  エクセルを新規起動する
//  起動したら最初のシートをアクティブにする
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  //ブックを追加
  ExcelApplication1.Workbooks.Add(EmptyParam, 0);
  ExcelWorkbook1.ConnectTo(ExcelApplication1.ActiveWorkbook as _workbook);
  //最初のシートオブジェクトを取得してアクティブにする
  //シート番号ではなくシート名(文字列)でも指定可能
  ExcelWorksheet1.ConnectTo(ExcelWorkbook1.Worksheets[1] as _WorkSheet);
  ExcelWorksheet1.Activate;

  //終了時に保存確認ダイアログを表示しない
  ExcelApplication1.DisplayAlerts[0] := False;

  //表示
  ExcelApplication1.Visible[0] := True;
end;

//=============================================================================
//  MSDNに掲載されているVBAのコードをDelphiのコードに変換
//
//  定数類の使用にはusesにOffic2000等が必要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
   ExcelWorksheet1.Shapes.AddPicture(
         ExtractFilePath(Application.ExeName) + '501.bmp',
         msoTrue, msoTrue, 100, 100, 70, 70);
end;

end.