unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    Panel1: TPanel;
    Button1: TButton;
    Edit1: TEdit;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//-----------------------------------------------------------------------------
//  文字列検索関数
//  Halbow資料館の同名関数をUnicode化
//
//  引数
//  Str      : この文字列の中を検索する
//  SubStr   : 検索文字列
//  SearchOP : False 検索文字の有無のみ調査
//             True  検索数を取得する場合
//
//  戻り値 : 検索数
//
//  [備考]
//  StrEnd(SysUtils.pas)
//  ヌルで終わる文字列の末尾を指すポインタを返す関数
//-----------------------------------------------------------------------------
function HowManyWords(const Str, SubStr: string; SearchOP: Boolean=True):Integer;
var
  LPStr    : PChar;
  LPSubStr : PChar;
  LMaxLen  : Integer;
  LPStrEnd : PChar;
begin
  Result     := 0;
  LMaxLen    := Length(SubStr);
  if LMaxLen = 0 then exit;

  LPStr    := @Str[1];
  LPSubStr := @SubStr[1];
  LPStrEnd := StrEnd(LPStr);

  while LPStrEnd > LPStr do begin
    if StrLIComp(LPStr, LPSubStr, LMaxLen) = 0 then
    begin
      //見つかったら検索文字数だけ次へ
      Inc(result);
      if SearchOP = False then break;
      Inc(LPStr, LMaxLen);
    end else
    begin
      //見つからなかったら1文字だけ次へ
      Inc(LPStr, 1);
    end;
    Application.ProcessMessages;
  end;
end;

//=============================================================================
//  テスト用のテキストをファイルから読み込んで表示
//  テスト用の検索文字列をセット
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  RichEdit1.Lines.LoadFromFile('ATest.txt');

  Edit1.Text := 'Delphi';
end;

//=============================================================================
//  検索文字列が対象テキスト内にいくつあるかを調査
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LCount : Integer;
begin
  LCount := HowManyWords(RichEdit1.Text, Edit1.Text, True);
  MessageBox(Handle, PChar(IntToStr(LCount)), '結果', MB_OK);
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    Panel1: TPanel;
    Button1: TButton;
    Edit1: TEdit;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  SkRegularExpressions;

{$R *.dfm}

//=============================================================================
//  テスト用のテキストをファイルから読み込んで表示
//  テスト用の検索文字列をセット
//  正規表現が使える
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  RichEdit1.Lines.LoadFromFile('ATest.txt');

  Edit1.Text := 'ORACLE|Delphi';
end;

//=============================================================================
//  検索文字列が対象テキスト内にいくつあるかを調査
//  小宮秀一氏のDelphi用正規表現ユニットを使用した例
//  Delphi XEで追加されたTRegExの互換ライブラリSkRegularExpressionsを使用
//
//  usesにSkRegularExpressionsが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LCollection : TMatchCollection;
begin
  LCollection := TRegEx.Matches(RichEdit1.Text, Edit1.Text, [roIgnoreCase]);
  MessageBox(Handle, PChar(IntToStr(LCollection.Count)), '結果', MB_OK);
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    Panel1: TPanel;
    Edit1: TEdit;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

type
  TIntArray = array[1..MAXWORD] of Integer;

{$R *.dfm}

//-----------------------------------------------------------------------------
//  一括検索関数
//  Halbow資料館の同名関数をUnicode化
//  改行文字等，特殊文字の処理が必要な場合は修正して利用可能
//
//  引数
//  Str      : この文字列の中を検索する
//  SubStr   : 検索文字列
//  PosArray : 検索位置の情報を格納した整数配列
//
//  戻り値 : 検索数
//
//  [備考]
//  StrEnd(SysUtils.pas)
//  ヌルで終わる文字列の末尾を指すポインタを返す関数
//-----------------------------------------------------------------------------
function SearchPos(const Str, SubStr: String; var PosArray: TIntArray): Integer;
var
  LPStr    : PChar;
  LPSubStr : PChar;
  LMaxLen  : Integer;
  LIndex   : Integer;
  LPStrEnd : PChar;
begin
  Result     := 0;
  LIndex     := 0;
  LMaxLen    := Length(SubStr);
  if LMaxLen = 0 then exit;

  LPStr    := @Str[1];
  LPSubStr := @SubStr[1];
  LPStrEnd := StrEnd(LPStr);

  while LPStrEnd > LPStr do begin
    if StrLIComp(LPStr, LPSubStr,LMaxLen) = 0 then begin
      //見つかったら検索文字数だけ次へ
      Inc(Result);
      PosArray[Result] := LIndex;
      Inc(LPStr, LMaxLen);
      inc(LIndex, LMaxLen);
    end else begin
      //見つからなかったら1文字だけ次へ
      Inc(LPStr, 1);
      //改行文字は文字数に数えない
      if StrLIComp(LPStr, sLineBreak, 1) <> 0 then begin
        Inc(LIndex, 1);
      end;
    end;
    Application.ProcessMessages;
  end;
end;

//=============================================================================
//  テスト用のテキストをファイルから読み込んで表示
//  テスト用の検索文字列をセット
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  RichEdit1.WantTabs := True;
  RichEdit1.Lines.LoadFromFile('ATest.txt');

  Edit1.Text := 'Delphi';
end;

//=============================================================================
//  検索文字列が対象テキストのどの位置にあるかを調査
//  SearchPosを実行すると，検索結果の文字列の開始位置が整数配列PAに格納される
//  検察した文字列の色を変更
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LPA    : TIntArray;
  LCount : Integer;
  i      : Integer;
begin
  LCount := SearchPos(RichEdit1.Text, Edit1.Text, LPA);

  if LCount > 0 then begin
    RichEdit1.Lines.BeginUpdate;

    //検索結果を順番に取り出して，該当文字列の色を変更
    for i := 1 to LCount do begin
      RichEdit1.SelStart            := LPA[i];
      RichEdit1.SelLength           := Length(Edit1.Text);
      RichEdit1.SelAttributes.Color := clRed;
      Application.ProcessMessages;
    end;

    RichEdit1.Lines.EndUpdate;
  end else begin
    MessageBox(Handle, '検索文字列はありません．' , '結果', MB_OK);
  end;

  RichEdit1.SelLength := 0;
  //最後の検索文字列が見える位置までスクロール
  RichEdit1.Perform(EM_SCROLLCARET, 0, 0);
  RichEdit1.SetFocus;
end;

//=============================================================================
//  検索文字列が対象テキストのどの位置にあるかを調査
//  検察した文字列の色を変更
//
//  TRichEditのFindText関数を使用した例
//  Delphi 5以降のバージョンであればこの関数で十分だろう
//  FindText関数は，その内部ではEM_FINDTEXTメッセージで検索している
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LLen    : Integer;
  LCurPos : Integer;
begin
  LLen := Length(RichEdit1.Text);
  //テキストの先頭から
  LCurPos := 0;

  while True do begin
    LCurPos := RichEdit1.FindText(Edit1.Text, LCurPos, LLen, []);
    if LCurPos < 0 then break;

    RichEdit1.SelStart            := LCurPos;
    RichEdit1.SelLength           := Length(Edit1.Text);
    RichEdit1.SelAttributes.Color := clRed;
    LCurPos := LCurPos + RichEdit1.SelLength;
    Application.ProcessMessages;
  end;

  RichEdit1.SelLength := 0;
  //最後の検索文字列が見える位置までスクロール
  RichEdit1.Perform(EM_SCROLLCARET, 0, 0);
  RichEdit1.SetFocus;
end;

//=============================================================================
//  再テストのために，テキストの文字列の色を全て同じにする
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
begin
  RichEdit1.Lines.BeginUpdate;
  RichEdit1.SelectAll;
  RichEdit1.SelAttributes.Color := clBlack;
  RichEdit1.SelStart            := 0;
  RichEdit1.Lines.EndUpdate;
  RichEdit1.SetFocus;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    Panel1: TPanel;
    Button1: TButton;
    Button2: TButton;
    Edit1: TEdit;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  SkRegExpW;

{$R *.dfm}

//=============================================================================
//  テスト用のテキストをファイルから読み込んで表示
//  テスト用の検索文字列をセット
//  正規表現が使える
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  RichEdit1.WantTabs := True;
  RichEdit1.Lines.LoadFromFile('ATest.txt');

  //改行文字も検索対象とする
  Edit1.Text := 'ORACLE|DELPHI';
end;

//=============================================================================
//  検索文字列が対象テキストのどの位置にあるかを調査
//  検索した文字列の色を変更
//
//  小宮秀一氏のDelphi用正規表現ユニットSkRegExpWを使用した例
//
//  usesにSkRegExpWが必要
//
//  前回のサンプルで使用したversion 1.2.4と今回の3.0.7の違い
//  version 2.0 の変更点
//  Match, MatchPos, MatchLen, NamedGroup, NamedGroupPos, NamedGroupLen
//  これらのプロパティの代わりに Groupsプロパティを使用する
//  OLD_PROPERTYを条件定義すれば利用可能
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LRegExp : TSkRegExp;
  LStr    : String;
  LLen    : Integer;
  LCurPos : Integer;
begin
  LRegExp := TSkRegExp.Create;
  try
    LRegExp.Expression := Edit1.Text;
    LRegExp.IgnoreCase := True;

    RichEdit1.Lines.BeginUpdate;

    if LRegExp.Exec(RichEdit1.Text) then begin

      LCurPos := 0;
      RichEdit1.SelStart := 0;
      repeat
        LStr := LRegExp.Groups[0].Strings[1];
        LLen := LRegExp.Groups[0].Length;

        //正規表現では，検索対象外の文字を空白行で出力することがあるのでその対策
        //制御文字も含めない
        if (LLen > 0) and (Trim(LStr) <> '') then begin
          //検索結果の位置は，制御文字等を含む位置なので，キャレット位置を再検索
          LCurPos := RichEdit1.FindText(LStr, LCurPos, Length(RichEdit1.Text), []);

          RichEdit1.SelStart            := LCurPos;
          RichEdit1.SelLength           := LLen;
          RichEdit1.SelAttributes.Color := clRed;
          LCurPos := LCurPos + LLen;
        end;
        Application.ProcessMessages;
      until (not LRegExp.ExecNext);

    end else begin
      MessageBox(Handle, '検索文字列はありません．' , '結果', MB_OK);
    end;
  finally
    LRegExp.Free;
  end;
  RichEdit1.Lines.EndUpdate;

  RichEdit1.SelLength := 0;
  //最後の検索文字列が見える位置までスクロール
  RichEdit1.Perform(EM_SCROLLCARET, 0, 0);
  RichEdit1.SetFocus;
end;

//=============================================================================
//  再テストのために，テキストの文字列の色を全て同じにする
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  RichEdit1.Lines.BeginUpdate;
  RichEdit1.SelectAll;
  RichEdit1.SelAttributes.Color := clBlack;
  RichEdit1.SelStart            := 0;
  RichEdit1.Lines.EndUpdate;
  RichEdit1.SetFocus;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    Panel1: TPanel;
    Button1: TButton;
    Button2: TButton;
    Edit1: TEdit;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  SkRegularExpressions;

{$R *.dfm}

//=============================================================================
//  テスト用のテキストをファイルから読み込んで表示
//  テスト用の検索文字列をセット
//  正規表現が使える
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  RichEdit1.WantTabs := True;
  RichEdit1.Lines.LoadFromFile('ATest.txt');

  //検索する文字列をセット
  Edit1.Text := 'ORACLE|DELPHI';
end;

//=============================================================================
//  検索文字列が対象テキストのどの位置にあるかを調査
//  検索した文字列の色を変更
//
//  小宮秀一氏のDelphi用正規表現ユニットSkRegularExpressionsを使用した例
//
//  usesにSkRegularExpressionsが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LMatch  : TMatch;
  LStr    : String;
  LLen    : Integer;
  LCurPos : Integer;
begin
  RichEdit1.Lines.BeginUpdate;

  //TMatchで取得する値には，改行文字分が入っているので，実際の表示の位置を求め
  //るためにTRichEditのFindTextを使用
  LCurPos := 0;
  for LMatch in TRegEx.Matches(RichEdit1.Text, Edit1.Text, [roIgnoreCase]) do begin
    LStr := LMatch.Value;
    LLen := LMatch.Length;

    //正規表現では，検索対象外の文字を空白行で出力することがあるのでその対策
    //制御文字も含めない
    if (LLen > 0) and (Trim(LStr) <> '') then begin
      //検索結果の位置は，制御文字等を含む位置なので，キャレット位置を再検索
      LCurPos := RichEdit1.FindText(LStr, LCurPos, Length(RichEdit1.Text), []);

      RichEdit1.SelStart            := LCurPos;
      RichEdit1.SelLength           := LLen;
      RichEdit1.SelAttributes.Color := clRed;
      LCurPos := LCurPos + LLen;
    end;
    Application.ProcessMessages;
  end;

  RichEdit1.Lines.EndUpdate;

  if LCurPos <= 0 then begin
    MessageBox(Handle, '検索文字列はありません．' , '結果', MB_OK);
  end;

  RichEdit1.SelLength := 0;
  //最後の検索文字列が見える位置までスクロール
  RichEdit1.Perform(EM_SCROLLCARET, 0, 0);
  RichEdit1.SetFocus;
end;

//=============================================================================
//  再テストのために，テキストの文字列の色を全て同じにする
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  RichEdit1.Lines.BeginUpdate;
  RichEdit1.SelectAll;
  RichEdit1.SelAttributes.Color := clBlack;
  RichEdit1.SelStart            := 0;
  RichEdit1.Lines.EndUpdate;
  RichEdit1.SetFocus;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    Panel1: TPanel;
    Button1: TButton;
    Edit1: TEdit;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  テスト用のテキストをファイルから読み込んで表示
//  テスト用の検索文字列をセット
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  RichEdit1.HideSelection := False;
  RichEdit1.Lines.LoadFromFile('ATest.txt');

  Edit1.Text := 'Delphi';
end;

//=============================================================================
//  検索文字列を現在のキャレット位置から逐次検索
//  検索した文字列をハイライト表示
//
//  TRichEditのFindText関数を使用した例
//  Delphi 5以降のバージョンであればこの関数で十分だろう
//  FindText関数は，その内部ではEM_FINDTEXTメッセージで検索している
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LCurPos : Integer;
begin
  //現在のキャレット位置を取得
  LCurPos := RichEdit1.SelStart + RichEdit1.SelLength;

  //検索実行
  LCurPos := RichEdit1.FindText(Edit1.Text, LCurPos, Length(RichEdit1.Text), []);

  if (LCurPos >= 0) then begin
    RichEdit1.SelStart  := LCurPos;
    RichEdit1.SelLength := Length(Edit1.Text);
    //最後の検索文字列が見える位置までスクロール
    RichEdit1.Perform(EM_SCROLLCARET, 0, 0);
  end else begin
    MessageBox(Handle, '検索が終了しました．' , '結果', MB_OK);
  end;
  RichEdit1.SetFocus;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, ExtCtrls;

type
  TplDataListItem =class(TObject)
  private
    FFindStr : String;
    FFindPos : Integer;
  public
    property FindStr : String  read FFindStr write FFindStr;
    property FindPos : Integer read FFindPos write FFindPos;
  end;

  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    Panel1: TPanel;
    Button1: TButton;
    Edit1: TEdit;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  SkRegularExpressions;

{$R *.dfm}

//=============================================================================
//  テスト用のテキストをファイルから読み込んで表示
//  テスト用の検索文字列をセット
//  正規表現が使える
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  RichEdit1.HideSelection := False;
  RichEdit1.Lines.LoadFromFile('ATest.txt');

  //AからZまでと半角の空白とaからzの組み合わせの文字列
  //[A-Z a-z\n] とすれば1文字づつが検索対象となる
  Edit1.Text := '[A-Z a-z]*';
end;

//=============================================================================
//  検索文字列の逐次検索
//
//  小宮秀一氏のDelphi用正規表現ユニットSkRegularExpressionsを使用した例
//
//  Halbow資料館のコードでは，文字列の位置のみを整数配列に格納しているが，正規
//  表現では，複数の異なる文字列を検索する場合もあるので，検索結果の文字列も格
//  納するようにしている
//
//  対象テキストが途中で編集されないという前提であれば
//  MatchList : TMatchCollection;
//  と定義して，MatchListをグローバル変数して保持しておくことも考えられる
//  MatchList := TRegEx.Matches(RichEdit1.Text, Edit1.Text, [roIgnoreCase]);
//
//  usesにSkRegularExpressionsが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LMatch        : TMatch;
  LDataList     : TList;
  LDataItem     : TplDataListItem;
  LPos          : Integer;
  LCurPos       : Integer;
  LCurPosOrigin : Integer;
  LStr          : String;
  LLen          : Integer;
  i             : Integer;
begin
  LDataList := TList.Create;

  //現在のキャレット位置を取得
  LCurPosOrigin := RichEdit1.SelStart + RichEdit1.SelLength;

  //検索実行
  LCurPos := 0;
  for LMatch in TRegEx.Matches(RichEdit1.Text, Edit1.Text, [roIgnoreCase]) do begin
    LStr := LMatch.Value;
    LLen := LMatch.Length;

    //正規表現では，検索対象外の文字を空白行で出力することがあるのでその対策
    //制御文字も含めない
    if (LLen > 0) and (Trim(LStr) <> '') then begin
      //検索結果の位置は，制御文字等を含む位置なのでキャレット位置を再検索
      LCurPos := RichEdit1.FindText(LStr, LCurPos, Length(RichEdit1.Text), []);

      LDataItem := TplDataListItem.Create;
      LDataItem.FindPos := LCurPos;
      LDataItem.FindStr := LStr;
      LCurPos           := LCurPos + LLen;
      LDataList.Add(LDataItem);
    end;
    Application.ProcessMessages;
  end;

  if LDataList.Count > 0 then begin
    LCurPos := LCurPosOrigin;
    LPos   := 0;
    for i := 0 to LDataList.Count - 1 do begin
      LPos := TplDataListItem(LDataList[i]).FindPos;
      LLen := Length(TplDataListItem(LDataList[i]).FindStr);

      if LPos >= LCurPos then begin
        RichEdit1.SelStart  := LPos;
        RichEdit1.SelLength := LLen;
        break;
      end;
      Application.ProcessMessages;
    end;
    if LCurPos > LPos then begin
      MessageBox(Handle, '検索が終了しました．' , '結果', MB_OK);
    end;
  end else begin
    MessageBox(Handle, '検索文字列はありません．' , '結果', MB_OK);
  end;
  RichEdit1.SetFocus;

  if LDataList <> nil then begin
    for i := LDataList.Count - 1 downto 0 do begin
      TplDataListItem(LDataList.Items[i]).Free;
    end;
    LDataList.Clear;
    FreeAndNil(LDataList);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    Panel1: TPanel;
    Button1: TButton;
    Edit1: TEdit;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses RichEdit;

{$R *.dfm}

//=============================================================================
//  テスト用のテキストをファイルから読み込んで表示
//  テスト用の検索文字列をセット
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  RichEdit1.HideSelection := False;
  RichEdit1.Lines.LoadFromFile('ATest.txt');
  RichEdit1.SelStart := Length(RichEdit1.Text);

  Edit1.Text := 'DELPHI';
end;

//=============================================================================
//  逐次逆方向検索
//  EM_FINDTEXTメッセージを使用した方法
//
//  ueseにRichEditが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LCurPos : Integer;
  LFind   : TFindText;
  LuFlags : Integer;
begin
  //fuFlagsの値をFR_DOWN(usesにCommDlgが必要=1)にすれば順方向検索となる
  LuFlags := 0;
  //検索開始キャレット位置．ここから先頭方向に検索
  LCurPos := RichEdit1.SelStart;

  //検索開始位置と検索文字列を設定
  LFind.chrg.cpMin := LCurPos;
  LFind.chrg.cpMax := LCurPos + Length(RichEdit1.Text);
  LFind.lpstrText  := PChar(Edit1.Text);

  //検索実行．戻り値は検索した文字列の先頭位置
  LCurPos := SendMessage(RichEdit1.Handle, EM_FINDTEXT, LuFlags, LPARAM(@LFind));

  if (LCurPos >= 0) then begin
    RichEdit1.SelStart  := LCurPos;
    RichEdit1.SelLength := Length(Edit1.Text);
    RichEdit1.Perform(EM_SCROLLCARET, 0, 0);
  end else begin
    MessageBox(Handle, '検索が終了しました．' , '結果', MB_OK);
  end;
  RichEdit1.SetFocus;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, ExtCtrls;

type
  TplDataListItem =class(TObject)
  private
    FFindStr : String;
    FFindPos : Integer;
  public
    property FindStr : String  read FFindStr write FFindStr;
    property FindPos : Integer read FFindPos write FFindPos;
  end;

  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    Panel1: TPanel;
    Button1: TButton;
    Edit1: TEdit;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  SkRegularExpressions;

{$R *.dfm}

//=============================================================================
//  テスト用のテキストをファイルから読み込んで表示
//  テスト用の検索文字列をセット
//  正規表現が使える
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  RichEdit1.HideSelection := False;
  RichEdit1.Lines.LoadFromFile('ATest.txt');
  RichEdit1.SelStart := Length(RichEdit1.Text);

  //AからZまでと半角の空白とaからzの組み合わせの文字列
  //[A-Z a-z] とすれば1文字づつが検索対象となる
  Edit1.Text := '[A-Z a-z]*';
end;

//=============================================================================
//  逐次逆方向検索
//
//  小宮秀一氏のDelphi用正規表現ユニットSkRegularExpressionsを使用した例
//
//  Halbow資料館のコードでは，文字列の位置のみを整数配列に格納しているが，正規
//  表現では，複数の異なる文字列を検索する場合もあるので，検索結果の文字列も格
//  納するようにしている
//
//  対象テキストが途中で編集されないという前提であれば
//  MatchList : TMatchCollection;
//  と定義して，MatchListをグローバル変数して保持しておくことも考えられる
//  MatchList := TRegEx.Matches(RichEdit1.Text, Edit1.Text, [roIgnoreCase]);
//
//  usesにSkRegularExpressionsが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LMatch        : TMatch;
  LDataList     : TList;
  LDataItem     : TplDataListItem;
  LPos          : Integer;
  LCurPos       : Integer;
  LCurPosOrigin : Integer;
  LStr          : String;
  LLen          : Integer;
  i             : Integer;
begin
  LDataList := TList.Create;

  //現在のキャレット位置を取得
  LCurPosOrigin := RichEdit1.SelStart;

  //検索実行
  LCurPos := 0;
  for LMatch in TRegEx.Matches(RichEdit1.Text, Edit1.Text, [roIgnoreCase]) do begin
    LStr := LMatch.Value;
    LLen := LMatch.Length;

    //正規表現では，検索対象外の文字を空白行で出力することがあるのでその対策
    //制御文字も含めない
    if (LLen > 0) and (Trim(LStr) <> '') then begin
      //検索結果の位置は，制御文字等を含む位置なのでキャレット位置を再検索
      LCurPos := RichEdit1.FindText(LStr, LCurPos, Length(RichEdit1.Text), []);

      LDataItem := TplDataListItem.Create;
      LDataItem.FindPos := LCurPos;
      LDataItem.FindStr := LStr;
      LCurPos           := LCurPos + LLen;
      LDataList.Add(LDataItem);
    end;
    Application.ProcessMessages;
  end;

  if LDataList.Count > 0 then begin
    LCurPos := LCurPosOrigin;
    LPos   := 0;
    for i := LDataList.Count - 1 downto 0 do begin
      LPos := TplDataListItem(LDataList[i]).FindPos;
      LLen := Length(TplDataListItem(LDataList[i]).FindStr);

      if LPos < LCurPos then begin
        RichEdit1.SelStart  := LPos;
        RichEdit1.SelLength := LLen;
        break;
      end;
      Application.ProcessMessages;
    end;

    if LCurPos <= LPos then begin
      MessageBox(Handle, '検索が終了しました．' , '結果', MB_OK);
    end;
  end else begin
    MessageBox(Handle, '検索文字列はありません．' , '結果', MB_OK);
  end;
  RichEdit1.SetFocus;

  if LDataList <> nil then begin
    for i := LDataList.Count - 1 downto 0 do begin
      TplDataListItem(LDataList.Items[i]).Free;
    end;
    LDataList.Clear;
    FreeAndNil(LDataList);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    Panel1: TPanel;
    Button1: TButton;
    Edit1: TEdit;
    Edit2: TEdit;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  テスト用のテキストをファイルから読み込んで表示
//  テスト用の検索文字列をセット
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  RichEdit1.HideSelection := False;
  RichEdit1.Lines.LoadFromFile('ATest.txt');

  Edit1.Text := 'Delphi';
  Edit2.Text := 'DELPHI';
end;

//=============================================================================
//  検索文字列を現在のキャレット位置から逐次検索して置換する
//  置換確認用のダイアログを表示
//
//  EM_REPLACESELメッセージを使用
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LCurPos  : Integer;
  LDestStr : String;
begin
  LCurPos := 0;

  while True do begin
    //現在のキャレット位置を取得
    LCurPos := RichEdit1.SelStart + RichEdit1.SelLength;

    //検索実行
    LCurPos := RichEdit1.FindText(Edit1.Text, LCurPos, Length(RichEdit1.Text), []);
    if LCurPos < 0 then break;

    if (LCurPos >= 0) then begin
      RichEdit1.SelStart  := LCurPos;
      RichEdit1.SelLength := Length(Edit1.Text);
      RichEdit1.Perform(EM_SCROLLCARET, 0, 0);

      if MessageBox(0, '置換しますか．', '文字列置換', MB_OKCANCEL) = ID_OK then begin
        LDestStr := Edit2.Text;
        RichEdit1.Perform(EM_REPLACESEL, 1, LPARAM(PChar(LDestStr)));

        //キャレットを置換した文字列の次に移動しておく
        RichEdit1.SelStart := LCurPos + Length(LDestStr);
      end else begin
        break;
      end;
    end;
  end;

  if LCurPos < 0 then begin
    MessageBox(Handle, '終了しました．' , '結果', MB_OK);
  end;

  RichEdit1.SetFocus;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    Panel1: TPanel;
    Button1: TButton;
    Edit1: TEdit;
    Splitter1: TSplitter;
    RichEdit2: TRichEdit;
    Button2: TButton;
    Button3: TButton;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses SkRegExpW;

{$R *.dfm}

//=============================================================================
//  テスト用のテキストをファイルから読み込んで表示
//  テスト用の検索文字列をセット
//  正規表現が使える
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  RichEdit1.Clear;
  RichEdit2.Clear;
  RichEdit1.ScrollBars := ssVertical;
  RichEdit2.ScrollBars := ssVertical;

  RichEdit1.Lines.LoadFromFile('ATest.txt');

  //半角英字の組み合わせの文字列を検索
  Edit1.Text := '[a-z A-Z!-"]*';
end;

//=============================================================================
//  半角英字の一括置換
//  文字列の前に<b>を，後ろに</b>を付加
//
//  小宮秀一氏のDelphi用正規表現ユニットSkRegExpWを使用した例
//
//  usesにSkRegExpWが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LRegExp     : TSkRegExp;
  LReplaceStr : String;
begin
  RichEdit2.Clear;
  RichEdit2.Update;

  LRegExp := TSkRegExp.Create;
  try
    LRegExp.Expression := Edit1.Text;
    LRegExp.IgnoreCase := True;

    //置換する文字列．SkRegExpWのヘルプの[置換専用のメタ文字]参照
    LReplaceStr := '<b>' + '$&' + '</b>';
    //置換実行
    RichEdit2.Text := LRegExp.Replace(RichEdit1.Text, LReplaceStr);
  finally
    LRegExp.Free;
  end;
end;

//=============================================================================
//  半角英字の一括置換
//  文字列の前に<b>を，後ろに</b>を付加
//
//  関数RegReplaceを使用した例
//
//  usesにSkRegExpWが必要
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
var
  LReplaceStr : String;
begin
  RichEdit2.Clear;
  RichEdit2.Update;

  //置換する文字列．SkRegExpWのヘルプの[置換専用のメタ文字]参照
  LReplaceStr := '<b>' + '$&' + '</b>';
  //置換実行
  RichEdit2.Text := RegReplace(Edit1.Text, RichEdit1.Text, LReplaceStr, []);
end;

//=============================================================================
//  テストのためにクリア
//=============================================================================
procedure TForm1.Button3Click(Sender: TObject);
begin
  RichEdit2.Clear;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    Panel1: TPanel;
    Edit1: TEdit;
    Splitter1: TSplitter;
    RichEdit2: TRichEdit;
    Button1: TButton;
    Button2: TButton;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses
  SkRegularExpressions;

{$R *.dfm}

//=============================================================================
//  テスト用のテキストをファイルから読み込んで表示
//  テスト用の検索文字列をセット
//  正規表現が使える
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  RichEdit1.Clear;
  RichEdit2.Clear;
  RichEdit1.ScrollBars := ssVertical;
  RichEdit2.ScrollBars := ssVertical;

  RichEdit1.Lines.LoadFromFile('ATest.txt');

  //半角英字の組み合わせの文字列を検索
  Edit1.Text := '[a-z A-Z!-"]*';
end;

//=============================================================================
//  半角英字の一括置換
//  文字列の前に<b>を，後ろに</b>を付加
//
//  小宮秀一氏のDelphi用正規表現ユニットSkRegularExpressionsを使用した例
//
//  usesにSkRegularExpressionsが必要
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LReplaceStr : String;
begin
  RichEdit2.Clear;
  RichEdit2.Update;

  //置換する文字列．SkRegExpWのヘルプの[置換専用のメタ文字]参照
  LReplaceStr := '<b>' + '$&' + '</b>';
  //置換実行
  RichEdit2.Text := TRegEx.Replace(RichEdit1.Text, Edit1.Text, LReplaceStr);
end;

//=============================================================================
//  テストのためにクリア
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  RichEdit2.Clear;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, ExtCtrls, SkRegularExpressions;

type
  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    Panel1: TPanel;
    Edit1: TEdit;
    Splitter1: TSplitter;
    RichEdit2: TRichEdit;
    Button1: TButton;
    Button2: TButton;
    procedure FormShow(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private 宣言 }
    function EValReplace(const AMatch: TMatch): String;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//=============================================================================
//  テスト用のテキストをファイルから読み込んで表示
//  テスト用の検索文字列をセット
//  正規表現が使える
//=============================================================================
procedure TForm1.FormShow(Sender: TObject);
begin
  RichEdit1.Clear;
  RichEdit2.Clear;
  RichEdit1.ScrollBars := ssVertical;
  RichEdit2.ScrollBars := ssVertical;

  RichEdit1.Lines.LoadFromFile('ATest.txt');

  //半角英字の組み合わせの文字列を検索
  Edit1.Text := '[a-z A-Z!-"]*';
end;

//=============================================================================
//  条件付きの置換用関数
//=============================================================================
function TForm1.EValReplace(const AMatch: TMatch): String;
begin
  //検索結果の文字列が'Delphi'のと時は'Delphi 2010'に
  //それ以外の時は文字列の左端にを，右端にを付加
  if UpperCase(AMatch.Value) = 'DELPHI' then begin
    Result := 'Delphi 2010';
  end else begin
    Result := '<b>' + AMatch.Value + '</b>';
  end;
end;

//=============================================================================
//  半角英字の一括置換
//  検索結果の文字列によって処理を分ける場合
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
var
  LEvaluator : TMatchEvaluator;
begin
  RichEdit2.Clear;
  RichEdit2.Update;

  //置換処理用関数を定義
  LEvaluator := EValReplace;
  //置換実行
  RichEdit2.Text := TRegEx.Replace(RichEdit1.Text, Edit1.Text, LEvaluator, []);
end;

//=============================================================================
//  テストのためにクリア
//=============================================================================
procedure TForm1.Button2Click(Sender: TObject);
begin
  RichEdit2.Clear;
end;

end.