unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Grids, ExtCtrls;

type
  TForm1 = class(TForm)
    StringGrid1: TStringGrid;
    Panel1: TPanel;
    procedure FormCreate(Sender: TObject);
    procedure StringGrid1GetEditText(Sender: TObject; ACol, ARow: Integer;
      var Value: string);
    procedure StringGrid1SetEditText(Sender: TObject; ACol, ARow: Integer;
      const Value: string);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

//protected部にアクセスするためのクラス宣言
type
  TMyStringGrid = class(TStringGrid);

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  //StringGrid1のセルを編集可能にする
  StringGrid1.Options := StringGrid1.Options + [goEditing];
end;

//=============================================================================
//  StringGrid1のOnGetEditTextイベント処理
//
//  インプレイスエディタが起動し，セルの値を取得してセットする時に発生する
//  引数のValueに値をセットすると，インプレイスエディタ起動時にその値となる
//=============================================================================
procedure TForm1.StringGrid1GetEditText(Sender: TObject; ACol, ARow: Integer;
  var Value: string);
var
  InpEdit  : TInplaceEdit;
  hInpEdit : HWND;
begin
  //インプレイスエディタのオブジェクトを取得
  InpEdit := TMyStringGrid(StringGrid1).InplaceEditor;

  if Assigned(InpEdit) then begin
    //インプレイスエディタのハンドルを取得して，IMEモードを設定
    hInpEdit := InpEdit.Handle;
    if ACol = 1 then begin
      SetImeMode(hInpEdit, imHira);
    end else begin
      Win32NLSEnableIME(hInpEdit, False);
    end;

    //InplaceEditの背景色の設定
    InpEdit.Brush.Color := clSkyBlue;
  end;
end;

//=============================================================================
//  StringGrid1のOnSetEditTexイベント処理
//  インプレスエディタの値が変化すると自動的に実行される
//=============================================================================
procedure TForm1.StringGrid1SetEditText(Sender: TObject; ACol, ARow: Integer;
  const Value: string);
begin
  //Panel1にインプレイスエディトの値を逐次表示
  Panel1.Caption := Value;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Grids, ExtCtrls;

type
  TMyStringGrid = class(TStringGrid)
  protected
    function CanEditShow: Boolean; override;
    function GetEditText(ACol: Integer; ARow: Integer): string; override;
    procedure SetEditText(ACol: Integer; ARow: Integer; const Value: string);
      override;
  end;

  TForm1 = class(TForm)
    StringGrid1: TStringGrid;
    Panel1: TPanel;
    procedure FormCreate(Sender: TObject);
  private
    { Private 宣言 }
    MyStringGrid1 : TMyStringGrid;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses plChgCompo;

{$R *.dfm}

// インプレイスエディタのprotected部にアクセスするための宣言
type
  TMyInpEdit = class(TInplaceEdit);


//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  //フォーム作成時にコンポーネントを入れ換えて，セルを編集可能にする
  MyStringGrid1 := TMyStringGrid(ChangeComponent(StringGrid1, TMyStringGrid));
  MyStringGrid1.Options := MyStringGrid1.Options + [goEditing];
end;

{ TMyStringGrid }

//=============================================================================
//  TStringGridのCanEditShowメソッド
//  インプレースエディタが起動した時に実行される
//=============================================================================
function TMyStringGrid.CanEditShow: Boolean;
begin
  Result := inherited CanEditShow;

  //フォントのサイズと背景色を設定
  if InplaceEditor <> nil then begin
    TMyInpEdit(InplaceEditor).Font.Size := 12;
    InplaceEditor.Brush.Color := clSkyBlue;

    if Col = 1 then begin
      SetImeMode(InplaceEditor.Handle, imHira);
    end else begin
      Win32NLSEnableIME(InplaceEditor.Handle, False);
    end;
  end;
end;

//=============================================================================
//  TStringGridのGetEditTextメソッド
//  インプレイスエディタがセルの値を受け取る時に実行される
//  戻り値の値がインプレイスエディタ起動時にセットされる
//=============================================================================
function TMyStringGrid.GetEditText(ACol, ARow: Integer): string;
begin
  Result := inherited GetEditText(ACol, ARow);
end;

//=============================================================================
//  TStringGridのSetEditTexメソッド
//  インプレスエディタの値が変化すると自動的に実行される
//=============================================================================
procedure TMyStringGrid.SetEditText(ACol, ARow: Integer; const Value: string);
begin
  inherited;

  //Panel1にインプレイスエディトの値を逐次表示
  Form1.Panel1.Caption := Value;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Grids, ExtCtrls, DB, DBTables, DBGrids;

type
  TMyDBGrid = class(TDBGrid)
  protected
    function CanEditShow: Boolean; override;
    function GetEditText(ACol: Integer; ARow: Integer): string; override;
    procedure SetEditText(ACol: Integer; ARow: Integer; const Value: string);
      override;
  end;

  TForm1 = class(TForm)
    Panel1: TPanel;
    DBGrid1: TDBGrid;
    DataSource1: TDataSource;
    Table1: TTable;
    procedure FormCreate(Sender: TObject);
  private
    { Private 宣言 }
    MyDBGrid1 : TMyDBGrid;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses plChgCompo;

{$R *.dfm}

// インプレイスエディタのprotected部にアクセスするための宣言
type
  TMyInpEdit = class(TInplaceEdit);


//=============================================================================
//  フォーム生成時の処理
//
//  配置コンポーネント類の設定は以下の通り
//
//  Table1.DatabaseName := DBDEMOS;
//  Table1.TableName    := customer.db;
//  DataSource1.DataSet := Table1;
//  DBGrid1.DataSource  := DataSource1;
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
begin
  //フォーム作成時にコンポーネントを入れ換える
  MyDBGrid1 := TMyDBGrid(ChangeComponent(DBGrid1, TMyDBGrid));

  //データベースの表を開く
  Table1.Active := True;
  //行の高さを設定
  MyDBGrid1.DefaultRowHeight := 23;
end;

{ TMyDBGrid }

//=============================================================================
//  TDBGridのCanEditShowメソッド
//  インプレースエディタが起動した時に自動的に実行される
//=============================================================================
function TMyDBGrid.CanEditShow: Boolean;
begin
  Result := inherited CanEditShow;

  if InplaceEditor <> nil then  begin
    //セルの背景色
    InplaceEditor.Brush.Color := clMoneyGreen;
    //フォントの設定
    TMyInpEdit(InplaceEditor).Font.Color := clBlue;
    //セルの枠線
    TMyInpEdit(InplaceEditor).BorderStyle := bsSingle;
    //キャレットの位置
    InplaceEditor.SelStart := 0;

    if Col = 2 then begin
      SetImeMode(InplaceEditor.Handle, imHira);
    end else begin
      Win32NLSEnableIME(InplaceEditor.Handle, False);
    end;
  end;
end;

//=============================================================================
//  TDBGridのGetEditTextメソッド
//  インプレイスエディタがセルから値を受け取る時に自動的に実行される
//  戻り値の値がインプレイスエディタにセットされる
//  本サンプルでは使用していないので実装しなくともよい．参考用
//=============================================================================
function TMyDBGrid.GetEditText(ACol, ARow: Integer): string;
begin
  Result := inherited GetEditText(ACol, ARow);
end;

//=============================================================================
//  TDBGridのSetEditTexメソッド
//  インプレスエディタの値が変化すると自動的に実行される
//=============================================================================
procedure TMyDBGrid.SetEditText(ACol, ARow: Integer; const Value: string);
begin
  inherited;

  //Panel1にインプレイスエディトの値を逐次表示
  Form1.Panel1.Caption := Value;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    ListView1: TListView;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure ListView1Editing(Sender: TObject; Item: TListItem;
      var AllowEdit: Boolean);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses CommCtrl;

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  AColumn : TListColumn;
  AItem   : TListItem;
begin
  ListView1.ViewStyle := vsReport;

  //カラムを作成
  AColumn := ListView1.Columns.Add;
  AColumn.Width := 130;
  AColumn.Caption := '項目';

  AColumn := ListView1.Columns.Add;
  AColumn.Width := 60;
  AColumn.Caption := '値';

  //テスト用のデータをセット
  AItem := ListView1.Items.Add;
  AItem.Caption := 'A';
  AItem.SubItems.Add('Sub A');

  AItem := ListView1.Items.Add;
  AItem.Caption := 'B';
  AItem.SubItems.Add('Sub B');

  AItem := ListView1.Items.Add;
  AItem.Caption := 'C';
  AItem.SubItems.Add('Sub C');
end;

//=============================================================================
//  ListViewのItemが0のCaptionを編集状態にする
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  ListView1.ItemIndex := 0;
  ListView1.Selected.EditCaption;
end;

//=============================================================================
//  ListView1のOnEditingイベント
//  Captionの編集開始時に呼ばれるイベント
//
//  ListView_GetEditControlの使用には，usesにCommCtrlが必要
//=============================================================================
procedure TForm1.ListView1Editing(Sender: TObject; Item: TListItem;
  var AllowEdit: Boolean);
var
  EditHandle : HWND;
begin
  //インプレースエディタのハンドルを取得
  EditHandle := ListView_GetEditControl(ListView1.Handle);
  if EditHandle > 0 then begin
    SetImeMode(EditHandle, imHira);
  end;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, CommCtrl, ExtCtrls;

type
  TMyListView = class(TListView)
  protected
    procedure CNNotify(var Message: TWMNotifyLV); message CN_NOTIFY;
    function CanEdit(Item: TListItem): Boolean; override;
    procedure Edit(const Item: tagLVITEMW); override;
  end;

  TForm1 = class(TForm)
    Button1: TButton;
    ListView1: TListView;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
    MyListView1 : TMyListView;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses plChgCompo;

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  AColumn : TListColumn;
  AItem   : TListItem;
begin
  //フォーム作成時にコンポーネントを入れ換える
  MyListView1 := TMyListView(ChangeComponent(ListView1, TMyListView));

  MyListView1.ViewStyle := vsReport;

  //カラムを作成
  AColumn := MyListView1.Columns.Add;
  AColumn.Width := 130;
  AColumn.Caption := '項目';

  AColumn := MyListView1.Columns.Add;
  AColumn.Width := 60;
  AColumn.Caption := '値';

  //テスト用のデータをセット
  AItem := MyListView1.Items.Add;
  AItem.Caption := 'A';
  AItem.SubItems.Add('Sub A');

  AItem := MyListView1.Items.Add;
  AItem.Caption := 'B';
  AItem.SubItems.Add('Sub B');

  AItem := MyListView1.Items.Add;
  AItem.Caption := 'C';
  AItem.SubItems.Add('Sub C');
end;

//=============================================================================
//  ListViewのCaptionを編集状態にする
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  MyListView1.ItemIndex := 0;
  MyListView1.Selected.EditCaption;
end;

{ TMyListView }

//=============================================================================
//  CanEditメソッド
//  編集状態に入ると自動実行される
//  本サンプルでは使用していないので実装しなくともよい．参考用
//=============================================================================
function TMyListView.CanEdit(Item: TListItem): Boolean;
begin
  Result := inherited CanEdit(Item);
end;

//=============================================================================
//  Editメソッド
//  編集が終了すると自動実行される
//  編集状態を[キャンセル]した場合は実行されない
//  本サンプルでは使用していないので実装しなくともよい．参考用
//=============================================================================
procedure TMyListView.Edit(const Item: tagLVITEMW);
begin
  inherited;
end;

//=============================================================================
//  CNNotifyメソッド(WM_NOTIFYメッセージ処理)
//  TWMNotifyLVはDelphi 2007以降の実装．それより前ではTWMNotifyを使用する
//=============================================================================
procedure TMyListView.CNNotify(var Message: TWMNotifyLV);
var
  hWindow : HWND;
begin
  //編集状態に入ればこの値はインプレイスエディタのハンドル
  hWindow := Message.NMHdr.hwndFrom;

  //通知メッセージを判定して操作
  if Message.NMHdr.code = LVN_BEGINLABELEDIT then begin
    SetImeMode(hWindow, imHira);
  end else
  if Message.NMHdr.code = LVN_ENDLABELEDIT then begin
    SetImeMode(hWindow, imClose);
  end;

  inherited;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, CommCtrl;

type
  TMyTreeView = class(TTreeView)
  protected
    function CanEdit(Node: TTreeNode): Boolean; override;
    procedure Edit(const Item: tagTVITEMW); override;
    procedure CNNotify(var Message: TWMNotifyTV); message CN_NOTIFY;
  end;

  TForm1 = class(TForm)
    Button1: TButton;
    TreeView1: TTreeView;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private 宣言 }
    MyTreeView1 : TMyTreeView;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses plChgCompo;

{$R *.dfm}

//=============================================================================
//  フォーム生成時の処理
//=============================================================================
procedure TForm1.FormCreate(Sender: TObject);
var
  Node : TTreeNode;
begin
  //フォーム作成時にコンポーネントを入れ換える
  MyTreeView1 := TMyTreeView(ChangeComponent(TreeView1, TMyTreeView));

  //テスト用のノード(Item)を作成
  Node  := TreeView1.Items.Add(nil, 'NODE_0');
  TreeView1.Items.AddChild(Node, 'NODE_0_ SUB1');
  TreeView1.Items.AddChild(Node, 'NODE_0_ SUB2');
  TreeView1.Items.AddChild(Node, 'NODE_0_ SUB3');

  Node  := TreeView1.Items.Add(nil, 'NODE_1');
  TreeView1.Items.AddChild(Node, 'NODE_1_ SUB1');
  TreeView1.Items.AddChild(Node, 'NODE_1_ SUB2');

  //ノードを全て展開
  TreeView1.FullExpand;
end;

//=============================================================================
//  TreeView1のItemを選択して編集状態にする
//=============================================================================
procedure TForm1.Button1Click(Sender: TObject);
begin
  TreeView1.SetFocus;
  TreeView1.Items[2].Selected := True;
  //編集開始
  TreeView1.Selected.EditText;
end;

{ TMyTreeView }

//=============================================================================
//  CanEditメソッド
//  編集状態に入ると自動実行される
//  本サンプルでは使用していないので実装しなくともよい．参考用
//=============================================================================
function TMyTreeView.CanEdit(Node: TTreeNode): Boolean;
begin
  Result := inherited CanEdit(Node);
end;

//=============================================================================
//  Editメソッド
//  編集が終了すると自動実行される
//  編集状態を[キャンセル]した場合は実行されない
//  本サンプルでは使用していないので実装しなくともよい．参考用
//=============================================================================
procedure TMyTreeView.Edit(const Item: tagTVITEMW);
begin
  inherited;
end;

//=============================================================================
//  CNNotifyメソッド(WM_NOTIFYメッセージ処理)
//  TWMNotifyTVはDelphi 2007以降の実装．それより前ではTWMNotifyを使用する
//=============================================================================
procedure TMyTreeView.CNNotify(var Message: TWMNotifyTV);
var
  hWindow : HWND;
begin
  //編集状態に入ればこの値はインプレイスエディタのハンドル
  hWindow := Message.NMHdr.hwndFrom;

  //通知メッセージを判定して操作
  if Message.NMHdr.code = TVN_BEGINLABELEDIT then begin
    SetImeMode(hWindow, imHira);
  end else
  if Message.NMHdr.code = TVN_ENDLABELEDIT then begin
    SetImeMode(hWindow, imClose);
  end;

  inherited;
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Edit1: TEdit;
    Edit2: TEdit;
    Edit3: TEdit;
    procedure Edit1Enter(Sender: TObject);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

uses imm;

{$R *.dfm}

//=============================================================================
//  Edit1,Edit2,Edit3共有のOnEnterイベント
//  日本語IMEのモードを切り替える
//
//  オブジェクトインスペクタやForm1のOnCreate等でImeModeをimDisableにしないこと
//=============================================================================
procedure TForm1.Edit1Enter(Sender: TObject);
begin
  if Sender = Edit1 then begin
    ImmAssociateContext(TEdit(Sender).Handle, 0);
  end else
  if Sender = Edit2 then begin
    SetImeMode(TEdit(Sender).Handle, imHira);
  end else
  if Sender = Edit3 then begin
    ImmAssociateContext(TEdit(Sender).Handle, 0);
  end;
end;

end.

var
  i       : Integer;
  InpEdit : TInplaceEdit;
begin
  for i := 0 to StringGrid1.ControlCount -1  do begin
    if (StringGrid1.Controls[i] is TInPlaceEdit) then begin
      InpEdit := StringGrid1.Controls[i] as TInPlaceEdit;
      break;
    end;
  end;

var
  InpEdit : TInplaceEdit;
begin
  if StringGrid1.ControlCount > 0 then
    InpEdit := TInplaceEdit(StringGrid1.Controls[0]);