unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Edit1: TEdit;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
  private
    { Private 宣言 }
    function GetFocusWindow(hTarget: HWND): HWND;    
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

//-----------------------------------------------------------------------------
//  入力フォーカスがあるコントロールのハンドルを取得
//
//  他アプリケーションのコントロールのハンドルは、コントロールのID値がわかれば
//  ID値から取得できるが、不明の場合はフォーカスのあるコントロールであればこの
//  関数で取得できる
//
//  GetForegroundWindowはトップウィンドウの取得、GetFocus単独では他のアプリの
//  場合常に0が返ってくる。AttachThreadInputを使用するとフォーカスのあるウィン
//  ドウ(コントロール)のハンドルを取得できる
//-----------------------------------------------------------------------------
function TForm1.GetFocusWindow(hTarget: HWND): HWND;
var
  dwTargetID : DWORD;
  dwActiveID : DWORD;
begin
  //操作対象ウィンドウのスレッドを取得
  dwTargetID := GetWindowThreadProcessId(hTarget, nil);
  //現在アクティブなウィンドウ(このアプリ)のスレッドを取得
  dwActiveID := GetCurrentThreadId;

  if hTarget <> GetForegroundWindow then begin
    //hTargetをZオーダのトップにしてアクティブに
    BringWindowToTop(hTarget);
    //Windows Vista,7の場合、これがないとアクティブにならない
    Application.ProcessMessages;
  end;

  if AttachThreadInput(dwTargetID, dwActiveID, True) then begin
    //フォーカスウィンドウの取得
    Result := GetFocus;
    //スレッドアタッチを切離す
    AttachThreadInput(dwTargetID, dwActiveID, False);
  end else begin
    Result := 0;
  end;
end;

//=============================================================================
//  他のアプリのフォーカスのあるコントロールに文字列をセットする
//  送信用文字列としてString型を使用する例
//
//  全て添付のReceiverApp.exeを起動してから実行する
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LhWindow   : HWND;
  LRevHandle : HWND;
  LChar      : Char;
begin
  //受取る側のトップウィンドウのハンドル
  LhWindow := FindWindow('TReceivAppForm', nil);

  if LhWindow <> 0 then begin
    //フォーカスのあるコントロールのハンドルを取得
    LRevHandle := Self.GetFocusWindow(LhWindow);

    //文字列を送る
    SendMessage(LRevHandle, WM_SETTEXT, 0, LPARAM(PChar(Edit1.Text)));

    //WM_CHARを使用すれば1文字分だけセットできる
    //第3引数にはキーストロークを指定する(ここでは無指定)
    LChar := 'A';
    SendMessage(LRevHandle, WM_CHAR, WPARAM(LChar), 0);
    //文字を直接セットする場合は以下でOK
    //SendMessage(LRevHandle, WM_CHAR, WPARAM('A'), 0);
  end;
end;

//=============================================================================
//  他のアプリのフォーカスのあるコントロールに文字列をセットする
//  送信用文字列としてPChar型を使用する例
//
//  String型の文字列をPChart型に代入するにはStrPCopyも使用できる
//  null終端文字(#0)は自動でセットされる
//  PChar型の文字列のサイズの設定は必要ない
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LhWindow   : HWND;
  LRevHandle : HWND;
  LBuffer    : PChar;
begin
  //String型の文字列をChar型の静的配列の文字列に代入
  LBuffer := PChar(Edit1.Text);

  //受取る側のトップウィンドウのハンドル
  LhWindow := FindWindow('TReceivAppForm', nil);

  if LhWindow <> 0 then begin
    //フォーカスのあるコントロールのハンドルを取得
    LRevHandle := Self.GetFocusWindow(LhWindow);

    //文字列を送る
    SendMessage(LRevHandle, WM_SETTEXT, 0, LPARAM(LBuffer));
  end;
end;

//=============================================================================
//  他のアプリのフォーカスのあるコントロールに文字列をセットする
//  送信用文字列としてChar型の静的配列を使用する例
//
//  Char型の静的配列は、変数の定義の際にその長さを設定する方式
//  String型の文字列をChar型の静的配列に代入するにはStrPCopyが使用できる
//  StrPCopyを使用するとnull終端文字(#0)は自動でセットされる
//
//  設定した文字列の長さが不足すると例外が発生するので注意
//  このサンプルような場面での使い方はあまり考えられない
//  Char型の静的配列は,文字数に制限がある場合によく使用される
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
var
  LhWindow   : HWND;
  LRevHandle : HWND;
  LBuffer    : array[0..MAX_PATH - 1] of Char;
begin
  //String型の文字列をChar型の静的配列の文字列に代入
  //代入可能な文字数はMAX_PATH
  StrPCopy(LBuffer, Edit1.Text);

  //受取る側のトップウィンドウのハンドル
  LhWindow := FindWindow('TReceivAppForm', nil);

  if LhWindow <> 0 then begin
    //フォーカスのあるコントロールのハンドルを取得
    LRevHandle := Self.GetFocusWindow(LhWindow);

    //文字列を送る
    //先頭のアドレス指定なので@LBuffer[0]でもOK
    SendMessage(LRevHandle, WM_SETTEXT, 0, LPARAM(@LBuffer));
  end;
end;

//=============================================================================
//  他のアプリのフォーカスのあるコントロールに文字列をセットする
//  送信用文字列としてChar型の動的配列を使用する例
//
//  Char型の動的配列の場合は実行時に領域(サイズ)の確保が必要
//=============================================================================
procedure TForm1.Button4Click(Sender: TObject);
var
  LhWindow   : HWND;
  LRevHandle : HWND;
  LBuffer    : array of Char;
begin
  //Char型配列の要素数を設定(null終端文字用に+1しておく)
  SetLength(LBuffer, Length(Edit1.Text) + 1);　
  //String型の文字列をChar型の動的配列の文字列に代入
  StrPCopy(PChar(LBuffer), Edit1.Text);

  //受取る側のトップウィンドウのハンドル
  LhWindow := FindWindow('TReceivAppForm', nil);

  if LhWindow <> 0 then begin
    //フォーカスのあるコントロールのハンドルを取得
    LRevHandle := Self.GetFocusWindow(LhWindow);

    //文字列を送る
    SendMessage(LRevHandle, WM_SETTEXT, 0, LPARAM(PChar(LBuffer)));
  end;
end;

end.

//=============================================================================
//  他のアプリのフォーカスのあるコントロールの文字列を取得する
//  String型を使用する例
//
//  String型はSetLengthで文字列の長さを設定する
//  Windows APIの関数によっては長さの設定が不要な場合もある
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LhWindow   : HWND;
  LRevHandle : HWND;
  LBuffer    : string;
begin
  //対象のトップウィンドウのハンドル
  LhWindow := FindWindow('TReceivAppForm', nil);

  if LhWindow <> 0 then begin
    //フォーカスのあるコントロールのハンドルを取得
    LRevHandle := Self.GetFocusWindow(LhWindow);

    //受信バッファとしての文字列の領域(長さ)を設定
    //取得可能な文字数は(MAX_PATH-1)
    SetLength(LBuffer, MAX_PATH);
    //文字列を取得するメッセージを送る
    SendMessage(LRevHandle, WM_GETTEXT, Length(LBuffer), LPARAM(PChar(LBuffer)));

    //取得した文字列を本アプリのEdit1.Textにセット
    Edit1.Text := LBuffer;
    SetForegroundWindow(Handle);
  end;
end;

//=============================================================================
//  他のアプリのフォーカスのあるコントロールの文字列を取得する
//  PChar型で取得する例
//
//  StrAllocで文字列の長さを設定する(終端文字のnull分を含める必要あり)
//  StrAllocで設定した長さは領域はStrBufSizeで取得できる
//  StrAllocで設定した領域はStrDisposeで開放が必要
//  Windows APIの関数によっては長さの設定が不要な場合もある
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LhWindow   : HWND;
  LRevHandle : HWND;
  LBuffer    : PChar;
begin
  //対象のトップウィンドウのハンドル
  LhWindow := FindWindow('TReceivAppForm', nil);

  if LhWindow <> 0 then begin
    //フォーカスのあるコントロールのハンドルを取得
    LRevHandle := Self.GetFocusWindow(LhWindow);

    //受信バッファとしての文字列の領域(長さ)を設定
    //取得可能な文字数は(MAX_PATH)
    LBuffer := StrAlloc(MAX_PATH + 1);
    try
      //文字列を取得するメッセージを送る
      SendMessage(LRevHandle, WM_GETTEXT, StrBufSize(LBuffer), LPARAM(LBuffer));

      //取得した文字列を本アプリのEdit1.Textにセット
      Edit1.Text := LBuffer;
      SetForegroundWindow(Handle);
    finally
      StrDispose(LBuffer);
    end;
  end;
end;

//=============================================================================
//  他のアプリのフォーカスのあるコントロールの文字列を取得する
//  Char型の静的配列で取得する例
//
//  Char型の静的配列は,変数の定義の時に長さを設定する方式
//  Char型の静的配列は,FillChar手続きで初期化できる
//  ウインドウのタイトルやファイル名等、長さ制限のある文字列の取得に適している
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
var
  LhWindow   : HWND;
  LRevHandle : HWND;
  LBuffer    : array[0..MAX_PATH - 1] of Char;
begin
  //対象のトップウィンドウのハンドル
  LhWindow := FindWindow('TReceivAppForm', nil);

  if LhWindow <> 0 then begin
    //フォーカスのあるコントロールのハンドルを取得
    LRevHandle := Self.GetFocusWindow(LhWindow);

    //バッファとしての文字列の初期化
    //null文字で埋めないと取得した文字列にゴミが入ることがある
    //取得可能な文字数は(MAX_PATH)
    FillChar(LBuffer, Sizeof(LBuffer), #0);
    //文字列を取得するメッセージを送る
    SendMessage(LRevHandle, WM_GETTEXT, Length(LBuffer), LPARAM(@LBuffer));

    //取得した文字列を本アプリのEdit1.Textにセット
    //Edit1.Text := string(LBuffer);とキャストすれば確実
    Edit1.Text := LBuffer;
    SetForegroundWindow(Handle);
  end;
end;

//=============================================================================
//  他のアプリのフォーカスのあるコントロールの文字列を取得する
//  Char型の動的配列で取得する例
//
//  Char型の動的配列はSetLengthで文字列の長さを設定する
//  String型へはstring,またはPCharでキャストすれば代入可能
//=============================================================================
procedure TForm1.Button4Click(Sender: TObject);
var
  LhWindow   : HWND;
  LRevHandle : HWND;
  LBuffer    : array of Char;
begin
  //対象のトップウィンドウのハンドル
  LhWindow := FindWindow('TReceivAppForm', nil);

  if LhWindow <> 0 then begin
    //フォーカスのあるコントロールのハンドルを取得
    LRevHandle := Self.GetFocusWindow(LhWindow);

    //Char型動的配列の長さを設定
    //取得可能な文字数は(MAX_PATH-1)
    SetLength(LBuffer, MAX_PATH);
    //文字列を取得するメッセージを送る
    SendMessage(LRevHandle, WM_GETTEXT, Length(LBuffer), LPARAM(PChar(LBuffer)));

    //取得した文字列を本アプリのEdit1.Textにセット
    //Edit1.Text := PChar(LBuffer); でもOK
    Edit1.Text := string(LBuffer);
    SetForegroundWindow(Handle);
  end;
end;

//=============================================================================
//  フォーム表示開始時の処理
//  テスト用の文字列をセット
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  Button2.Enabled := False;
  Button3.Enabled := False;
  Button4.Enabled := False;
  Button5.Enabled := False;

  with Memo1.Lines do begin
    Clear;
    BeginUpdate;
    Add('Delphiはウインドウズ用の開発言語です');
    Add('開発言語は他にもいろいろあります');
    Add('山登りは苦しいけど、頂上に立った時は感激です');
    Add('このプログラムはDelphiで作成されています');
    Add('開発言語にはインタープリタというのもあります');
    Add('Delphi2009からDelphiはユニコード化されました');
    Add('文字列の扱いが違ってきて、コードの移植が重要です');
    EndUpdate;
  end;
end;

//=============================================================================
//  フォームを閉じる時の処理
//  テストなので終了時はメモ帳も強制的に閉じる
//  ただし、このアプリで起動したメモ帳のみ
//=============================================================================
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  if FhNotepad <> 0 then begin
    SendMessage(FhNotepad, WM_CLOSE, 0, 0);
  end;
end;

//=============================================================================
//  メモ帳を起動
//
//  (1)メモ帳を起動し、そのハンドルを取得
//  (2)起動直後は、メモ帳がアクティブなウィンドウ
//  (3)そのウィンドウで入力フォーカスがあるウインドウがメモ帳の編集ウィンドウ
//
//  アプリの起動完了を検出するにはShellExecuteEx,CreateProcess 関数等を使用する
//
//  ShellExecuteの使用にはusesにShellAPOが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  ShellExecute(Handle, '', PChar('Notepad.exe'), nil, nil, SW_SHOW);

  //起動完了待ちの代用
  //メモ帳が表示されても必ずもハンドルが有効になっているとは限らないので注意
  Sleep(2000);

  //メモ帳のハンドル
  FhNotepad := GetForegroundWindow;
  if FhNotepad > 0 then begin
    //受取る側のトップウィンドウのハンドルを取得.ここではメモ帳の編集ウィンドウ
    FhNotepadEdit := Self.GetFocusWindow(FhNotepad);

    Button2.Enabled := True;
    Button3.Enabled := True;
    Button4.Enabled := True;
    Button5.Enabled := True;
  end;
end;

//=============================================================================
//  他のアプリのフォーカスのあるコントロールに文字列をセットする
//  メモ帳の例
//  送信用文字列としてString型を使用する例
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  //メモ帳の編集ウィンドウのハンドルを確認
  if not IsWindowEnabled(FhNotepadEdit) then begin
    MessageBox(Handle, '操作可能なメモ帳が起動していません', '情報', MB_OK);
    exit;
  end;

  //文字列を送る
  SendMessage(FhNotepadEdit, WM_SETTEXT, 0, LPARAM(PChar(Memo1.Text)));
end;

//=============================================================================
//  他のアプリのフォーカスのあるコントロールに文字列をセットする
//  メモ帳の例
//  送信用文字列としてPChar型を使用する例
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
var
  LBuffer : PChar;
begin
  //メモ帳の編集ウィンドウのハンドルを確認
  if not IsWindowEnabled(FhNotepadEdit) then begin
    MessageBox(Handle, '操作可能なメモ帳が起動していません', '情報', MB_OK);
    exit;
  end;

  //String型の文字列をChar型の静的配列の文字列に代入
  LBuffer := PChar(Memo1.Lines.Text);

  //文字列を送る
  SendMessage(FhNotepadEdit, WM_SETTEXT, 0, LPARAM(LBuffer));
end;

//=============================================================================
//  他のアプリのフォーカスのあるコントロールに文字列をセットする
//  メモ帳の例
//  送信用文字列としてChar型の静的配列を使用する例
//
//  設定した文字列の長さが不足すると例外が発生するので注意
//  このサンプルような場面での使い方はあまり考えられない
//  Char型の静的配列は,文字数に制限がある場合によく使用される
//=============================================================================
procedure TForm1.Button4Click(Sender: TObject);
var
  LBuffer : array[0..MAXWORD] of Char;
begin
  //メモ帳の編集ウィンドウのハンドルを確認
  if not IsWindowEnabled(FhNotepadEdit) then begin
    MessageBox(Handle, '操作可能なメモ帳が起動していません', '情報', MB_OK);
    exit;
  end;

  //String型の文字列をChar型の静的配列の文字列に代入
  StrPCopy(LBuffer, Memo1.Lines.Text);

  //文字列を送る
  //先頭のアドレス指定なので@LBuffer[0]でもOK
  SendMessage(FhNotepadEdit, WM_SETTEXT, 0, LPARAM(@LBuffer));
end;

//=============================================================================
//  他のアプリのフォーカスのあるコントロールに文字列をセットする
//  メモ帳の例
//  送信用文字列としてChar型の動的配列を使用する例
//
//  Char型の動的配列の場合は実行時に領域(サイズ)の確保が必要
//=============================================================================
procedure TForm1.Button5Click(Sender: TObject);
var
  LBuffer : array of Char;
begin
  //メモ帳の編集ウィンドウのハンドルを確認
  if not IsWindowEnabled(FhNotepadEdit) then begin
    MessageBox(Handle, '操作可能なメモ帳が起動していません', '情報', MB_OK);
    exit;
  end;

  //Char型配列の要素数を設定(null終端文字用に+1しておく)
  SetLength(LBuffer, Length(Memo1.Lines.Text) + 1);　
  //String型の文字列をChar型の動的配列の文字列に代入
  StrPCopy(PChar(LBuffer), Memo1.Lines.Text);

  //文字列を送る
  SendMessage(FhNotepadEdit, WM_SETTEXT, 0, LPARAM(PChar(LBuffer)));
end;

//=============================================================================
//  起動中のメモ帳に文字(文字列ではない)を送る
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LhNotepad     : HWND;
  LhNotepadEdit : HWND;
begin
  //メモ帳のウィンドウハンドルを取得
  LhNotepad := FindWindow('Notepad', nil);
  if LhNotepad = 0 then begin
    MessageBox(Handle, 'メモ帳が起動していません', '情報', MB_OK);
    exit;
  end;

  //メモ帳の編集ウィンドウのハンドルを取得
  LhNotepadEdit := FindWindowEx(LhNotepad, 0, 'Edit', nil);

  //そのウィンドウハンドルに文字を送信
  if LhNotepadEdit > 0 then begin
    PostMessage(LhNotepadEdit, WM_CHAR, Ord('日'), 0);;
    PostMessage(LhNotepadEdit, WM_CHAR, Ord('本'), 0);
  end;
end;

//=============================================================================
//  フォーム表示開始時の処理
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  Button2.Enabled := False;
  Button3.Enabled := False;
  Button4.Enabled := False;
  Button5.Enabled := False;
end;

//=============================================================================
//  フォームを閉じる時の処理
//  テストなので終了時はメモ帳も強制的に閉じる
//  ただし、このアプリで起動したメモ帳のみ
//=============================================================================
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  if FhNotepad <> 0 then begin
    SendMessage(FhNotepad, WM_CLOSE, 0, 0);
  end;
end;

//=============================================================================
//  メモ帳を起動
//
//  (1)メモ帳を起動し、そのハンドルを取得
//  (2)起動直後は、メモ帳がアクティブなウィンドウ
//  (3)そのウィンドウで入力フォーカスがあるウインドウがメモ帳の編集ウィンドウ
//
//  アプリの起動完了を検出するにはShellExecuteEx,CreateProcess 関数等を使用する
//
//  ShellExecuteの使用にはusesにShellAPOが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  ShellExecute(Handle, '', PChar('Notepad.exe'), nil, nil, SW_SHOW);

  //起動完了待ちの代用
  //メモ帳が表示されても必ずもハンドルが有効になっているとは限らないので注意
  Sleep(2000);

  //メモ帳のハンドル
  FhNotepad := GetForegroundWindow;
  if FhNotepad > 0 then begin
    //受取る側のトップウィンドウのハンドルを取得.ここではメモ帳の編集ウィンドウ
    FhNotepadEdit := Self.GetFocusWindow(FhNotepad);

    Button2.Enabled := True;
    Button3.Enabled := True;
    Button4.Enabled := True;
    Button5.Enabled := True;
  end;
end;

//=============================================================================
//  他のアプリのフォーカスのあるコントロールの文字列を取得する
//  メモ帳の例
//  String型を使用する例
//
//  String型はSetLengthで文字列の長さを設定する
//  Windows APIの関数によっては長さの設定が不要な場合もある
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LBuffer  : string;
  LTextLen : Integer;
begin
  Memo1.Lines.Clear;
  //メモ帳の編集ウィンドウのハンドルを確認
  if not IsWindowEnabled(FhNotepadEdit) then begin
    MessageBox(Handle, '操作可能なメモ帳が起動していません', '情報', MB_OK);
    exit;
  end;

  //メモ帳の文字列の長さを調査
  LTextLen := SendMessage(FhNotepadEdit, WM_GETTEXTLENGTH, 0, 0);
  if LTextLen > 0 then begin
    //文字列格納用の領域を確保
    //+1は終端文字の分
    SetLength(LBuffer, LTextLen + 1);

    //メモ帳の編集ウィンドウに文字列を取得するメッセージを送る
    SendMessage(FhNotepadEdit, WM_GETTEXT, Length(LBuffer), LPARAM(PChar(LBuffer)));

    //取得した文字列を本アプリのMemo1にセット
    Memo1.Lines.Text := LBuffer;
  end;
end;

//=============================================================================
//  他のアプリのフォーカスのあるコントロールの文字列を取得する
//  メモ帳の例
//  PChar型で取得する例
//
//  StrAllocで文字列の長さを設定する(終端文字のnull分を含める必要あり)
//  StrAllocで設定した長さは領域はStrBufSizeで取得できる
//  StrAllocで設定した領域はStrDisposeで開放が必要
//  Windows APIの関数によっては長さの設定が不要な場合もある
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
var
  LBuffer  : PChar;
  LTextLen : Integer;
begin
  Memo1.Lines.Clear;
  //メモ帳の編集ウィンドウのハンドルを確認
  if not IsWindowEnabled(FhNotepadEdit) then begin
    MessageBox(Handle, '操作可能なメモ帳が起動していません', '情報', MB_OK);
    exit;
  end;

  //メモ帳の文字列の長さを調査
  LTextLen := SendMessage(FhNotepadEdit, WM_GETTEXTLENGTH, 0, 0);
  if LTextLen > 0 then begin
    //受信バッファとしての文字列の領域(長さ)を設定
    //+1は終端文字の分
    LBuffer := StrAlloc(LTextLen + 1);
    try
      //文字列を取得するメッセージを送る
      SendMessage(FhNotepadEdit, WM_GETTEXT, StrBufSize(LBuffer), LPARAM(LBuffer));

      //取得した文字列を本アプリのMemo1にセット
      Memo1.Lines.Text := LBuffer;
    finally
      StrDispose(LBuffer);
    end;
  end;
end;

//=============================================================================
//  他のアプリのフォーカスのあるコントロールの文字列を取得する
//  メモ帳の例
//  Char型の静的配列で取得する例
//
//  設定した文字列の長さが不足すると例外が発生するので注意
//  Char型の静的配列は変数の定義の時に長さを設定する方式
//  Char型の静的配列はFillChar手続きで初期化できる
//  ウインドウのタイトルやファイル名等、長さ制限のある文字列の取得に適している
//=============================================================================
procedure TForm1.Button4Click(Sender: TObject);
var
  LBuffer  : array[0..MAXWORD] of Char;
  LTextLen : Integer;
begin
  Memo1.Lines.Clear;
  //メモ帳の編集ウィンドウのハンドルを確認
  if not IsWindowEnabled(FhNotepadEdit) then begin
    MessageBox(Handle, '操作可能なメモ帳が起動していません', '情報', MB_OK);
    exit;
  end;

  //メモ帳の文字列の長さを調査
  LTextLen := SendMessage(FhNotepadEdit, WM_GETTEXTLENGTH, 0, 0);
  if LTextLen > 0 then begin
    //バッファとしての文字列の初期化
    //null文字で埋めないと取得した文字列にゴミが入ることがある
    //実際に取得可能な文字数は(MAXWORD)まで
    FillChar(LBuffer, Sizeof(LBuffer), #0);

    //メモ帳の編集ウィンドウに文字列を取得するメッセージを送る
    SendMessage(FhNotepadEdit, WM_GETTEXT, Length(LBuffer), LPARAM(@LBuffer));

    //取得した文字列を本アプリのMemo1にセット
    //Memo1.Lines.Text := string(LBuffer);とキャストすれば確実
    Memo1.Lines.Text := LBuffer;
  end;
end;

//=============================================================================
//  他のアプリのフォーカスのあるコントロールの文字列を取得する
//  Char型の動的配列で取得する例
//
//  Char型の動的配列はSetLengthで文字列の長さを設定する
//  String型へはstring,またはPCharでキャストすれば代入可能
//=============================================================================
procedure TForm1.Button5Click(Sender: TObject);
var
  LBuffer  : array of Char;
  LTextLen : Integer;
begin
  Memo1.Lines.Clear;
  //メモ帳の編集ウィンドウのハンドルを確認
  if not IsWindowEnabled(FhNotepadEdit) then begin
    MessageBox(Handle, '操作可能なメモ帳が起動していません', '情報', MB_OK);
    exit;
  end;

  //メモ帳の文字列の長さを調査
  LTextLen := SendMessage(FhNotepadEdit, WM_GETTEXTLENGTH, 0, 0);
  if LTextLen > 0 then begin
    //文字列格納用の領域を確保
    //+1は終端文字の分
    SetLength(LBuffer, LTextLen + 1);

    //メモ帳の編集ウィンドウに文字列を取得するメッセージを送る
    SendMessage(FhNotepadEdit, WM_GETTEXT, Length(LBuffer), LPARAM(PChar(LBuffer)));

    //取得した文字列を本アプリのMemo1にセット
    //Memo1.Lines.Text := PChar(LBuffer); でもOK
    Memo1.Lines.Text := string(LBuffer);
  end;
end;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Memo1: TMemo;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  フォーム表示開始時の処理
//  テスト用の文字列をセット
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  with Memo1.Lines do begin
    Clear;
    BeginUpdate;
    Add('Delphiはウインドウズ用の開発言語です');
    Add('これはテスト用の文字列です');
    EndUpdate;
  end;
end;

//=============================================================================
//  起動中のメモ帳に文字列を送る
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LhNotepad     : HWND;
  LhNotepadEdit : HWND;
begin
  //メモ帳のウィンドウハンドルを取得
  LhNotepad := FindWindow('Notepad', nil);
  if LhNotepad = 0 then begin
    MessageBox(Handle, 'メモ帳が起動していません', '情報', MB_OK);
    exit;
  end;

  //メモ帳の編集ウィンドウのハンドルを取得
  LhNotepadEdit := FindWindowEx(LhNotepad, 0, 'Edit', nil);

  if LhNotepadEdit <> 0 then begin
    //そこにテキストを送る
    SendMessage(LhNotepadEdit, WM_SETTEXT, 0, LPARAM(PChar(Memo1.Text)));
  end;
end;

//=============================================================================
//  起動中のメモ帳からテキストを取得
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  FhNotepad     : HWND;
  FhNotepadEdit : HWND;
  LTextLen      : Integer;
  LBuffer       : string;
begin
  //メモ帳のウィンドウハンドルを取得
  FhNotepad := FindWindow('Notepad', nil);
  if FhNotepad = 0 then begin
    MessageBox(Handle, 'メモ帳が起動していません', '情報', MB_OK);
    exit;
  end;

  //メモ帳の編集ウィンドウのハンドルを取得
  FhNotepadEdit := FindWindowEx(FhNotepad, 0, 'Edit', nil);

  //メモ帳の文字列の長さを調査
  LTextLen := SendMessage(FhNotepadEdit, WM_GETTEXTLENGTH, 0, 0);
  if LTextLen > 0 then begin
    //文字列格納用の領域を確保
    SetLength(LBuffer, LTextLen + 1);

    //メモ帳の編集ウィンドウに文字列を取得するメッセージを送る
    SendMessage(FhNotepadEdit, WM_GETTEXT, Length(LBuffer), LPARAM(PChar(LBuffer)));

    //取得した文字列を本アプリのMemo1にセット
    Memo1.Lines.Text := LBuffer;
  end;
end;

end.

    Memo1.Text := Clipboard.AsText;

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, Clipbrd;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    Panel1: TPanel;
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  protected
    procedure WMDrawClipboard(var Message: TWMDrawClipboard);
      message WM_DRAWCLIPBOARD;
  private
    { Private 宣言 }
    FhNextClipboardViewer : HWND;
    FReceiveFlag : Boolean;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  テスト用の文字列をセット
//  クリップボードの監視を開始
//  flagReceive の値は、他のアプリに [Ctrl] + [C] の操作をする直前に True にする
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  FReceiveFlag := False;
  // クリップボードビューアとして登録
  FhNextClipboardViewer := SetClipboardViewer(Self.Handle);

  Memo1.Text := '文字列送信テスト';
end;

//=============================================================================
//  フォームの OnDestroy 処理
//  クリップボードのチェーンからこのフォームを削除する
//=============================================================================
procedure TForm1.FormDestroy(Sender: TObject);
begin
  ChangeClipboardChain(Self.Handle, FhNextClipboardViewer);
end;

//=============================================================================
//  直前にアクティブだったウィンドウに文字列を送信
//  入力フォーカスがあったコントロールが文字列を受信する
//
//  uses に Clipbrd が必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LhWindow : HWND;
  LKeyByte : Byte;
begin
  // テスト用の文字列をクリップボードに格納
  Clipboard.AsText := Memo1.Text;

  // 直前にアクティブだったウィンドウを取得
  LhWindow := Handle;
  LhWindow := GetNextWindow(LhWindow, GW_HWNDNEXT);
  while not IsWindowVisible(LhWindow) do begin
    LhWindow := GetNextWindow(LhWindow, GW_HWNDNEXT);
  end;

  //見つかったらそのウィンドウを前面にもってくる
  SetForegroundWindow(LhWindow);

  // [Ctrl] + [V] のキー操作
  LKeyByte := Ord('V');

  keybd_event(VK_CONTROL, MapVirtualKey(VK_CONTROL, 0), 0, 0);
  keybd_event(LKeyByte,   MapVirtualKey(LKeyByte, 0),   0, 0);
  keybd_event(LKeyByte,   MapVirtualKey(LKeyByte, 0),   KEYEVENTF_KEYUP, 0);
  keybd_event(VK_CONTROL, MapVirtualKey(VK_CONTROL, 0), KEYEVENTF_KEYUP, 0);
end;

//=============================================================================
//  直前にアクティブだったウィンドウの文字列を取得
//  入力フォーカスがあったコントロールの文字列を取得する
//
//  uses に Clipbrd が必要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LhWindow : HWND;
  LKeyByte : Byte;
  LKeyFlag : Cardinal;
begin
  // クリップボード監視を有効にする
  FReceiveFlag := True;

  // 直前にアクティブだったウィンドウを取得
  LhWindow := Handle;
  LhWindow := GetNextWindow(LhWindow, GW_HWNDNEXT);
  while not IsWindowVisible(LhWindow) do begin
    LhWindow := GetNextWindow(LhWindow, GW_HWNDNEXT);
  end;

  // 見つかったらそのウィンドウを前面にもってくる
  SetForegroundWindow(LhWindow);

  // [Ctrl] + [A] のキー操作 全て選択
  LKeyByte := Ord('A');

  keybd_event(VK_CONTROL, MapVirtualKey(VK_CONTROL, 0), 0, 0);
  keybd_event(LKeyByte,   MapVirtualKey(LKeyByte, 0),   0, 0);
  keybd_event(LKeyByte,   MapVirtualKey(LKeyByte, 0),   KEYEVENTF_KEYUP, 0);
  keybd_event(VK_CONTROL, MapVirtualKey(VK_CONTROL, 0), KEYEVENTF_KEYUP, 0);
  Application.ProcessMessages;

  // [Ctrl] +[C] のキー操作 コピー
  LKeyByte := Ord('C');

  keybd_event(VK_CONTROL, MapVirtualKey(VK_CONTROL, 0), 0, 0);
  keybd_event(LKeyByte,   MapVirtualKey(LKeyByte, 0),   0, 0);
  keybd_event(LKeyByte,   MapVirtualKey(LKeyByte, 0),   KEYEVENTF_KEYUP, 0);
  keybd_event(VK_CONTROL, MapVirtualKey(VK_CONTROL, 0), KEYEVENTF_KEYUP, 0);
  Application.ProcessMessages;
  Sleep(100);

  // [HOME] のキー操作 選択解除のつもり
  LKeyFlag := KEYEVENTF_KEYUP or KEYEVENTF_EXTENDEDKEY;
  keybd_event(VK_HOME, MapVirtualKey(VK_HOME, 0), 0, 0);
  keybd_event(VK_HOME, MapVirtualKey(VK_HOME, 0), LKeyFlag, 0);
end;

//=============================================================================
//  クリップボードビューアとしての監視
//  クリップボードにデータが発生した時の処理
//=============================================================================
procedure TForm1.WMDrawClipboard(var Message: TWMDrawClipboard);
begin
  if not FReceiveFlag then exit;

  if (Clipboard.HasFormat(CF_TEXT)) then begin
    Memo1.Text  := Clipboard.AsText;
    SetForegroundWindow(Handle);
    FReceiveFlag := False;
  end;
end;

end.